C_ObjPgMaintNotificationItem

@AbapCatalog.sqlViewName: 'COBJPGMNTNTFITM'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Maintenance Notification Item'
@Metadata.allowExtensions: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

@UI.headerInfo:
{
    typeName: 'Malfunction Item',
    typeNamePlural: 'Malfunction Items',
    description:    {value: 'MaintNotifItemText',
                     type: #STANDARD },
    title      :    {value: 'MaintenanceNotificationItem',
                     type:   #STANDARD}
}
@UI.presentationVariant: {
        sortOrder.by: 'MaintenanceNotificationItem'
    }
define view C_ObjPgMaintNotificationItem
  as select from I_MaintNotificationItemTP
  association [0..*] to C_ObjPgMaintNotifActivity     as _ObjPgMaintNotifActivity     on  $projection.MaintenanceNotificationItem = _ObjPgMaintNotifActivity.MaintenanceNotificationItem
                                                                                      and $projection.MaintenanceNotification    = _ObjPgMaintNotifActivity.MaintenanceNotification
  association [0..*] to C_ObjPgMaintNotificationTask  as _ObjPgMaintNotificationTask  on  $projection.MaintenanceNotificationItem = _ObjPgMaintNotificationTask.MaintenanceNotificationItem
                                                                                      and $projection.MaintenanceNotification    = _ObjPgMaintNotificationTask.MaintenanceNotification
  association [0..*] to C_ObjPgMaintNotificationCause as _ObjPgMaintNotificationCause on  $projection.MaintenanceNotificationItem = _ObjPgMaintNotificationCause.MaintenanceNotificationItem
                                                                                      and $projection.MaintenanceNotification    = _ObjPgMaintNotificationCause.MaintenanceNotification
{
      @UI.hidden: true
  key I_MaintNotificationItemTP.MaintenanceNotification,
      @UI: {lineItem: { position: 50, importance: #HIGH },
            fieldGroup: {qualifier:'ObjectGroup',position: 10, importance: #HIGH}}
      @ObjectModel.text.element:  [ 'MaintNotifItemText' ]
      @UI.textArrangement: #TEXT_FIRST
  key I_MaintNotificationItemTP.MaintenanceNotificationItem,
      @Semantics.text: true
      I_MaintNotificationItemTP.MaintNotifItemText,
      @UI: {lineItem: { position: 10, importance: #HIGH },
            fieldGroup: {qualifier:'ObjectGroup',position: 20, importance: #HIGH}}
      @EndUserText.label: 'Object Group'
      @ObjectModel.text.element: ['MaintNotifObjPrtCodeGroupName']
      @UI.textArrangement: #TEXT_FIRST
      I_MaintNotificationItemTP.MaintNotifObjPrtCodeGroup,
      @Semantics.text: true
      @EndUserText.label: 'Object Group Name'
      replace(I_MaintNotificationItemTP._MaintNotifObjPrtCodeGroup._Text[1:Language=$session.system_language].InspSpecAddlCodeGroupText, '&', ' ') as MaintNotifObjPrtCodeGroupName,
      @UI: { lineItem: { position: 30, importance: #HIGH },
             fieldGroup: {qualifier:'ObjectGroup',position: 40, importance: #HIGH}}
      @EndUserText.label: 'Object Part'
      @ObjectModel.text.element:  [ 'MaintNotifObjPrtCodeName' ]
      @UI.textArrangement: #TEXT_FIRST
      I_MaintNotificationItemTP.MaintNotifObjPrtCode,
      @Semantics.text: true
      @EndUserText: { label: 'Object Part Name', quickInfo: 'Object Part Name' }
      I_MaintNotificationItemTP._MaintNotifObjPrtCode._Text[1:Language=$session.system_language].InspectionCodeText             as MaintNotifObjPrtCodeName,
      @UI: {lineItem: { position: 70, importance: #HIGH },
            fieldGroup: {qualifier:'DamageGroup',position: 10, importance: #HIGH}}
      @EndUserText.label: 'Damage Group'
      @ObjectModel.text.element:  [ 'MaintNotifDamageCodeGroupName' ]
      @UI.textArrangement: #TEXT_FIRST
      I_MaintNotificationItemTP.MaintNotifDamageCodeGroup,
      @Semantics.text: true
      @EndUserText.label: 'Damage Group Name'
      replace(I_MaintNotificationItemTP._MaintNotifDamageCodeGroup._Text[1:Language=$session.system_language].InspSpecAddlCodeGroupText, '&', ' ') as MaintNotifDamageCodeGroupName,
      @UI: {lineItem: { position: 90, importance: #HIGH },
            fieldGroup: {qualifier:'DamageGroup',position: 30, importance: #HIGH}}
      @ObjectModel.text.element:  [ 'MaintNotifDamageCodeName' ]
      @UI.textArrangement: #TEXT_FIRST
      I_MaintNotificationItemTP.MaintNotificationDamageCode,
      @Semantics.text: true
      @EndUserText: { label: 'Damage Code Name', quickInfo: 'Damage Code Name' }
      I_MaintNotificationItemTP._MaintNotificationDamageCode._Text[1:Language=$session.system_language].InspectionCodeText      as MaintNotifDamageCodeName,
        @UI.hidden: true
      I_MaintNotificationItemTP._MaintenanceNotification.NotificationType,

      // Technical field; Filled in Odata service

      @UI: {fieldGroup: {position: 20, importance: #HIGH, qualifier:'General'}}
      @EndUserText.label: 'Long Text'
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'CL_EAM_NTF_LTXT_EXIT'
      cast('' as eams_ltext ) as MaintNotifItemLongText,

      /* Associations - locally defined */
      _ObjPgMaintNotifActivity,
      _ObjPgMaintNotificationCause,
      _ObjPgMaintNotificationTask,

      /* Associations - DCL */
      I_MaintNotificationItemTP._MaintenanceNotification
}