C_MasterProjectActivity

@AbapCatalog.sqlViewName: 'CMSTRPROJACTY'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Commercial Project Activity Detail'
@AccessControl.privilegedAssociations: [ '_CreatedByUser', '_ChangedByUser' ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@Search.searchable: true
@VDM.viewType: #CONSUMPTION
define view C_MasterProjectActivity
  as select from I_MstrProjActivityDetail as MPActivities
  association [0..*] to I_MstrProjActyTeamMbr         as _MstrProjTeamMemberID              on  $projection.MstrProjActivityId = _MstrProjTeamMemberID.MstrProjActivityId
  association [0..1] to I_MstrProjActyTeamMbr         as _TeamMemberUserId          on  $projection.MstrProjActivityId         = _TeamMemberUserId.MstrProjActivityId
                                                                                    and $projection.ActivityUUID               = _TeamMemberUserId.ActivityUUID
                                                                                    and _TeamMemberUserId.IsResponsiblePartner = 'X'

  association [0..*] to I_MstrProjActyAttchsWithUsr   as _DocumentURL               on  $projection.MstrProjActivityId = _DocumentURL.MstrProjActivityId
  association [0..1] to I_MstrProjActyDesc            as _ProjectActivity           on  $projection.MstrProjActivityId = _ProjectActivity.MstrProjActivityId
                                                                                    and $projection.ActivityUUID       = _ProjectActivity.ActivityUUID
  association [0..*] to I_MstrProjActyNotes           as _Activity                  on  $projection.MstrProjActivityId = _Activity.MstrProjActivityId



  //For Text

  association [0..1] to I_MasterProjectType           as _MasterProjectType         on  $projection.MasterProjectType = _MasterProjectType.MasterProjectType
  association [0..1] to I_EngagementProjectStage      as _MasterProjectStage        on  $projection.MasterProjectStage = _MasterProjectStage.EngagementProjectStage
  association [0..1] to I_EngagementProjectSrvcOrg    as _MasterProjectOrganization on  $projection.MasterProjectOrganization = _MasterProjectOrganization.EngagementProjectServiceOrg


  association [0..1] to I_MstrProjActyCompletedStatus as _Status                    on  $projection.OriginApplication = _Status.OriginApplication
                                                                                    and $projection.Status            = _Status.Status
  association [0..1] to I_MstrProjChklstPrioCode      as _MstrProjChklstPrioCode    on  MPActivities.MstrProjChklstPrioCode = _MstrProjChklstPrioCode.MstrProjChklstPrioCode
  association [0..1] to I_MstrProjIssueType           as _MstrProjIssueType         on  $projection.IssueType = _MstrProjIssueType.IssueType
  association [0..1] to I_MstrProjActyCat             as _IssueCategory             on  $projection.IssueCategory = _IssueCategory.IssueCategory
  association [0..1] to I_MstrProjUsrInvlmntStatus    as _MstrProjUsrInvlmntStatus  on  $projection.IsUserStatus = _MstrProjUsrInvlmntStatus.MstrProjUsrInvlmntStatus


  //For Value Help

  association [0..1] to I_MasterProjectVH             as _MasterProject             on  $projection.MasterProject = _MasterProject.MasterProject
  association [0..1] to I_MstrProjActyVH              as _MstrProjActyVH            on  $projection.MstrProjActivityId = _MstrProjActyVH.MstrProjActivityId
  association [0..1] to I_MstrProjActyStsCat          as _MstrProjActyStsCat        on  $projection.IsCompleted = _MstrProjActyStsCat.IsCompleted

  association [0..1] to I_MstrProjActyRefVH           as _MstrProjActyRefVH         on  $projection.ReferenceDocument = _MstrProjActyRefVH.ReferenceDocument


  association [0..*] to I_MstrProjBusPartnerByRoleVH  as _BusinessPartner           on  $projection.businesspartner = _BusinessPartner.BusinessPartner

  association [0..1] to E_MasterProjectActivityRoot   as _Extension                 on  $projection.ActivityUUID = _Extension.ActivityUUID

{

      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_MasterProjectStdVH',
                           element: 'MasterProject' }
              }]
      @ObjectModel.text.element: 'MasterProjectName'
      @ObjectModel: {foreignKey.association: '_MasterProject'}
  key MPActivities.MasterProject,



      @Consumption.valueHelpDefinition: [
       { entity:  { name:    'I_MstrProjActyRefVH',
                    element: 'ReferenceDocument' }
       }]
      @ObjectModel.text.element: 'ReferenceDocumentDesc'
      @ObjectModel: {foreignKey.association: '_MstrProjActyRefVH'}
  key MPActivities.ReferenceDocument,

      @Consumption.valueHelpDefinition: [
         { entity:  { name:    'I_MstrProjActyVH',
                      element: 'MstrProjActivityId' }
         }]
      @ObjectModel.text.element: 'ActivityName'
      @ObjectModel: {foreignKey.association: '_MstrProjActyVH'}
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
  key MPActivities.MstrProjActivityId,

      @Consumption.filter.hidden: true
      @UI.hidden: true
  key MPActivities.ActivityUUID,

      @Semantics.text: true
      MPActivities.MasterProjectName,

      MPActivities.MasterProjectUUID,
      @ObjectModel: {foreignKey.association: '_MasterProjectType'}
      @ObjectModel.text.element: 'MasterProjectTypeName'

      MPActivities.MasterProjectStage,

      cast(_MasterProjectStage._Text[1:Language =  $session.system_language ].EngagementProjectStageText as /cpd/cpm_mpstage_desc)                                                                                                                                    as  MasterProjectStageName,

      MPActivities.MasterProjectType
                                                                                                                                                                                                                                                                      as  MasterProjectType,
      cast(_MasterProjectType._Text[1:Language =  $session.system_language ].MasterProjectTypeName as /cpd/cpm_mp_type_desc)                                                                                                                                          as  MasterProjectTypeName,

      MPActivities.MasterProjectIsConfidential,

      MPActivities.MasterProjectOrganization,

      cast(_MasterProjectOrganization._Text[1:Language = $session.system_language].EngmtProjectServiceOrgName as /cpd/cpm_comlprojorgname)                                                                                                                            as  MasterProjectOrganizationName,

      MPActivities.ReferenceDocumentDesc,

      @ObjectModel: {foreignKey.association: '_MstrProjIssueType'}
      MPActivities.IssueType,

      @Search.defaultSearchElement: true
      _MstrProjIssueType._Text [1: Language = $session.system_language ].ReferenceTypeText                                                                                                                                                                            as  ReferenceTypeText,

      MPActivities.ActivityType,

      @ObjectModel: {foreignKey.association: '_IssueCategory'}
      @ObjectModel.text.element: 'IssueCategoryName'
      MPActivities.IssueCategory,

      @Semantics.text: true
      @Search.fuzzinessThreshold: 0.8
      _IssueCategory._Text[1:Language = $session.system_language].IssueCategoryName                                                                                                                                                                                   as  IssueCategoryName,

      MPActivities.OriginApplication,

      @ObjectModel: {foreignKey.association: '_Status'}
      @ObjectModel.text.element: 'ActivityStatusName'
      MPActivities.Status,

      @UI.lineItem
      @Semantics.text: true
      @Search.defaultSearchElement: true
      cast(_Status.ActivityStatusName as /cpd/activity_status)                                                                                                                                                                                                        as  ActivityStatusName,

      cast( _MstrProjChklstPrioCode._Text[1:Language = $session.system_language].MstrProjChklstPrioCodeTxt as /cpd/chk_priority_desc)                                                                                                                                 as  MstrProjChklstPrioCodeTxt,

      @Semantics.user.lastChangedBy: true
      MPActivities.LastChangedByUser,

      @Semantics.user.createdBy: true
      MPActivities.CreatedByUser,
      MPActivities.CreatedByUserFullName,
      MPActivities.LastChangedByUserFullName,

      MPActivities.ChangedOnDateTime,
      @Semantics.systemDateTime.lastChangedAt: true
      @Consumption.filter.hidden: true
      MPActivities.ChangedDate
                                                                                                                                                                                                                                                                      as  ChangedDate,
      MPActivities.CreationDate                                                                                                                                                                                                                                       as  CreationDate,

      @Semantics.text: true
      @Search.fuzzinessThreshold: 0.8
      @Search.defaultSearchElement: true
      MPActivities.ActivityName,

      @Semantics.calendarItem.dtStart: true
      MPActivities.PlannedStartDate,

      @Semantics.calendarItem.dtEnd: true
      MPActivities.PlannedEndDate,

      @Semantics.calendarItem.dtStart: true
      MPActivities.ActualStartDate,

      @Semantics.calendarItem.dtEnd: true
      MPActivities.ActualEndDate,

      _TeamMemberUserId.EmailAddress,

      _TeamMemberUserId.MobilePhoneNumber,

      _TeamMemberUserId.PhoneNumber,

      @Consumption.valueHelpDefinition: [
       { entity: { name:    'I_MstrProjBusPartnerByRoleVH',
                    element: 'BusinessPartner'
                          } }]
      @ObjectModel.text.element: 'BusinessPartnerFullName'
      // @ObjectModel: {foreignKey.association: '_BusinessPartner'}

      _TeamMemberUserId.BusinessPartner,

      @Semantics.text: true
      _TeamMemberUserId.BusinessPartnerFullName,

      _TeamMemberUserId.BusinessPartnerRoleName,

      _TeamMemberUserId.BusinessPartnerUUID,
      @Consumption.hidden: true
      @UI.hidden: true
      _TeamMemberUserId.IsBusinessPurposeCompleted                                                                                                                                                                                                                    as  IsBusinessPurposeCompleted,
      _TeamMemberUserId.PartnerUUID,

      @ObjectModel: {foreignKey.association: '_MstrProjActyStsCat'}
      @ObjectModel.text.element: 'ActivityStatusName'
      MPActivities.IsCompleted,

      @ObjectModel: {foreignKey.association: '_MstrProjUsrInvlmntStatus'}
      cast(case when _TeamMemberUserId.UserID = $session.user
      then 'I'
      else 'N'
      end as /cpd/cpm_isuser_status )                                                                                                                                                                                                                                 as  IsUserStatus,

     _MstrProjTeamMemberID,    
      _DocumentURL,
      _ProjectActivity,
      _Activity,
      _Status,
      _BusinessPartner,
      _MstrProjIssueType,
      _MasterProject,
      _IssueCategory,
      _MstrProjActyStsCat,
      _MstrProjUsrInvlmntStatus,
      _MstrProjActyRefVH,
      _MstrProjActyVH,
      _MasterProjectType,
      MPActivities._ChangedByUser,
      MPActivities._CreatedByUser

}