C_SourcingProjectQuotationVH

DDL: C_SOURCINGPROJECTQUOTATIONVH Type: view_entity CONSUMPTION

Quotation for Sourcing Project

C_SourcingProjectQuotationVH is a Consumption CDS View that provides data about "Quotation for Sourcing Project" in SAP S/4HANA. It reads from 1 data source (R_SourcingProjectQuotationTP) and exposes 15 fields with key field SourcingProjectQuotationUUID. It is exposed through 1 OData service (UI_SRCGPROJQUOTATION_MANAGE).

1 data source(s) Exposed by 1 service(s) 15 fields

Data Sources (1)

SourceAliasJoin Type
R_SourcingProjectQuotationTP R_SourcingProjectQuotationTP from

Annotations (11)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.representativeKey SourcingProjectQuotationUUID view
VDM.viewType #CONSUMPTION view
Search.searchable true view
Consumption.ranked true view
EndUserText.label Quotation for Sourcing Project view

OData Services (1)

ServiceBindingVersionContractRelease
UI_SRCGPROJQUOTATION_MANAGE UI_SRCGPROJQTN_MANAGE V2 C1 NOT_RELEASED

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY SourcingProjectQuotationUUID SourcingProjectQuotationUUID
SourcingProjectQuotation SourcingProjectQuotation
SrcgProjQuotationVersion SrcgProjQuotationVersion
SourcingProjectQuotationName
SourcingProject _SourcingProject SourcingProject
SourcingProjectVersion _SourcingProject SourcingProjectVersion
SourcingProjectName
PurchasingOrganization PurchasingOrganization
PurchasingGroup PurchasingGroup
SourcingProjectQuotationType SourcingProjectQuotationType
CompanyCode CompanyCode
MaterialGroup MaterialGroup
IsEndOfPurposeBlocked IsEndOfPurposeBlocked
SourcingProjectUUID SourcingProjectUUID
Bidder Bidder 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY //#NOT_REQUIRED


@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType:{ serviceQuality: #C,
                         sizeCategory: #M,
                         dataClass: #MIXED
}
@ObjectModel.dataCategory:#VALUE_HELP
@ObjectModel.semanticKey: ['SourcingProjectQuotation']
@ObjectModel.representativeKey: 'SourcingProjectQuotationUUID'
@VDM.viewType: #CONSUMPTION

@Search.searchable: true
@Consumption.ranked: true

@EndUserText.label: 'Quotation for Sourcing Project'
define view entity C_SourcingProjectQuotationVH
  as select from R_SourcingProjectQuotationTP
{
      @UI.hidden: true
  key SourcingProjectQuotationUUID,
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      @ObjectModel.text.element: [ 'SourcingProjectQuotationName' ]
      SourcingProjectQuotation,
      SrcgProjQuotationVersion,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( SourcingProjectQuotationName as vdm_srcgprojquotationnamelong preserving type )       as SourcingProjectQuotationName,
      @ObjectModel.text.element: [ 'SourcingProjectName' ]
      @Consumption.filter.hidden: true
      _SourcingProject.SourcingProject,
      @Consumption.filter.hidden: true
      _SourcingProject.SourcingProjectVersion,
      @Semantics.text: true
      @Consumption.filter.hidden: true
      cast( _SourcingProject.SourcingProjectName as vdm_sourcingprojectnamelong preserving type ) as SourcingProjectName,
      @UI.hidden: true
      PurchasingOrganization,
      @UI.hidden: true
      PurchasingGroup,
      @UI.hidden: true
      SourcingProjectQuotationType,
      @UI.hidden: true
      CompanyCode,
      @UI.hidden: true
      MaterialGroup,
      @UI.hidden: true
      @Semantics.booleanIndicator: true
      IsEndOfPurposeBlocked,
      @Consumption.filter.hidden: true
      @UI.hidden               : true
      SourcingProjectUUID,
      @Consumption.filter.hidden: true
      @UI.hidden               : true
      Bidder
}

Learn More