C_SalesDocumentUserVH

@AbapCatalog: {
   sqlViewName: 'CSDUSERVH',
   compiler.compareFilter: true
}

@ClientDependent: true
@AccessControl:{
  authorizationCheck: #CHECK,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@EndUserText.label: 'Sales Document User'
@Search.searchable: true
@Consumption.ranked: true

@VDM: {
  viewType: #CONSUMPTION
}
@ObjectModel:{
  usageType:{
    dataClass: #TRANSACTIONAL,
    serviceQuality: #A,
    sizeCategory: #S
  }
}

@UI.headerInfo:{
  typeName:       'Sales Document User',
  typeNamePlural: 'Sales Document Users'
}

@ObjectModel.representativeKey: 'UserID'

@UI.presentationVariant:{
    sortOrder: [
        { by: 'UserID', direction: #ASC },
        { by: 'UserDescription', direction: #ASC }]
}
define view C_SalesDocumentUserVH
  as select from I_User 
     association [0..*] to I_SalesDocumentBasic as _SalesDocument on UserID = _SalesDocument.CreatedByUser or
                                                                     UserID = _SalesDocument.LastChangedByUser
{
      
      @ObjectModel.text.element:  [ 'UserDescription' ]
      @Search: {
       defaultSearchElement: true,
       ranking: #HIGH,
       fuzzinessThreshold: 0.9
      }
  key UserID,
      @Semantics.text: true
      @Search: {
       defaultSearchElement: true,
       ranking: #LOW,
       fuzzinessThreshold: 0.9
      }
      UserDescription,
      
      // For Access control

      _SalesDocument
}