C_UtilsInstallationHistoryDEX

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Data Extractor for Intstallation History'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #CONSUMPTION
@ObjectModel: {
    supportedCapabilities:  [ #EXTRACTION_DATA_SOURCE ],
    modelingPattern: #NONE,
    sapObjectNodeType: { name: 'UtilitiesInstallation' },
    usageType:  {
      serviceQuality: #X,
      sizeCategory: #XL,
      dataClass: #TRANSACTIONAL
                }
              }
@Analytics: {
      dataCategory: #FACT,
      technicalName: 'CUTILINSTHISTDEX',
      dataExtraction: {
      enabled: true,
      delta.changeDataCapture: {
                                 mapping: [
                                 {
                                 table: 'EANLH', role: #MAIN,
                                 viewElement: [ 'UtilitiesInstallation', 'UtilsInstHistValidityEndDate' ],
                                 tableElement: [ 'anlage', 'bis' ]
                                 },
                                 {
                                 table: 'EANL', role: #LEFT_OUTER_TO_ONE_JOIN,
                                 viewElement: [ 'UtilitiesInstallation' ],
                                 tableElement: [ 'anlage' ]
                                 }
                                          ]
                               }
                       }
           }


define view entity C_UtilsInstallationHistoryDEX
  as select from           I_UtilitiesInstallationHist
    left outer to one join I_UtilitiesInstallation as I_UtilitiesInstallation on I_UtilitiesInstallationHist.UtilitiesInstallation = I_UtilitiesInstallation.UtilitiesInstallation

  association [0..1] to E_UtilitiesInstallation     as _ExtensionInstallation     on  _ExtensionInstallation.UtilitiesInstallation = $projection.UtilitiesInstallation
  association [0..1] to E_UtilitiesInstallationHist as _ExtensionInstallationHist on  _ExtensionInstallationHist.UtilitiesInstallation        = $projection.UtilitiesInstallation
                                                                                  and _ExtensionInstallationHist.UtilsInstHistValidityEndDate = $projection.UtilsInstHistValidityEndDate
{

      @ObjectModel.foreignKey.association: '_UtilitiesInstallation'
  key I_UtilitiesInstallationHist.UtilitiesInstallation,
  key I_UtilitiesInstallationHist.UtilsInstHistValidityEndDate,
      I_UtilitiesInstallationHist.UtilsInstHistValidityStartDate,
      I_UtilitiesInstallationHist.UtilitiesRateCategory,
      I_UtilitiesInstallationHist.UtilitiesBillingSchema,
      I_UtilitiesInstallationHist.UtilitiesBillingClass,
      I_UtilitiesInstallationHist.MeterReadingUnit,
      I_UtilitiesInstallationHist.UtilitiesTemperatureArea,
      @Semantics.booleanIndicator: true
      I_UtilitiesInstallationHist.UtilsInstIsExmptFrmFrnchsFee,
      @Semantics.booleanIndicator: true
      I_UtilitiesInstallationHist.UtilsInstDvceAllctnIsNotAllwd,
      I_UtilitiesInstallationHist.UtilitiesFranchiseContract,
      I_UtilitiesInstallationHist.UtilitiesBillingParty,
      I_UtilitiesInstallationHist.UtilitiesInvoicingParty,
      I_UtilitiesInstallationHist.ObligatorySupUtilsSrvcProvider,
      I_UtilitiesInstallationHist.PrimaryUtilitiesInstallation,
      I_UtilitiesInstallationHist.UtilsInstallationGroupRole,
      I_UtilitiesInstallationHist.UtilsInstallationGroupType,
      I_UtilitiesInstallationHist.HigherLevelUtilsInstallation,
      I_UtilitiesInstallationHist.UnbilldRevnXtrapltnType,
      I_UtilitiesInstallationHist.UtilsRegDepdntValdtnGroup,
      //      I_UtilitiesInstallationHist.IndustrySector,

      I_UtilitiesInstallation.UtilitiesInstallationType,
      I_UtilitiesInstallation.Division,
      I_UtilitiesInstallation.UtilitiesInstVoltageLevel,
      I_UtilitiesInstallation.UtilitiesInstGasPrssrLvl,
      I_UtilitiesInstallation.UtilsInstTimeZone,
      I_UtilitiesInstallation.UtilsInstGuarOfSupReason,
      I_UtilitiesInstallation.UtilsInstDeregulationSts,
      I_UtilitiesInstallation.UtilsInstDataReleaseStatus,
      I_UtilitiesInstallation.UtilitiesSrvcProviderRole,
      @Semantics.booleanIndicator: true
      I_UtilitiesInstallation.UtilsInstIsForEnergyFeedIn,
      I_UtilitiesInstallation.UtilsInstCreationDate,
      I_UtilitiesInstallation.UtilsInstCreatedByUser,
      I_UtilitiesInstallation.UtilsInstLastChangeDate,
      I_UtilitiesInstallation.UtilsInstLastChangedByUser,
      I_UtilitiesInstallation.MeterReadingBlockingReason,
      I_UtilitiesInstallation.MeterReadingBasePeriodCat,
      I_UtilitiesInstallation.NmbrOfAllwdMtrRdngsCntrlCode,
      I_UtilitiesInstallation.AuthorizationGroup,
      I_UtilitiesInstallation.IsMarkedForDeletion,
      I_UtilitiesInstallation.UtilitiesPremise,
      I_UtilitiesInstallation.UtilitiesGeoLocAltitudeValue,
      /* Associations */
      I_UtilitiesInstallationHist._UtilitiesInstallation
}