C_PurchaseRequisitionValueHelp

DDL: C_PURCHASEREQUISITIONVALUEHELP SQL: CPURREQN_VH Type: view CONSUMPTION

Purchase Requisition Value Help

C_PurchaseRequisitionValueHelp is a Consumption CDS View that provides data about "Purchase Requisition Value Help" in SAP S/4HANA. It reads from 1 data source (I_Purchaserequisitionitem) and exposes 11 fields with key fields PurchaseRequisition, PurchaseRequisitionItem. It has 2 associations to related views.

1 data source(s) 11 fields

Data Sources (1)

SourceAliasJoin Type
I_Purchaserequisitionitem PurchaseRequisitionItem from

Associations (2)

CardinalityTargetAliasCondition
[0..*] I_MaterialText _MaterialText $projection.Material = _MaterialText.Material
[0..1] I_Plant _Plant $projection.Plant = _Plant.Plant

Annotations (13)

NameValueLevelField
AbapCatalog.sqlViewName CPURREQN_VH view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
VDM.viewType #CONSUMPTION view
Search.searchable true view
ObjectModel.representativeKey PurchaseRequisition view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
EndUserText.label Purchase Requisition Value Help view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.dataCategory #VALUE_HELP view
Consumption.ranked true view

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY PurchaseRequisition I_Purchaserequisitionitem PurchaseRequisition
KEY PurchaseRequisitionItem I_Purchaserequisitionitem PurchaseRequisitionItem
PurchaseRequisitionItemText I_Purchaserequisitionitem PurchaseRequisitionItemText
ProcessingStatus I_Purchaserequisitionitem ProcessingStatus
Material I_Purchaserequisitionitem Material
Plant I_Purchaserequisitionitem Plant
PlantName _Plant PlantName
PurchasingOrganization I_Purchaserequisitionitem PurchasingOrganization
PurchasingGroup I_Purchaserequisitionitem PurchasingGroup
PurchaseRequisitionType I_Purchaserequisitionitem PurchaseRequisitionType
_MaterialText _MaterialText 
@AbapCatalog.sqlViewName: 'CPURREQN_VH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@ObjectModel.semanticKey: ['PurchaseRequisition', 'PurchaseRequisitionItem']
@ObjectModel.representativeKey: 'PurchaseRequisition'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@EndUserText.label: 'Purchase Requisition Value Help'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.dataCategory: #VALUE_HELP
@Consumption.ranked: true

define view C_PurchaseRequisitionValueHelp
  as select from I_Purchaserequisitionitem as PurchaseRequisitionItem

  association [0..*] to I_MaterialText as _MaterialText on $projection.Material = _MaterialText.Material

  association [0..1] to I_Plant        as _Plant        on $projection.Plant = _Plant.Plant

{

      @Search: { defaultSearchElement: true, ranking: #HIGH }
  key PurchaseRequisitionItem.PurchaseRequisition         as PurchaseRequisition,
      
      @Search: { defaultSearchElement: true, ranking: #HIGH }
  key PurchaseRequisitionItem.PurchaseRequisitionItem     as PurchaseRequisitionItem,

      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      PurchaseRequisitionItem.PurchaseRequisitionItemText as PurchaseRequisitionItemText,
      
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      PurchaseRequisitionItem.ProcessingStatus            as ProcessingStatus,

      @ObjectModel.text.association: '_MaterialText'
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      PurchaseRequisitionItem.Material                    as Material,

      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      PurchaseRequisitionItem.Plant                       as Plant,
      
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      _Plant.PlantName,
      
      @UI.hidden: true
      PurchaseRequisitionItem.PurchasingOrganization,
      @UI.hidden: true
      PurchaseRequisitionItem.PurchasingGroup,
      @UI.hidden: true
      PurchaseRequisitionItem.PurchaseRequisitionType,
      _MaterialText

}

Learn More