R_SOURCINGPROJECTQUOTATIONTP

CDS View

Quotation for Sourcing Project - TP

R_SOURCINGPROJECTQUOTATIONTP is a CDS View in S/4HANA. Quotation for Sourcing Project - TP. 5 CDS views read from this table.

Used by 5 CDS view(s)

CDS Views using this table (5)

ViewTypeJoinVDMDescription
A_SourcingProjectQuotation view_entity projection CONSUMPTION Supplier Quotation for Sourcing Project
C_SourcingProjectQuotationTP view_entity projection CONSUMPTION Quotation for Sourcing Project - TP
C_SourcingProjectQuotationVH view_entity from CONSUMPTION Quotation for Sourcing Project
ESH_N_SOURCINGPROJECTQUOTATION view from
I_SourcingProjectQuotationTP view_entity projection TRANSACTIONAL Quotation for Sourcing Project - TP 
@AccessControl: {
  authorizationCheck: #MANDATORY,
  privilegedAssociations: [ '_CreatedByUser', '_ChangedByUser']
}

@ObjectModel:{representativeKey: 'SourcingProjectQuotationUUID',
              semanticKey: ['SrcgProjQuotationVersion', 'SourcingProjectQuotation'],

              usageType: {
                dataClass: #TRANSACTIONAL,
                serviceQuality: #A,
                sizeCategory: #M
              },
              sapObjectNodeType.name: 'SourcingProjectQuotation'
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@EndUserText.label: 'Quotation for Sourcing Project - TP'
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  allowNewDatasources: false,
  elementSuffix: 'SQH',
  quota: { maximumFields: 404,
           maximumBytes: 40400 },
  allowNewCompositions: true }

define root view entity R_SourcingProjectQuotationTP
  as select from R_SourcingProjectQuotation
  composition [*] of R_SrcgProjQtnItemTP             as _SrcgProjQtnItem
  composition [*] of R_SrcgProjQtnAllowedCurrencyTP  as _SrcgProjQtnAllowedCurrency
  composition [*] of R_SrcgProjQtnSupplierContactTP  as _SrcgProjQtnSupplierContact
  composition [*] of R_SrcgProjQtnNoteTP             as _SrcgProjQtnNote

  association [0..1] to R_SourcingProjectNegotiation as _SourcingProjectNegotiation on $projection.SourcingProjectNegotiationUUID = _SourcingProjectNegotiation.SourcingProjectNegotiationUUID
  association [0..*] to I_SrcgProjQtnSuitabilityTxt  as _SrcgProjQtnSuitabilityTxt  on $projection.SrcgProjQtnSuitability = _SrcgProjQtnSuitabilityTxt.SrcgProjQtnSuitability
  association [0..*] to I_SrcgProjSourcingOriginText as _SrcgProjSourcingOriginText on $projection.SourcingOrigin = _SrcgProjSourcingOriginText.SourcingOrigin
  association [0..*] to I_CurrencyText               as _OfferCurrencyText          on $projection.SrcgProjQtnOfferCurrency = _OfferCurrencyText.Currency
  association [0..*] to I_MaterialGroupText          as _MaterialGroupText          on $projection.MaterialGroup = _MaterialGroupText.MaterialGroup
  association [0..*] to I_SourcingProjectTypeText    as _SourcingProjectTypeText    on $projection.SourcingProjectQuotationType = _SourcingProjectTypeText.SourcingProjectType
  
  //Extension

  association [1..1] to E_SourcingProjectQuotation   as _Extension                  on $projection.SourcingProjectQuotationUUID = _Extension.SourcingProjectQuotationUUID

{
  key SourcingProjectQuotationUUID,
      SourcingProjectQuotation,
      SrcgProjQuotationVersion,
      SourcingProjectQuotationType,
      SourcingProjectQuotationName,
      SrcgProjQuotationIsSimulated,
      Bidder,
      CompanyCode,
      PurchasingGroup,
      PurchasingOrganization,
      SrcgProjQtnOfferCurrency,
      SrcgProjQtnTotNetAmt,
      SrcgProjQtnLifecycleStatus,
      SrcgProjQtnRevisionSts,
      SrcgProjQtnActvtnSts,
      SrcgProjQtnSubmsnSts,
      SrcgProjQtnAwardingStatus,
      SourcingProjectUUID,
      SourcingProjectNegotiationUUID,
      PricingProcedure,
      LastChangedByUser,
      CreatedByUser,
      LastChangeDateTime,
      CreationDateTime,
      SrcgProjAttchsAreForbidden,
      SrcgProjNotesAreForbidden,
      SourcingOrigin,
      ExternalSourcingProjectQtnRef,
      QtnLatestSubmissionDateTime,
      LogicalSystem,
      SourceSrcgProjQuotationUUID,
      IsEndOfPurposeBlocked,
      CashDiscount1Days,
      CashDiscount2Days,
      CashDiscount1Percent,
      CashDiscount2Percent,
      NetPaymentDays,
      MaterialGroup,
      SourcingAwardingDate,
      SrcgProjQtnSuitability,
      _SourcingProjectNegotiation.SourcingProjectNegotiationType,
      //Required for the ECM Integration

      cast( concat(SourcingProjectQuotation,
             concat('/' ,cast(SrcgProjQuotationVersion as abap.char(10))))
              as vdm_sourcingprojectuniqueid ) as LglCntntMLinkdObj,
      cast( '' as vdm_spqtntypeisnotauthorized preserving type )   as SrcgProjQtnTypeIsNotAuthorized,
      cast( '' as vdm_purgorgisnotauthorized preserving type  )    as PurgOrgIsNotAuthorized,
      cast( '' as vdm_purggroupisnotauthorized preserving type )   as PurgGroupIsNotAuthorized,
      cast( '' as vdm_companycodeisnotauthorized preserving type ) as CompanyCodeIsNotAuthorized,
      cast( '' as vdm_matlgroupisnotauthorized preserving type )   as MaterialGroupIsNotAuthorized,
      /* Associations */
      _BusinessPartner,
      _CompanyCode,
      _PurchasingGroup,
      _PurchasingOrganization,
      _SourcingProject,
      _SrcgProjQtnItem,
      _SrcgProjQtnAllowedCurrency,
      _SrcgProjQtnLifecycleSts,
      _SrcgProjQtnOfferCurrency,
      _SrcgProjQtnSupplierContact,
      _SrcgProjQtnSuitabilityTxt,
      _SrcgProjQtnNote,
      _DeviationPercentUnit,
      //tbd

      _CreatedByUser,
      _ChangedByUser,
      _MaterialGroup,
      _SourcingProjectNegotiation,
      _SourceSrcgProjQuotation,
      _SrcgProjSourcingOriginText,
      _OfferCurrencyText,
      _MaterialGroupText,
      _SourcingProjectTypeText
}

Learn More