I_UTILITIESINSTALLATION
Installation
I_UTILITIESINSTALLATION is a CDS View in S/4HANA. Installation. It contains 38 fields. 11 CDS views read from this table.
CDS Views using this table (11)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| CRMS4_IU_I_ILN | view | from | Utilities Installation | |
| CRMS4_IU_P_CONPP | view | left_outer | Conn. Objects, Premise, PoD tuples | |
| CRMS4_IU_P_PODBP | view | inner | Point of Delivery by Business Partner | |
| I_ImplsblMtrRdngMaLrnApply | view | inner | COMPOSITE | Machine Learning Training for Implbl. Mtr. Rdng. |
| I_ImplsblMtrRdngMaLrnTrng | view | inner | COMPOSITE | Machine Learning Training Data for Implausible Meter Reading |
| I_SchedldRdngRelevantRegCube | view | inner | COMPOSITE | Scheduled Reading-Relevant Register Cube |
| I_UtilitiesInstallationVH | view | from | COMPOSITE | Installation Value Help |
| I_UtilitiesLossInstallationVH | view | from | BASIC | ISU BR Engy Loss Installation |
| I_UtilitiesPremiseOwner | view | left_outer | COMPOSITE | Utilities Premise Owner |
| I_UtilsInstallationExtnEnbld | view | from | COMPOSITE | Utilities Installation Extension Enabled |
| I_UtilsInstKeyDateAnalysisC | view | from | COMPOSITE | Key Date - Based Installation Analysis |
Fields (38)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | UtilitiesInstallation | UtilitiesInstallation | 2 |
| KEY | UtilitiesPremise | UtilitiesPremise | 7 |
| _Division | _Division | 1 | |
| _UtilitiesInstallationHist | _UtilitiesInstallationHist | 1 | |
| _UtilitiesPremise | _UtilitiesPremise | 2 | |
| _UtilsAllocOfInstToPoD | _UtilsAllocOfInstToPoD | 1 | |
| _UtilsInstallationType | _UtilsInstallationType | 1 | |
| _UtilsInstCreatedByUser | _UtilsInstCreatedByUser | 1 | |
| _UtilsInstDataReleaseSts | _UtilsInstDataReleaseSts | 1 | |
| _UtilsInstDeregulationSts | _UtilsInstDeregulationSts | 1 | |
| _UtilsInstGasPressureLvl | _UtilsInstGasPressureLvl | 1 | |
| _UtilsInstGuarOfSupRsn | _UtilsInstGuarOfSupRsn | 1 | |
| _UtilsInstLastChangedByUser | _UtilsInstLastChangedByUser | 1 | |
| _UtilsInstVltgLevel | _UtilsInstVltgLevel | 1 | |
| _UtilsMtrRdngBasePerdCat | _UtilsMtrRdngBasePerdCat | 1 | |
| _UtilsMtrRdngBlockReason | _UtilsMtrRdngBlockReason | 1 | |
| _UtilsNmbrOfAllwdMRCtrlCode | _UtilsNmbrOfAllwdMRCtrlCode | 1 | |
| _UtilsServiceProviderRole | _UtilsServiceProviderRole | 1 | |
| AuthorizationGroup | AuthorizationGroup | 3 | |
| Division | Division | 3 | |
| IsMarkedForDeletion | IsMarkedForDeletion | 2 | |
| MeterReadingBasePeriodCat | MeterReadingBasePeriodCat | 2 | |
| MeterReadingBlockingReason | MeterReadingBlockingReason | 2 | |
| NmbrOfAllwdMtrRdngsCntrlCode | NmbrOfAllwdMtrRdngsCntrlCode | 2 | |
| UtilitiesGeoLocAltitudeValue | UtilitiesGeoLocAltitudeValue | 1 | |
| UtilitiesInstallationType | UtilitiesInstallationType | 2 | |
| UtilitiesInstGasPrssrLvl | UtilitiesInstGasPrssrLvl | 2 | |
| UtilitiesInstVoltageLevel | UtilitiesInstVoltageLevel | 2 | |
| UtilitiesSrvcProviderRole | UtilitiesSrvcProviderRole | 2 | |
| UtilsInstCreatedByUser | UtilsInstCreatedByUser | 2 | |
| UtilsInstCreationDate | UtilsInstCreationDate | 2 | |
| UtilsInstDataReleaseStatus | UtilsInstDataReleaseStatus | 2 | |
| UtilsInstDeregulationSts | UtilsInstDeregulationSts | 2 | |
| UtilsInstGuarOfSupReason | UtilsInstGuarOfSupReason | 2 | |
| UtilsInstIsForEnergyFeedIn | UtilsInstIsForEnergyFeedIn | 4 | |
| UtilsInstLastChangeDate | UtilsInstLastChangeDate | 2 | |
| UtilsInstLastChangedByUser | UtilsInstLastChangedByUser | 2 | |
| UtilsInstTimeZone | UtilsInstTimeZone | 2 |
@EndUserText.label: 'Installation'
@Analytics.dataCategory: #DIMENSION
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.representativeKey: 'UtilitiesInstallation'
@AbapCatalog.sqlViewName: 'IEINSTALLATION'
//@AbapCatalog.preserveKey: true
@ObjectModel.usageType.serviceQuality: 'B'
@ObjectModel.usageType.sizeCategory: 'L'
@ObjectModel.usageType.dataClass: 'MASTER'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #ANALYTICAL_DIMENSION, #ANALYTICAL_PROVIDER, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE ]
@AbapCatalog.compiler.compareFilter:true
//Privileged associations specified
@AccessControl.privilegedAssociations: [ '_UtilsInstCreatedByUser', '_UtilsInstLastChangedByUser' ]
@Metadata.allowExtensions: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
define view I_UtilitiesInstallation
as select from eanl
association [1..*] to I_UtilitiesInstallationHist as _UtilitiesInstallationHist on $projection.UtilitiesInstallation = _UtilitiesInstallationHist.UtilitiesInstallation
association [0..1] to I_UtilsNmbrOfAllwdMRCtrlCode as _UtilsNmbrOfAllwdMRCtrlCode on $projection.NmbrOfAllwdMtrRdngsCntrlCode = _UtilsNmbrOfAllwdMRCtrlCode.NmbrOfAllwdMtrRdngsCntrlCode
/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ] } */
association [0..1] to I_UtilsMtrRdngBasePerdCat as _UtilsMtrRdngBasePerdCat on $projection.MeterReadingBasePeriodCat = _UtilsMtrRdngBasePerdCat.MeterReadingBasePeriodCat
association [0..1] to I_UtilsMtrRdngBlockReason as _UtilsMtrRdngBlockReason on $projection.MeterReadingBlockingReason = _UtilsMtrRdngBlockReason.MeterReadingBlockingReason
association [0..1] to I_UtilsServiceProviderRole as _UtilsServiceProviderRole on $projection.UtilitiesSrvcProviderRole = _UtilsServiceProviderRole.UtilitiesSrvcProviderRole
association [0..1] to I_UtilsInstDataReleaseSts as _UtilsInstDataReleaseSts on $projection.UtilsInstDataReleaseStatus = _UtilsInstDataReleaseSts.UtilsInstDataReleaseStatus
association [0..1] to I_UtilsInstDeregulationSts as _UtilsInstDeregulationSts on $projection.UtilsInstDeregulationSts = _UtilsInstDeregulationSts.UtilsInstDeregulationSts
association [0..1] to I_UtilsInstGuarOfSupRsn as _UtilsInstGuarOfSupRsn on $projection.UtilsInstGuarOfSupReason = _UtilsInstGuarOfSupRsn.UtilsInstGuarOfSupReason
association [0..1] to I_UtilsInstGasPressureLvl as _UtilsInstGasPressureLvl on $projection.UtilitiesInstGasPrssrLvl = _UtilsInstGasPressureLvl.UtilitiesInstGasPrssrLvl
association [0..1] to I_UtilsInstVltgLevel as _UtilsInstVltgLevel on $projection.UtilitiesInstVoltageLevel = _UtilsInstVltgLevel.UtilitiesInstVoltageLevel
association [0..1] to I_Division as _Division on $projection.Division = _Division.Division
association [0..1] to I_UtilsInstallationType as _UtilsInstallationType on $projection.UtilitiesInstallationType = _UtilsInstallationType.UtilitiesInstallationType
/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ] } */
association [0..1] to I_User as _UtilsInstCreatedByUser on $projection.UtilsInstCreatedByUser = _UtilsInstCreatedByUser.UserID
association [0..1] to I_User as _UtilsInstLastChangedByUser on $projection.UtilsInstLastChangedByUser = _UtilsInstLastChangedByUser.UserID
association [0..1] to I_UtilitiesPremise as _UtilitiesPremise on $projection.UtilitiesPremise = _UtilitiesPremise.UtilitiesPremise
association [0..*] to I_UtilsAllocOfInstToPoD as _UtilsAllocOfInstToPoD on $projection.UtilitiesInstallation = _UtilsAllocOfInstToPoD.UtilitiesInstallation
{
key eanl.anlage as UtilitiesInstallation,
@ObjectModel.foreignKey.association: '_UtilsInstallationType'
eanl.anlart as UtilitiesInstallationType,
@ObjectModel.foreignKey.association: '_Division'
eanl.sparte as Division,
@ObjectModel.foreignKey.association: '_UtilsInstVltgLevel'
eanl.spebene as UtilitiesInstVoltageLevel,
@ObjectModel.foreignKey.association: '_UtilsInstGasPressureLvl'
eanl.drckstuf as UtilitiesInstGasPrssrLvl,
eanl.etimezone as UtilsInstTimeZone,
@ObjectModel.foreignKey.association: '_UtilsInstGuarOfSupRsn'
eanl.nodisconct as UtilsInstGuarOfSupReason,
@ObjectModel.foreignKey.association: '_UtilsInstDeregulationSts'
eanl.deregstat as UtilsInstDeregulationSts,
@ObjectModel.foreignKey.association: '_UtilsInstDataReleaseSts'
eanl.inforel as UtilsInstDataReleaseStatus,
@ObjectModel.foreignKey.association: '_UtilsServiceProviderRole'
eanl.service as UtilitiesSrvcProviderRole,
@Semantics.booleanIndicator: true
eanl.bezug as UtilsInstIsForEnergyFeedIn,
@Semantics.businessDate.at: true
eanl.erdat as UtilsInstCreationDate,
@Semantics.user.createdBy: true
eanl.ernam as UtilsInstCreatedByUser,
@Semantics.systemDate.lastChangedAt: true
eanl.aedat as UtilsInstLastChangeDate,
@Semantics.user.lastChangedBy: true
eanl.aenam as UtilsInstLastChangedByUser,
@ObjectModel.foreignKey.association: '_UtilsMtrRdngBlockReason'
eanl.ablsperr as MeterReadingBlockingReason,
@ObjectModel.foreignKey.association: '_UtilsMtrRdngBasePerdCat'
eanl.bapertyp as MeterReadingBasePeriodCat,
@ObjectModel.foreignKey.association: '_UtilsNmbrOfAllwdMRCtrlCode'
eanl.ablesartst as NmbrOfAllwdMtrRdngsCntrlCode,
eanl.begru as AuthorizationGroup,
eanl.loevm as IsMarkedForDeletion,
@ObjectModel.foreignKey.association: '_UtilitiesPremise'
eanl.vstelle as UtilitiesPremise,
eanl.altitude as UtilitiesGeoLocAltitudeValue,
/* Associations */
_UtilsNmbrOfAllwdMRCtrlCode,
_UtilsMtrRdngBasePerdCat,
_UtilsMtrRdngBlockReason,
_UtilsServiceProviderRole,
_UtilsInstDataReleaseSts,
_UtilsInstDeregulationSts,
_UtilsInstGuarOfSupRsn,
_UtilsInstGasPressureLvl,
_UtilsInstVltgLevel,
_Division,
_UtilsInstallationType,
_UtilsInstCreatedByUser,
_UtilsInstLastChangedByUser,
_UtilitiesInstallationHist,
_UtilitiesPremise,
_UtilsAllocOfInstToPoD
}