I_BPScriptedPersAddrProcTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BuPa Person Address Version Process - TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view entity I_BPScriptedPersAddrProcTP
  as select from I_BusPartScriptedPersAddrProc
  association        to parent I_BusinessPartnerAddressProcTP as _BusPartAddressProc    on  $projection.MasterDataChangeProcess = _BusPartAddressProc.MasterDataChangeProcess
                                                                                        and $projection.MDChgProcessStep        = _BusPartAddressProc.MDChgProcessStep
                                                                                        and $projection.MDChgProcessSrceSystem  = _BusPartAddressProc.MDChgProcessSrceSystem
                                                                                        and $projection.MDChgProcessSrceObject  = _BusPartAddressProc.MDChgProcessSrceObject
                                                                                        and $projection.AddressNumber           = _BusPartAddressProc.AddressNumber
  association [1..1] to I_BusinessPartnerProcessTP            as _BusinessPartner       on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                                        and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                                        and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                                        and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association [0..1] to I_BPProcessKPIRecordType              as _RecordType            on  $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess
                                                                                        and $projection.MDChgProcessStep        = _RecordType.MDChgProcessStep
                                                                                        and $projection.MDChgProcessSrceSystem  = _RecordType.MDChgProcessSrceSystem
                                                                                        and $projection.MDChgProcessSrceObject  = _RecordType.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessKPIRowVH             as _KPIUpdateStatusText   on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  association [0..*] to I_MDChgProcRecordMessages             as _RecordMessages        on  $projection.MasterDataChangeProcess = _RecordMessages.MasterDataChangeProcess
                                                                                        and $projection.MDChgProcessStep        = _RecordMessages.MDChgProcessStep
                                                                                        and $projection.MDChgProcessSrceSystem  = _RecordMessages.MDChgProcessSrceSystem
                                                                                        and $projection.MDChgProcessSrceObject  = _RecordMessages.MDChgProcessSrceObject
  association [0..1] to I_Country                             as _Country               on  $projection.Country = _Country.Country
  association [0..1] to I_Region                              as _Region                on  $projection.Country = _Region.Country
                                                                                        and $projection.Region  = _Region.Region
  association [0..1] to I_AddressRepresentation               as _AddressRepresentation on  $projection.AddressRepresentationCode = _AddressRepresentation.AddressRepresentationCode
  association [0..1] to I_BusinessPartnerFormOfAddress        as _FormOfAddress         on  $projection.FormOfAddress = _FormOfAddress.FormOfAddress
  association [0..1] to I_MDChgProcessStepTP                  as _Step                  on  $projection.MasterDataChangeProcess = _Step.MasterDataChangeProcess
                                                                                        and $projection.MDChgProcessStep        = _Step.MDChgProcessStep
  association [0..1] to I_BPAddrInfoManagementOut             as _AddrInfoMgmtOut       on  $projection.MasterDataChangeProcess   = _AddrInfoMgmtOut.MasterDataChangeProcess
                                                                                        and $projection.MDChgProcessStep          = _AddrInfoMgmtOut.MDChgProcessStep
                                                                                        and $projection.MDChgProcessSrceSystem    = _AddrInfoMgmtOut.MDChgProcessSrceSystem
                                                                                        and $projection.MDChgProcessSrceObject    = _AddrInfoMgmtOut.MDChgProcessSrceObject
                                                                                        and $projection.AddressNumber             = _AddrInfoMgmtOut.AddressNumber
                                                                                        and $projection.AddressRepresentationCode = _AddrInfoMgmtOut.AddressRepresentationCode
  association [0..1] to I_MDChgProcKPIFilterStdznSts          as _StdStatus             on  $projection.MDChgProcKPIStdznStatus = _StdStatus.MDChangeProcKPIValueKey
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key AddressNumber,
  key AddressRepresentationCode,
      Person,
      BusinessPartner,
      StandardUsage,
      BusinessPartnerAddressUUID,
      ValidityStartDate,
      ValidityEndDate,
      FormOfAddress,
      SearchTerm1,
      SearchTerm2,
      FirstName,
      LastName,
      BusinessPartnerBirthName,
      MiddleName,
      AdditionalLastName,
      PersonFullName,
      AcademicTitle,
      AcademicTitle2,
      LastNamePrefix,
      LastNameSecondPrefix,
      BusinessPartnerSupplementName,
      BusinessPartnerNicknameLabel,
      Initials,
      NameFormat,
      NameCountry,
      BPFirstNameSearchHelp,
      BPLastNameSearchHelp,
      FullName,
      CityName,
      DistrictName,
      CityNumber,
      HomeCityName,
      CityFileTestStatus,
      PostalCode,
      POBoxPostalCode,
      CompanyPostalCode,
      POBox,
      AddressPostBoxUnusable,
      POBoxIsWithoutNumber,
      POBoxDeviatingCityName,
      POBoxDeviatingRegion,
      POBoxDeviatingCountry,
      TransportZone,
      StreetName,
      AddressStreetUnusable,
      HouseNumber,
      HouseNumberSupplementText,
      StreetPrefixName,
      AdditionalStreetPrefixName,
      StreetSuffixName,
      AdditionalStreetSuffixName,
      Building,
      Floor,
      RoomNumber,
      Country,
      CorrespondenceLanguage,
      Region,
      PrfrdCommMediumType,
      PhoneNumber,
      AddressFaxNumber,
      CitySearch,
      StreetSearch,
      AddressTimeZone,
      TaxJurisdiction,
      POBoxLobbyName,
      DeliveryServiceTypeCode,
      DeliveryServiceNumber,
      CountyCode,
      BPCountyText,
      CareOfName,
      AddressNonDeliverableReason,
      PostBoxNonDeliverableReason,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,
      MDChgProcessSourceModif3Binary,
      MDChgProcSrceLastChgdDateTime,

      case
        when MDChgProcessSourceModified = '' then cast( 'N' as mdc_source_modified preserving type )
        when MDChgProcessSourceModified = 'X' then cast( 'M' as mdc_source_modified preserving type )
        else cast( MDChgProcessSourceModified as mdc_source_modified preserving type )
      end as MDChgProcKPIUpdateStatus,

      cast( case
        when _Step.MDChgProcessStepAdapter = 'CL_MDC_ADAPTER_BP_DQMM'
              and MDChgProcessSourceModified = 'X'
                then 'M'
        when _Step.MDChgProcessStepAdapter = 'CL_MDC_ADAPTER_BP_DQMM'
              and MDChgProcessSourceModified = ''
              and CityFileTestStatus = ''
              and not _AddrInfoMgmtOut.AddressInfoCode between '2000' and '4999'
              and not _AddrInfoMgmtOut.AddressPostOfficeBoxInfoCode between '2000' and '4999'
              and not (
                (
                  _AddrInfoMgmtOut.AddressInfoCode = '' or _AddrInfoMgmtOut.AddressInfoCode = ' ' or _AddrInfoMgmtOut.AddressInfoCode = '5020'
                ) and (
                  _AddrInfoMgmtOut.AddressPostOfficeBoxInfoCode = '' or _AddrInfoMgmtOut.AddressPostOfficeBoxInfoCode = ' ' or _AddrInfoMgmtOut.AddressPostOfficeBoxInfoCode = '5020'
                )
              )
                then 'D'
        when _Step.MDChgProcessStepAdapter = 'CL_MDC_ADAPTER_BP_DQMM'
              and MDChgProcessSourceModified = ''
              and CityFileTestStatus = ''
              and ( _AddrInfoMgmtOut.AddressInfoCode between '2000' and '4999'
                 or _AddrInfoMgmtOut.AddressPostOfficeBoxInfoCode between '2000' and '4999'
              )
                then 'B'
        when _Step.MDChgProcessStepAdapter = 'CL_MDC_ADAPTER_BP_DQMM'
              and MDChgProcessSourceModified = ''
              and CityFileTestStatus = 'D'
                then 'O'
        when _Step.MDChgProcessStepAdapter = 'CL_MDC_ADAPTER_BP_DQMM'
              and MDChgProcessSourceModified = ''
              and CityFileTestStatus = 'C'
                then 'A'
        else '' end as mdc_kpi_filter_val
      )   as MDChgProcKPIStdznStatus,

      /* Associations */
      _BPProtectedAddress,
      _BusinessPartner,
      _BusPartAddressProc,
      _RecordType,
      _KPIUpdateStatusText,
      _RecordMessages,
      _Country,
      _Region,
      _AddressRepresentation,
      _FormOfAddress,
      _Step,
      _AddrInfoMgmtOut,
      _StdStatus
}