C_PPM_TeamMemberSearchHelp

DDL: C_PPM_TEAMMEMBERSEARCHHELP SQL: CPPMTEAMMBRSHLP Type: view CONSUMPTION

Search help for team member

C_PPM_TeamMemberSearchHelp is a Consumption CDS View that provides data about "Search help for team member" in SAP S/4HANA. It reads from 2 data sources (I_BusinessPartner_to_BP_Role, I_BusinessUserBasic) and exposes 22 fields with key field BusinessPartner.

2 data source(s) 22 fields

Data Sources (2)

SourceAliasJoin Type
I_BusinessPartner_to_BP_Role BupaToBPRole inner
I_BusinessUserBasic BusinessUser from

Annotations (13)

NameValueLevelField
AbapCatalog.sqlViewName CPPMTEAMMBRSHLP view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Search help for team member view
VDM.viewType #CONSUMPTION view
AccessControl.personalData.blocking #REQUIRED view
ObjectModel.representativeKey BusinessPartner view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.dataCategory #VALUE_HELP view
Search.searchable true view
Consumption.ranked true view

Fields (22)

KeyFieldSource TableSource FieldDescription
KEY BusinessPartner I_BusinessUserBasic BusinessPartner
BusinessPartnerUUID I_BusinessUserBasic BusinessPartnerUUID
PersonFullName I_BusinessUserBasic PersonFullName
FirstName I_BusinessUserBasic FirstName
LastName I_BusinessUserBasic LastName
Building Building Code
RoomNumber
NormalizedPhoneNumber
DefaultEmailAddress
AuthorizationGroup I_BusinessUserBasic AuthorizationGroup
IsBusinessPurposeCompleted I_BusinessUserBasic IsBusinessPurposeCompleted
DataControllerSet I_BusinessUserBasic DataControllerSet
DataController1 I_BusinessUserBasic DataController1
DataController2 I_BusinessUserBasic DataController2
DataController3 I_BusinessUserBasic DataController3
DataController4 I_BusinessUserBasic DataController4
DataController5 I_BusinessUserBasic DataController5
DataController6 I_BusinessUserBasic DataController6
DataController7 I_BusinessUserBasic DataController7
DataController8 I_BusinessUserBasic DataController8
DataController9 I_BusinessUserBasic DataController9
DataController10 I_BusinessUserBasic DataController10 
@AbapCatalog.sqlViewName: 'CPPMTEAMMBRSHLP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Search help for team member'
@VDM.viewType: #CONSUMPTION

@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel: {
   semanticKey:       [ 'PersonFullName' ],
   representativeKey: 'BusinessPartner',
   alternativeKey: [ { id : 'BusinessPartnerUUID', element: ['BusinessPartnerUUID'], uniqueness: #UNIQUE } ],  
   usageType: {
     serviceQuality:  #C,
     dataClass:       #MIXED,
     sizeCategory:    #XL
   },
   dataCategory: #VALUE_HELP
}
@Search.searchable: true
@Consumption.ranked: true

define view C_PPM_TeamMemberSearchHelp as select 
  from            I_BusinessUserBasic               as BusinessUser 
  inner join      I_BusinessPartner_to_BP_Role as BupaToBPRole      on BupaToBPRole.BusinessPartner         = BusinessUser.BusinessPartner
  
{
  
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  @EndUserText: { label: 'Business Partner', quickInfo: 'Business Partner' }
  @ObjectModel.text.element:  [ 'PersonFullName' ]
  @Search.ranking: #HIGH 
  key BusinessUser.BusinessPartner,
  
  @ObjectModel.text.element:  [ 'PersonFullName' ]
  @UI.hidden: true
  BusinessUser.BusinessPartnerUUID,
  
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8 
  @Semantics.text: true
  @Search.ranking: #LOW
  BusinessUser.PersonFullName,
  
  @Search.defaultSearchElement: true
  @Search.ranking: #LOW
  BusinessUser.FirstName,
  @Search.defaultSearchElement: true
  @Search.ranking: #LOW
  BusinessUser.LastName,
 
  //Location Information

  @Search.defaultSearchElement: true
  @Search.ranking: #LOW
  @EndUserText.label: 'Building Code'
  BusinessUser._WorkplaceAddress.Building,
  @Search.defaultSearchElement: true
  @Search.ranking: #LOW
  BusinessUser._WorkplaceAddress.RoomNumber,
  @Search.defaultSearchElement: true
  @Search.ranking: #LOW
  @Semantics: { telephone.type:  [ #WORK, #PREF ] }
  BusinessUser._WorkplaceAddress.NormalizedPhoneNumber,
  @Search.defaultSearchElement: true
  @Search.ranking: #LOW
  BusinessUser._WorkplaceAddress.DefaultEmailAddress,
  
  @Consumption.hidden: true     // required for authorizations only

  BusinessUser.AuthorizationGroup,
  
  @Consumption.hidden: true      // required for authorizations only

  BusinessUser.IsBusinessPurposeCompleted,
  
  @Consumption.hidden:true
  BusinessUser.DataControllerSet,
  @Consumption.hidden:true
  BusinessUser.DataController1,
  @Consumption.hidden:true
  BusinessUser.DataController2,
  @Consumption.hidden:true
  BusinessUser.DataController3,
  @Consumption.hidden:true
  BusinessUser.DataController4,
  @Consumption.hidden:true
  BusinessUser.DataController5,
  @Consumption.hidden:true
  BusinessUser.DataController6,
  @Consumption.hidden:true
  BusinessUser.DataController7,
  @Consumption.hidden:true
  BusinessUser.DataController8,
  @Consumption.hidden:true
  BusinessUser.DataController9,
  @Consumption.hidden:true
  BusinessUser.DataController10
  
} where BupaToBPRole.BusinessPartnerRole = 'BUP003' //Employee role

Learn More