C_PersSettlmtDocWorkItem

@AbapCatalog:{
    sqlViewName: 'CWLFPERSSMTDOCWI',
    compiler.compareFilter: true,
    preserveKey: true
}
@AccessControl: {
    authorizationCheck: #MANDATORY,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}
@ObjectModel:{
   usageType: {
       serviceQuality: #D,
       dataClass: #MIXED,
       sizeCategory:  #XXL
   },
   semanticKey: [ 'WorkflowTaskInternalID' ],
   representativeKey: 'WorkflowTaskInternalID'
}
@ClientHandling: {
    algorithm: #SESSION_VARIABLE,
    type: #INHERITED
}
@VDM.viewType: #CONSUMPTION
@Consumption.semanticObject: 'WorkflowTaskInternalID'
@EndUserText.label: 'Personnel Settlement Document Work Item'

define view C_PersSettlmtDocWorkItem
  as select from I_WorkflowTask            as _WorkflowTask
    inner join   I_WorkflowTaskApplObject  as _WorkflowTaskApplObject  on  _WorkflowTaskApplObject.WorkflowTaskInternalID        = _WorkflowTask.WorkflowTaskInternalID
                                                                       and _WorkflowTaskApplObject.WorkflowObjectRole            = '01'
                                                                       and _WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'CL'
                                                                       and _WorkflowTaskApplObject.SAPObjectNodeRepresentation   = 'PersonnelSettlementDocument'
    inner join   C_PersSettlmtDocWrkflwDet as _PersSettlmtDocWrkflwDet on _PersSettlmtDocWrkflwDet.PersonnelSettlementDocument = _WorkflowTaskApplObject.TechnicalWrkflwObject
{
  key _WorkflowTask.WorkflowTaskInternalID,
      _PersSettlmtDocWrkflwDet.PersonnelSettlementDocument,
      @ObjectModel: { foreignKey.association: '_CreatedByUser', mandatory: true}
      @ObjectModel.text.element:  [ 'UserFullName' ]
      _PersSettlmtDocWrkflwDet.CreatedByUser,
      @Semantics.text: true
      _PersSettlmtDocWrkflwDet.UserFullName,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_PersSettlmtDocCurrency'
      _PersSettlmtDocWrkflwDet.PersSettlmtDocCurrency,
      @Semantics.amount.currencyCode: 'PersSettlmtDocCurrency'
      _PersSettlmtDocWrkflwDet.TotalNetAmount,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      _PersSettlmtDocWrkflwDet.CompanyCode,
      @ObjectModel.foreignKey.association: '_PersonWorkAgreement'
      _PersSettlmtDocWrkflwDet.PersonWorkAgreement,
      _PersSettlmtDocWrkflwDet.SettlmtDate,
      _PersSettlmtDocWrkflwDet.DocumentDate,
      _PersSettlmtDocWrkflwDet.PersonnelCostCenter,
      @ObjectModel.foreignKey.association: '_SettlmtCompnRsn'
      _PersSettlmtDocWrkflwDet.SettlmtCompensationReason,
      @ObjectModel.foreignKey.association: '_SettlmtCompnVar'
      _PersSettlmtDocWrkflwDet.SettlmtCompnVar,
      _PersSettlmtDocWrkflwDet.DocumentTitle,
      _PersSettlmtDocWrkflwDet.SalesOrganization,
      _PersSettlmtDocWrkflwDet.DistributionChannel,
      _PersSettlmtDocWrkflwDet.Division,
      _PersSettlmtDocWrkflwDet.SettlmtDocType,

      //Associations

      _PersSettlmtDocWrkflwDet._CreatedByUser,
      _PersSettlmtDocWrkflwDet._PersSettlmtDocCurrency,
      _PersSettlmtDocWrkflwDet._CompanyCode,
      _PersSettlmtDocWrkflwDet._PersonWorkAgreement,
      _PersSettlmtDocWrkflwDet._SettlmtCompnRsn,
      _PersSettlmtDocWrkflwDet._SettlmtCompnVar
}