C_ObjPgMaintNotificationTask

DDL: C_OBJPGMAINTNOTIFICATIONTASK SQL: COBJPGMNTNTFTASK Type: view CONSUMPTION

Maintenance Notification Task

C_ObjPgMaintNotificationTask is a Consumption CDS View that provides data about "Maintenance Notification Task" in SAP S/4HANA. It reads from 1 data source (I_MaintNotificationTaskTP) and exposes 35 fields with key fields MaintenanceNotification, MaintenanceNotificationTask. It has 1 association to related views.

1 data source(s) 35 fields

Data Sources (1)

SourceAliasJoin Type
I_MaintNotificationTaskTP I_MaintNotificationTaskTP from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_User _CompletedByUser $projection.CompletedByUser = _CompletedByUser.UserID

Annotations (10)

NameValueLevelField
AbapCatalog.sqlViewName COBJPGMNTNTFTASK view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Maintenance Notification Task view
Metadata.allowExtensions true view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
VDM.viewType #CONSUMPTION view

Fields (35)

KeyFieldSource TableSource FieldDescription
KEY MaintenanceNotification I_MaintNotificationTaskTP MaintenanceNotification
KEY MaintenanceNotificationTask I_MaintNotificationTaskTP MaintenanceNotificationTask
MaintenanceNotificationItem I_MaintNotificationTaskTP MaintenanceNotificationItem
MaintNotifTaskCodeGroup I_MaintNotificationTaskTP MaintNotifTaskCodeGroup Task Code Group
MaintNotifTaskCodeGroupName Task Code Group Name
MaintNotifTaskCode I_MaintNotificationTaskTP MaintNotifTaskCode Task Code
MaintNotifTaskCodeName
MaintNotifTaskTxt I_MaintNotificationTaskTP MaintNotifTaskTxt
ResponsiblePersonFunctionCode I_MaintNotificationTaskTP ResponsiblePersonFunctionCode
MaintNotifTaskPartFuncName
ResponsiblePerson I_MaintNotificationTaskTP ResponsiblePerson
ResponsiblePersonName Responsible Name
PlannedStartDate I_MaintNotificationTaskTP PlannedStartDate
PlannedStartTime I_MaintNotificationTaskTP PlannedStartTime Planned Start Time
PlannedEndDate I_MaintNotificationTaskTP PlannedEndDate Planned Finish Date
PlannedEndTime I_MaintNotificationTaskTP PlannedEndTime Planned Finish Time
MaintNotifItmTskPlndStrtDteTme Planned Start Date
MaintNotifItmTskPlndEndDteTime Planned Finish Date
CompletedByUser I_MaintNotificationTaskTP CompletedByUser
TaskCompletedByUserName _CompletedByUser UserDescription Completed by User Name
CompletionDate I_MaintNotificationTaskTP CompletionDate Completion Date
CompletionTime I_MaintNotificationTaskTP CompletionTime Completion Time
MaintNotifItmTskCompltnDteTime Completion Date
MaintNotifTaskInternalID I_MaintNotificationTaskTP MaintNotifTaskInternalID
IsDeleted I_MaintNotificationTaskTP IsDeleted
_MaintenanceNotification I_MaintNotificationTaskTP _MaintenanceNotification
_PartnerFunction I_MaintNotificationTaskTP _PartnerFunction
_ContactPerson I_MaintNotificationTaskTP _ContactPerson
_Customer I_MaintNotificationTaskTP _Customer
_Employee I_MaintNotificationTaskTP _Employee
_OrganizationalUnitText I_MaintNotificationTaskTP _OrganizationalUnitText
_PositionText I_MaintNotificationTaskTP _PositionText
_Supplier I_MaintNotificationTaskTP _Supplier
_User I_MaintNotificationTaskTP _User
_CompletedByUser _CompletedByUser 
@AbapCatalog.sqlViewName: 'COBJPGMNTNTFTASK'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maintenance Notification Task'
@Metadata.allowExtensions: true
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #CONSUMPTION


define view C_ObjPgMaintNotificationTask
  as select from I_MaintNotificationTaskTP
  association [0..1] to I_User as _CompletedByUser on $projection.CompletedByUser = _CompletedByUser.UserID
{
      @UI.hidden: true
  key I_MaintNotificationTaskTP.MaintenanceNotification,
      @UI: {lineItem: { position: 10, importance: #HIGH }}
      @ObjectModel.text.element:  [ 'MaintNotifTaskTxt' ]
      @UI.textArrangement: #TEXT_FIRST
      @EndUserText:{label: 'Task', quickInfo: 'Task'}
  key I_MaintNotificationTaskTP.MaintenanceNotificationTask,
      @UI.hidden: true
      I_MaintNotificationTaskTP.MaintenanceNotificationItem,
      @UI: {lineItem: { position: 20, importance: #HIGH }}
      @EndUserText.label: 'Task Code Group'
      @ObjectModel.text.element:  [ 'MaintNotifTaskCodeGroupName' ]
      @UI.textArrangement: #TEXT_FIRST
      I_MaintNotificationTaskTP.MaintNotifTaskCodeGroup,
      @EndUserText.label: 'Task Code Group Name'
      @Semantics.text: true
      replace(I_MaintNotificationTaskTP._MaintNotifTaskCodeGroup._Text[1:Language=$session.system_language].InspSpecAddlCodeGroupText, '&', ' ')  as MaintNotifTaskCodeGroupName,
      @UI: {lineItem: { position: 30, importance: #HIGH }}
      @EndUserText.label: 'Task Code'
      @ObjectModel.text.element:  [ 'MaintNotifTaskCodeName' ]
      @UI.textArrangement: #TEXT_FIRST
      I_MaintNotificationTaskTP.MaintNotifTaskCode,
      @Semantics.text: true
      @EndUserText:{label: 'Task Code Name', quickInfo: 'Task Code Name'}
      I_MaintNotificationTaskTP._MaintNotificationTaskCode._Text[1:Language=$session.system_language].InspectionCodeText                          as MaintNotifTaskCodeName,
      @Semantics.text: true
      I_MaintNotificationTaskTP.MaintNotifTaskTxt,
      @UI: {lineItem: { position: 60, importance: #HIGH }}
      @EndUserText.label: 'System Status'
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_NTFTSK_STS_EXIT'
      cast ('' as vdm_j_system_status_concat_t)                                                                                                   as ConcatenatedActiveSystStsName,
      @UI: {lineItem: { position: 70, importance: #HIGH }}
      @EndUserText.label: 'User Status'
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_NTFTSK_STS_EXIT'
      cast ('' as vdm_j_user_status_concat_t)                                                                                                     as ConcatenatedActiveUserStsName,
      @UI: {lineItem: { position: 80, importance: #HIGH }}
      @ObjectModel.text.element:  [ 'MaintNotifTaskPartFuncName' ]
      @UI.textArrangement: #TEXT_FIRST
      I_MaintNotificationTaskTP.ResponsiblePersonFunctionCode,
      @EndUserText:{label: 'Task Processor Text', quickInfo: 'Task Processor Text'}
      @Semantics.text: true
      I_MaintNotificationTaskTP._PartnerFunction._Text[1:Language=$session.system_language].PartnerFunctionName                                   as MaintNotifTaskPartFuncName,
      @UI: {lineItem: { position: 90, importance: #HIGH }}
      @ObjectModel.text.element:  [ 'ResponsiblePersonName' ]
      @UI.textArrangement: #TEXT_FIRST
      I_MaintNotificationTaskTP.ResponsiblePerson,
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_OBJPG_NTFTASK_PART_EXIT'
      @EndUserText.label: 'Responsible Name'
      cast('' as eams_person_responsible_name)                                                                                                    as ResponsiblePersonName,

      @UI.hidden: true
      @UI: {lineItem: { position: 100, importance: #HIGH }}
      I_MaintNotificationTaskTP.PlannedStartDate,
      @UI: {lineItem: { position: 110, importance: #HIGH }}

      @UI.hidden: true
      @EndUserText.label: 'Planned Start Time'
      I_MaintNotificationTaskTP.PlannedStartTime,
      @UI.hidden: true
      @UI: {lineItem: { position: 120, importance: #HIGH }}
      @EndUserText.label: 'Planned Finish Date'
      I_MaintNotificationTaskTP.PlannedEndDate,

      @UI.hidden: true
      @UI: {lineItem: { position: 130, importance: #HIGH }}
      @EndUserText.label: 'Planned Finish Time'
      I_MaintNotificationTaskTP.PlannedEndTime,
      @UI: {lineItem: { position: 100, importance: #HIGH }}
      @EndUserText.label: 'Planned Start Date'
      cast (dats_tims_to_tstmp( PlannedStartDate, PlannedStartTime, I_MaintNotificationTaskTP._MaintenanceNotification.NotificationTimeZone , $session.client, 'NULL') as  tzntstmps preserving type ) as MaintNotifItmTskPlndStrtDteTme,
      @UI: {lineItem: { position: 120, importance: #HIGH }}
      @EndUserText.label: 'Planned Finish Date'
      cast (dats_tims_to_tstmp( PlannedEndDate, PlannedEndTime, I_MaintNotificationTaskTP._MaintenanceNotification.NotificationTimeZone , $session.client, 'NULL') as  tzntstmps preserving type )     as MaintNotifItmTskPlndEndDteTime,

      @ObjectModel.text.element:  [ 'TaskCompletedByUserName' ] //3477818 ->

      I_MaintNotificationTaskTP.CompletedByUser,
      @Semantics.text: true
      @EndUserText.label: 'Completed by User Name'
      _CompletedByUser.UserDescription                                                                                                                                                              as TaskCompletedByUserName,
      @UI.hidden: true
      @EndUserText.label: 'Completion Date'
      I_MaintNotificationTaskTP.CompletionDate,
      @UI.hidden: true
      @EndUserText.label: 'Completion Time'
      I_MaintNotificationTaskTP.CompletionTime,
      @EndUserText.label: 'Completion Date'
      cast (dats_tims_to_tstmp( CompletionDate, CompletionTime, I_MaintNotificationTaskTP._MaintenanceNotification.NotificationTimeZone , $session.client, 'NULL') as  tzntstmps preserving type )     as MaintNotifItmTskCompltnDteTime,
      //<- 3477818


      /* Technical Fields */
      @UI.hidden: true
      I_MaintNotificationTaskTP.MaintNotifTaskInternalID,

      @UI.hidden: true // n3086741

      I_MaintNotificationTaskTP.IsDeleted, // n3086741


      /* Associations - DPP */
      I_MaintNotificationTaskTP._MaintenanceNotification,
      I_MaintNotificationTaskTP._PartnerFunction,
      I_MaintNotificationTaskTP._ContactPerson,
      I_MaintNotificationTaskTP._Customer,
      I_MaintNotificationTaskTP._Employee,
      I_MaintNotificationTaskTP._OrganizationalUnitText,
      I_MaintNotificationTaskTP._PositionText,
      I_MaintNotificationTaskTP._Supplier,
      I_MaintNotificationTaskTP._User,
      _CompletedByUser

}

Learn More