I_PURCHASEREQUISITIONITEM

@EndUserText.label: 'Purchase Requisition Item'
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'IPRITEM'
@AbapCatalog.preserveKey:true
//@Analytics.dataCategory: #DIMENSION

@AccessControl.authorizationCheck:#CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'PurchaseRequisitionItem'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
//@AccessControl.privilegedAssociations:  [ '_ExtRefForPurReqnItm' ]

@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@Consumption.semanticObject: 'PurchaseRequisition'

define view I_Purchaserequisitionitem
  as select from I_PurchaseRequisitionItemBasic

  association [0..*] to I_PurReqnAcctAssgmt          as _PurReqnAcctAssgmt         on  $projection.PurchaseRequisition     = _PurReqnAcctAssgmt.PurchaseRequisition
                                                                                   and $projection.PurchaseRequisitionItem = _PurReqnAcctAssgmt.PurchaseRequisitionItem

  association [0..1] to I_PurchaseOrder              as _PurchaseOrder             on  $projection.PurchasingDocument = _PurchaseOrder.PurchaseOrder

  association [1..1] to I_PurchasingDocumentType     as _PurchasingDocumentType    on  _PurchasingDocumentType.PurchasingDocumentCategory = 'B'
                                                                                   and $projection.PurchaseRequisitionType                = _PurchasingDocumentType.PurchasingDocumentType

  association [0..1] to I_Supplier                   as _Supplier                  on  $projection.FixedSupplier = _Supplier.Supplier

  association [0..1] to I_Supplier                   as _DesiredSupplier           on  $projection.Supplier = _DesiredSupplier.Supplier //Added for ESH Modeling


  association [0..1] to I_PurchasingOrganization     as _PurchasingOrganization    on  $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization

  association [0..1] to I_PurchasingGroup            as _PurchasingGroup           on  $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup

  association [0..1] to I_Currency                   as _Currency                  on  $projection.PurReqnItemCurrency = _Currency.Currency

  association [0..1] to I_Plant                      as _SupplyingPlant            on  $projection.SupplyingPlant = _SupplyingPlant.Plant

  association [1..1] to I_MRPArea                    as _MRPArea                   on  $projection.MRPArea = _MRPArea.MRPArea

  association [1..1] to I_AccAssgnmtCategory         as _AccAssgnmtCategory        on  $projection.AccountAssignmentCategory = _AccAssgnmtCategory.AccountAssignmentCategory

  association [0..1] to I_Material                   as _Material                  on  $projection.Material = _Material.Material

  association [0..1] to I_MaterialGroup              as _MaterialGroup             on  $projection.MaterialGroup = _MaterialGroup.MaterialGroup

  association [0..1] to I_Plant                      as _Plant                     on  $projection.Plant = _Plant.Plant

  association [0..1] to I_Address                    as _Address                   on  $projection.ManualDeliveryAddressID = _Address.AddressID

  association [0..1] to I_OrganizationAddress        as _OrganizationAddress       on  $projection.ManualDeliveryAddressID  = _OrganizationAddress.AddressID
                                                                                   and _OrganizationAddress.AddressPersonID           = ''
                                                                                   and _OrganizationAddress.AddressRepresentationCode = ''

  association [1..1] to I_UnitOfMeasure              as _UnitOfMeasure             on  $projection.BaseUnit = _UnitOfMeasure.UnitOfMeasure

  association [0..1] to I_StorageLocation            as _StorageLocation           on  $projection.StorageLocation = _StorageLocation.StorageLocation
                                                                                   and $projection.Plant           = _StorageLocation.Plant

  association [0..1] to I_PurchasingInfoRecord       as _PurchasingInfoRecord      on  $projection.PurchasingInfoRecord = _PurchasingInfoRecord.PurchasingInfoRecord

  association [1..1] to I_Purchaserequisition        as _PurchaseRequisition       on  $projection.PurchaseRequisition = _PurchaseRequisition.PurchaseRequisition

  association [1..1] to I_PurchaseReqnItemCalcFields as _CalcFields                on  $projection.PurchaseRequisition     = _CalcFields.PurchaseRequisition
                                                                                   and $projection.PurchaseRequisitionItem = _CalcFields.PurchaseRequisitionItem
  association [0..1] to I_ExternalRefForPurReqnItm   as _ExtRefForPurReqnItm       on  $projection.PurchaseRequisition     = _ExtRefForPurReqnItm.PurchaseRequisition
                                                                                   and $projection.PurchaseRequisitionItem = _ExtRefForPurReqnItm.PurchaseRequisitionItem
  
  association [0..1] to I_BackendSourceSystem        as _BackendSourceSystem       on  $projection.ProcurementHubSourceSystem = _BackendSourceSystem.ProcurementHubSourceSystem

  association [0..1] to I_User                       as _User                      on  $projection.CreatedByUser = _User.UserID //Added for ESH Modeling


  association [1..1] to P_PlantValuationArea         as _PlantValuationArea        on  $projection.Plant = _PlantValuationArea.Plant

  association [1..1] to P_PurReqnItemNetAmt          as _ItemNetAmt                on  $projection.PurchaseRequisition     = _ItemNetAmt.PurchaseRequisition
                                                                                   and $projection.PurchaseRequisitionItem = _ItemNetAmt.PurchaseRequisitionItem

  association [1..1] to I_FundedProgramByPurReqnItem as _FundedProgram             on  $projection.PurchaseRequisition     = _FundedProgram.PurchaseRequisition
                                                                                   and $projection.PurchaseRequisitionItem = _FundedProgram.PurchaseRequisitionItem
  ----Extension Association
  association [0..1] to E_Purchaserequisitionitem    as _PurchaseReqnItemExtension on  _PurchaseReqnItemExtension.PurchaseRequisition     = $projection.PurchaseRequisition
                                                                                   and _PurchaseReqnItemExtension.PurchaseRequisitionItem = $projection.PurchaseRequisitionItem                                                                                
{
      @ObjectModel.foreignKey.association: '_PurchaseRequisition'
  key cast (PurchaseRequisition as vdm_purchaserequisition preserving type )         as PurchaseRequisition,

  key cast (PurchaseRequisitionItem as vdm_purchaserequisitionitem preserving type ) as PurchaseRequisitionItem,

      PurReqnDescription                                                             as PurReqnDescription,

      PurchasingDocument                                                             as PurchasingDocument,

      PurchasingDocumentItem                                                         as PurchasingDocumentItem,

      PurReqnReleaseStatus                                                           as PurReqnReleaseStatus,

      PurchaseRequisitionType                                                        as PurchaseRequisitionType,

      PurchasingDocumentSubtype                                                      as PurchasingDocumentSubtype,

      PurchasingDocumentItemCategory                                                 as PurchasingDocumentItemCategory,

      PurchaseRequisitionItemText                                                    as PurchaseRequisitionItemText,

      AccountAssignmentCategory                                                      as AccountAssignmentCategory,

      PurchasingDocumentCategory                                                     as PurchasingDocumentCategory,

      IsOutline                                                                      as IsOutline,

      PurchasingParentItem                                                           as PurchasingParentItem,

      PurReqnItemOutlineType                                                         as PurReqnItemOutlineType,
      PurgConfigurableItemNumber                                                     as PurgConfigurableItemNumber,
      PurgExternalSortNumber                                                         as PurgExternalSortNumber,

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @DefaultAggregation: #NONE
      RequestedQuantity                                                              as RequestedQuantity,

      @ObjectModel.foreignKey.association: '_UnitOfMeasure'
      @Semantics.unitOfMeasure: true
      BaseUnit                                                                       as BaseUnit,

      @ObjectModel.foreignKey.association: '_Currency'
      @Semantics.currencyCode: true
      PurReqnItemCurrency                                                            as PurReqnItemCurrency, //2846005


      @Semantics.amount.currencyCode: 'PurReqnItemCurrency'
      @DefaultAggregation: #NONE
      PurchaseRequisitionPrice                                                       as PurchaseRequisitionPrice,

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @DefaultAggregation: #NONE
      PurReqnPriceQuantity                                                           as PurReqnPriceQuantity,

      ReleaseCode                                                                    as ReleaseCode,

      @Semantics.businessDate.at:true
      PurchaseRequisitionReleaseDate                                                 as PurchaseRequisitionReleaseDate,

      PurchasingOrganization                                                         as PurchasingOrganization,

      PurchasingGroup                                                                as PurchasingGroup,

      Plant                                                                          as Plant,

      SourceOfSupplyIsAssigned                                                       as SourceOfSupplyIsAssigned,

      SupplyingPlant                                                                 as SupplyingPlant,

      ProcuringPlant                                                                 as ProcuringPlant,

      Material                                                                       as Material,

      ManufacturerMaterial                                                           as ManufacturerMaterial,

      ManufacturerPartProfile                                                        as ManufacturerPartProfile,

      ManufacturerPartNmbr                                                           as ManufacturerPartNmbr,

      MaterialGroup                                                                  as MaterialGroup,

      MaterialGoodsReceiptDuration                                                   as MaterialGoodsReceiptDuration,

      SupplierMaterialNumber                                                         as SupplierMaterialNumber,

      MaterialRevisionLevel                                                          as MaterialRevisionLevel,

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      OrderedQuantity                                                                as OrderedQuantity,
      @Semantics.amount.currencyCode: 'PurReqnItemCurrency'
      PurReqnLimitConsumptionAmt                                                     as PurReqnLimitConsumptionAmt,

      DeliveryDate                                                                   as DeliveryDate,

      @Semantics.businessDate.at:true
      CreationDate                                                                   as CreationDate,

      LastChangedDate                                                                as LastChangedDate,

      ProcessingStatus                                                               as ProcessingStatus,

      PurchasingInfoRecord                                                           as PurchasingInfoRecord,

      Supplier                                                                       as Supplier,

      FixedSupplier                                                                  as FixedSupplier,

      IsDeleted                                                                      as IsDeleted,

      RequisitionerName                                                              as RequisitionerName,

      CreatedByUser                                                                  as CreatedByUser,

      PurReqCreationDate                                                             as PurReqCreationDate,

      AddressID                                                                      as AddressID,

      case
       when ManualDeliveryAddressID != '' then ManualDeliveryAddressID
       else _Plant.AddressID
      end                                                                            as DeliveryAddressID,

      ManualDeliveryAddressID                                                        as ManualDeliveryAddressID,

      MaterialPlannedDeliveryDurn                                                    as MaterialPlannedDeliveryDurn,

      DelivDateCategory                                                              as DelivDateCategory,

      MultipleAcctAssgmtDistribution                                                 as MultipleAcctAssgmtDistribution,

      ItemDeliveryAddressID                                                          as ItemDeliveryAddressID,

      PartialInvoiceDistribution                                                     as PartialInvoiceDistribution,

      StorageLocation                                                                as StorageLocation,

      PurReqnSSPRequestor                                                            as PurReqnSSPRequestor,

      PurReqnSSPAuthor                                                               as PurReqnSSPAuthor,

      PurchaseContract                                                               as PurchaseContract,

      PurReqnSourceOfSupplyType                                                      as PurReqnSourceOfSupplyType,

      PurchaseContractItem                                                           as PurchaseContractItem,

      ConsumptionPosting                                                             as ConsumptionPosting,

      PurReqnOrigin                                                                  as PurReqnOrigin,

      PurReqnSSPCatalog                                                              as PurReqnSSPCatalog,

      PurReqnSSPCatalogItem                                                          as PurReqnSSPCatalogItem,

      PurReqnSSPCrossCatalogItem                                                     as PurReqnSSPCrossCatalogItem,

      IsPurReqnBlocked                                                               as IsPurReqnBlocked,

      PurReqnItemBlockingReasonText                                                  as PurReqnItemBlockingReasonText,

      Language                                                                       as Language,

      IsClosed                                                                       as IsClosed,

      Reservation                                                                    as Reservation,

      ReleaseIsNotCompleted                                                          as ReleaseIsNotCompleted,

      ServicePerformer                                                               as ServicePerformer,

      //      ProductType                                                                    as ProductType,


      cast ( ProductTypeCode as product_type )                                       as ProductType,

      PurchaseRequisitionStatus                                                      as PurchaseRequisitionStatus,

      ReleaseStrategy                                                                as ReleaseStrategy,

      PerformancePeriodStartDate                                                     as PerformancePeriodStartDate,

      PerformancePeriodEndDate                                                       as PerformancePeriodEndDate,

      _PlantValuationArea.CompanyCode                                                as CompanyCode, // CC is Filled in case if valuation area is CC


      _Plant.ValuationArea                                                           as ValuationArea,

      Batch                                                                          as Batch,

      MinRemainingShelfLife                                                          as MinRemainingShelfLife,

      @Semantics.amount.currencyCode: 'PurReqnItemCurrency'
      case
          when _ItemNetAmt .ItemNetAmount > 9999999999999.99
          then fltp_to_dec(9999999999999.99 as abap.curr(15,2) )
      else
          cast( _ItemNetAmt.ItemNetAmount as abap.curr(15,2) )
          end                                                                        as ItemNetAmount,

      GoodsReceiptIsExpected                                                         as GoodsReceiptIsExpected,

      InvoiceIsExpected                                                              as InvoiceIsExpected,

      GoodsReceiptIsNonValuated                                                      as GoodsReceiptIsNonValuated,

      RequirementTracking                                                            as RequirementTracking,

      MRPArea                                                                        as MRPArea,

      MRPController                                                                  as MRPController,

      TaxCode                                                                        as TaxCode,

      PurchaseRequisitionIsFixed                                                     as PurchaseRequisitionIsFixed,

      LastChangeDateTime                                                             as LastChangeDateTime,

      IsPurReqnCmplt                                                                 as IsPurReqnCmplt,

      PurReqnCmpltnsCat                                                              as PurReqnCmpltnsCat,

      ExtMaterialForPurg                                                             as ExtMaterialForPurg,

      ExtFixedSupplierForPurg                                                        as ExtFixedSupplierForPurg,

      ExtDesiredSupplierForPurg                                                      as ExtDesiredSupplierForPurg,

      ExtContractForPurg                                                             as ExtContractForPurg,

      ExtContractItemForPurg                                                         as ExtContractItemForPurg,

      ExtInfoRecordForPurg                                                           as ExtInfoRecordForPurg,

      ExtPlantForPurg                                                                as ExtPlantForPurg,

      ProcmtHubStorageLocation                                                       as ProcmtHubStorageLocation,

      ExtCompanyCodeForPurg                                                          as ExtCompanyCodeForPurg,

      ExtPurgOrgForPurg                                                              as ExtPurgOrgForPurg,

      ExtSourceSystem                                                                as ExtSourceSystem, //deprecate this


      ProcurementHubSourceSystem                                                     as ProcurementHubSourceSystem,

      IsPurReqnOvrlRel                                                               as IsPurReqnOvrlRel,

      ReleaseGroup                                                                   as ReleaseGroup,

      @Semantics.amount.currencyCode: 'PurReqnItemCurrency'
      ExpectedOverallLimitAmount                                                     as ExpectedOverallLimitAmount,

      @Semantics.amount.currencyCode: 'PurReqnItemCurrency'
      OverallLimitAmount                                                             as OverallLimitAmount,
      PurContractForOverallLimit                                                     as PurContractForOverallLimit,
      
      PurContractItemForOverallLimit                                                 as PurContractItemForOverallLimit,

      IsEndOfPurposeBlocked                                                          as IsEndOfPurposeBlocked,

      PurchaseReqnItemUniqueID                                                       as PurchaseReqnItemUniqueID,

      Subcontractor                                                                  as Subcontractor,

      PurReqnReceivingCustomer                                                       as PurReqnReceivingCustomer,

      PurchaseOrderPriceType                                                         as PurchaseOrderPriceType,

      IsOnBehalfCart                                                                 as IsOnBehalfCart,

      ExtPurchaseRequisitionType                                                     as ExtPurchaseRequisitionType,

      PurReqnIsCreatedInExpertMode                                                   as PurReqnIsCreatedInExpertMode,

      MaterialShortageQuantity                                                       as MaterialShortageQuantity,

      PurchaseOrderDate                                                              as PurchaseOrderDate,

      PurReqnIntObjNmbr                                                              as PurReqnIntObjNmbr,

      PFMTransDataFootprintUUID                                                      as PFMTransDataFootprintUUID,

      ExternalProcurementProfile                                                     as ExternalProcurementProfile,

      case  when PurReqnSSPRequestor = ''
      then RequisitionerName
      else
      PurReqnSSPRequestor end                                                        as PurReqnRequestor,

      case ExtApprvlIntmdSts
      when ''
        then ExternalApprovalStatus
      else
        cast( ExtApprvlIntmdSts as mmpur_req_extapprvlsts )
      end                                                                            as ExternalApprovalStatus,
      //     ExternalApprovalStatus                                                         as ExternalApprovalStatus,

      //     ExtApprvlIntmdSts                                                              as ExtApprvlIntmdSts,

      //     cast( CommitmentItemShortID as fipos )                                         as CommitmentItem,

      CommitmentItemShortID                                                          as CommitmentItemShortID,
      FundsCenter                                                                    as FundsCenter,
      Fund                                                                           as Fund,
      GrantID                                                                        as GrantID,
      FunctionalArea                                                                 as FunctionalArea,
      EarmarkedFundsDocument                                                         as EarmarkedFundsDocument,
      EarmarkedFundsDocumentItem                                                     as EarmarkedFundsDocumentItem,
      BudgetPeriod                                                                   as BudgetPeriod,
      @EndUserText.label: 'Funded Program'
      _FundedProgram.FundedProgram                                                   as FundedProgram,
      MaterialOrderUnit                                                              as MaterialOrderUnit,
      CostCenter                                                                     as CostCenter,
      GLAccount                                                                      as GLAccount,


      /*    EBAN_TECH fields */
      _ExtRefForPurReqnItm.PurReqnExternalReference                                  as PurReqnExternalReference,
      _ExtRefForPurReqnItm.PurReqnItemExternalReference                              as PurReqnItemExternalReference,


      _ExtRefForPurReqnItm.PurReqnExternalSystemId                                   as PurReqnExternalSystemId,
      _ExtRefForPurReqnItm.PurReqnExternalSystemType                                 as PurReqnExternalSystemType,

      /*    deprecated and not used anymore. Still available for compatibility */
      _ExtRefForPurReqnItm.PurReqnTypeExternalReference                              as PurReqnTypeExternalReference,
      _ExtRefForPurReqnItm.PurReqnProcessingType                                     as PurReqnProcessingType,
      _ExtRefForPurReqnItm.PurReqnProcessingDateTime                                 as PurReqnProcessingDateTime,

      _BackendSourceSystem.ProcmtHubBackendBusSyst                                   as ProcmtHubBackendBusSyst,

      ProcmtHubPurReqnItmIsChanged                                                   as ProcmtHubPurReqnItmIsChanged,

      InventorySpecialStockType                                                      as InventorySpecialStockType,

      cast (' ' as mmpur_req_d_author_bpid )                                         as SSPAuthorExternalBPIdnNumber,

      cast (' ' as mmpur_req_d_requestor_userid )                                    as SSPReqrUserId,

      PurReqnIsValdInCntrlReqnProcg                                                  as PurReqnIsValdInCntrlReqnProcg,
      PurchasingDeliveryAddressType                                                  as PurchasingDeliveryAddressType,

      PurReqnHasDelegateApproval                                                     as PurReqnHasDelegateApproval,

      CntrlReqnIsRpldBfrApprvl                                                       as CntrlReqnIsRpldBfrApprvl,

      CntrlReqnApprvlStsInRpldReqn                                                   as CntrlReqnApprvlStsInRpldReqn,

      _PurchaseOrder,
      _PurchasingDocumentType,
      _PurchaseRequisition,
      _Supplier,
      _DesiredSupplier, //Added for ESH Modeling

      _PurchasingOrganization,
      _PurchasingGroup,
      _Currency,
      _SupplyingPlant,
      _AccAssgnmtCategory,
      _Material,
      _MaterialGroup,
      _Plant,
      @VDM: {
              lifecycle: {
                           status: #DEPRECATED,
                           successor: '_OrganizationAddress'
                         }
            }
      _Address,
      _OrganizationAddress,
      _UnitOfMeasure,
      _StorageLocation,
      _PurchasingInfoRecord,
      _PurReqnAcctAssgmt,
      _MRPArea,
      _CalcFields,
      _User //Added for ESH Modeling

     
}