C_MaintNotificationItemTP

@AbapCatalog.sqlViewName: 'CNOTIFITTP'
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Notification Item'

@VDM.viewType: #CONSUMPTION

@ObjectModel.transactionalProcessingDelegated:true

@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL


@ObjectModel: {
  representativeKey : 'MaintenanceNotificationItem',
  semanticKey: [ 'MaintenanceNotificationItem', 'MaintenanceNotification']
}

@AccessControl.privilegedAssociations: ['_MaintNotifObjPrtCodeText', '_MaintNotificationDamageCodeT']

define view C_MaintNotificationItemTP
  as select from I_MaintNotificationItemTP
  association [1..1] to C_MaintNotificationTP      as _MaintNotificationTP           on  _MaintNotificationTP.MaintenanceNotification = $projection.MaintenanceNotification

  association [0..*] to C_MaintNotificationCauseTP as _MaintNotificationCauseTP      on  _MaintNotificationCauseTP.MaintenanceNotification     = $projection.MaintenanceNotification
                                                                                     and _MaintNotificationCauseTP.MaintenanceNotificationItem = $projection.MaintenanceNotificationItem

  //Damage Coding

  association [0..1] to I_Inspectioncatalog        as _MaintNotifDamageCodeCatalog   on  $projection.MaintNotifDamageCodeCatalog = _MaintNotifDamageCodeCatalog.InspectionCatalog
  association [0..1] to I_InspectionCodeGroup      as _MaintNotifDamageCodeGroup     on  $projection.MaintNotifDamageCodeGroup   = _MaintNotifDamageCodeGroup.InspectionCodeGroup
                                                                                     and $projection.MaintNotifDamageCodeCatalog = _MaintNotifDamageCodeGroup.InspectionCatalog
  association [0..*] to I_Inspectioncodegrouptext  as _MaintNotifDamageCodeGroupText on  $projection.MaintNotifDamageCodeGroup   = _MaintNotifDamageCodeGroupText.InspectionCodeGroup
                                                                                     and $projection.MaintNotifDamageCodeCatalog = _MaintNotifDamageCodeGroupText.InspectionCatalog
  association [0..1] to I_InspectionCode           as _MaintNotificationDamageCode   on  $projection.MaintNotificationDamageCode = _MaintNotificationDamageCode.InspectionCode
                                                                                     and $projection.MaintNotifDamageCodeCatalog = _MaintNotificationDamageCode.InspectionCatalog
                                                                                     and $projection.MaintNotifDamageCodeGroup   = _MaintNotificationDamageCode.InspectionCodeGroup
  association [0..*] to I_InspectionCodeText       as _MaintNotificationDamageCodeT  on  $projection.MaintNotificationDamageCode = _MaintNotificationDamageCodeT.InspectionCode
                                                                                     and $projection.MaintNotifDamageCodeCatalog = _MaintNotificationDamageCodeT.InspectionCatalog
                                                                                     and $projection.MaintNotifDamageCodeGroup   = _MaintNotificationDamageCodeT.InspectionCodeGroup
  //Object Part Coding_MaintNotificationDamageCodeT

  association [0..1] to I_Inspectioncatalog        as _MaintNotifObjPrtCodeCatalog   on  $projection.MaintNotifObjPrtCodeCatalog = _MaintNotifObjPrtCodeCatalog.InspectionCatalog
  association [0..1] to I_InspectionCodeGroup      as _MaintNotifObjPrtCodeGroup     on  $projection.MaintNotifObjPrtCodeGroup   = _MaintNotifObjPrtCodeGroup.InspectionCodeGroup
                                                                                     and $projection.MaintNotifObjPrtCodeCatalog = _MaintNotifObjPrtCodeGroup.InspectionCatalog
  association [0..*] to I_Inspectioncodegrouptext  as _MaintNotifObjPrtCodeGroupText on  $projection.MaintNotifObjPrtCodeGroup   = _MaintNotifObjPrtCodeGroupText.InspectionCodeGroup
                                                                                     and $projection.MaintNotifObjPrtCodeCatalog = _MaintNotifObjPrtCodeGroupText.InspectionCatalog
  association [0..1] to I_InspectionCode           as _MaintNotifObjPrtCode          on  $projection.MaintNotifObjPrtCode        = _MaintNotifObjPrtCode.InspectionCode
                                                                                     and $projection.MaintNotifObjPrtCodeCatalog = _MaintNotifObjPrtCode.InspectionCatalog
                                                                                     and $projection.MaintNotifObjPrtCodeGroup   = _MaintNotifObjPrtCode.InspectionCodeGroup
  association [0..*] to I_InspectionCodeText       as _MaintNotifObjPrtCodeText      on  $projection.MaintNotifObjPrtCode        = _MaintNotifObjPrtCodeText.InspectionCode
                                                                                     and $projection.MaintNotifObjPrtCodeCatalog = _MaintNotifObjPrtCodeText.InspectionCatalog
                                                                                     and $projection.MaintNotifObjPrtCodeGroup   = _MaintNotifObjPrtCodeText.InspectionCodeGroup
{

      @ObjectModel.foreignKey.association: '_MaintNotificationTP'
      @UI.hidden: true
  key I_MaintNotificationItemTP.MaintenanceNotification,
      @ObjectModel.text.element:  [ 'MaintNotifItemText' ]
      @EndUserText.label: 'Damage'
  key I_MaintNotificationItemTP.MaintenanceNotificationItem,

      @UI.hidden: true
      I_MaintNotificationItemTP.MaintNotificationItemForEdit,

      @Semantics.text: true
      I_MaintNotificationItemTP.MaintNotifItemText,

      // Object Part

      //--[ GENERATED:012:GFBfhxvv7jY4hCRG3B4jvm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_InspectionCodeStdVH',
                     element: 'InspectionCode' },
          additionalBinding: [{ localElement: 'MaintNotifObjPrtCodeCatalog',
                                element: 'InspectionCatalog' },
                              { localElement: 'MaintNotifObjPrtCodeGroup',
                                element: 'InspectionCodeGroup' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_MaintNotifObjPrtCode'
      @ObjectModel.text.association: '_MaintNotifObjPrtCodeText'
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      cast( I_MaintNotificationItemTP.MaintNotifObjPrtCode  as eam_object_part_code )                                                                                                                                         as MaintNotifObjPrtCode,

      // Damage

      //--[ GENERATED:012:GFBfhxvv7jY4hCRG3B4jvm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_InspectionCodeStdVH',
                     element: 'InspectionCode' },
          additionalBinding: [{ localElement: 'MaintNotifDamageCodeCatalog',
                                element: 'InspectionCatalog' },
                              { localElement: 'MaintNotifDamageCodeGroup',
                                element: 'InspectionCodeGroup' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_MaintNotificationDamageCode'
      @ObjectModel.text.association: '_MaintNotificationDamageCodeT'
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      cast( I_MaintNotificationItemTP.MaintNotificationDamageCode  as eam_damage_code )                                                                                                                                       as MaintNotificationDamageCode,

      @ObjectModel.foreignKey.association: '_MaintNotifDamageCodeCatalog'
      @UI.hidden: true
      I_MaintNotificationItemTP.MaintNotifDamageCodeCatalog,
      //--[ GENERATED:012:GFBfhxvv7jY4hCRG3B4jvm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_InspectionCodeGroupStdVH',
                     element: 'InspectionCodeGroup' },
          additionalBinding: [{ localElement: 'MaintNotifDamageCodeCatalog',
                                element: 'InspectionCatalog' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_MaintNotifDamageCodeGroup'
      @ObjectModel.text.association: '_MaintNotifDamageCodeGroupText'
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      I_MaintNotificationItemTP.MaintNotifDamageCodeGroup,

      @ObjectModel.foreignKey.association: '_MaintNotifObjPrtCodeCatalog'
      @UI.hidden: true
      I_MaintNotificationItemTP.MaintNotifObjPrtCodeCatalog,
      //--[ GENERATED:012:GFBfhxvv7jY4hCRG3B4jvm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_InspectionCodeGroupStdVH',
                     element: 'InspectionCodeGroup' },
          additionalBinding: [{ localElement: 'MaintNotifObjPrtCodeCatalog',
                                element: 'InspectionCatalog' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_MaintNotifObjPrtCodeGroup'
      @ObjectModel.text.association: '_MaintNotifObjPrtCodeGroupText'
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      I_MaintNotificationItemTP.MaintNotifObjPrtCodeGroup,

      @UI.hidden: true
      I_MaintNotificationItemTP.IsDeleted,

      /* Associations */
      I_MaintNotificationItemTP._IsDeleted,
      I_MaintNotificationItemTP._MaintenanceNotification,


      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _MaintNotificationTP,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _MaintNotificationCauseTP,


      @ObjectModel.readOnly: true
      _MaintNotificationCauseTP[1: IsMaintNotificationRootCause = 'X' ].IsMaintNotificationRootCause,


      _MaintNotifDamageCodeCatalog,
      _MaintNotifDamageCodeGroup,
      _MaintNotificationDamageCode,
      _MaintNotifObjPrtCodeCatalog,
      _MaintNotifObjPrtCodeGroup,
      _MaintNotifObjPrtCode,
      _MaintNotifObjPrtCodeGroupText,
      _MaintNotifObjPrtCodeText,
      _MaintNotifDamageCodeGroupText,
      _MaintNotificationDamageCodeT

}
where
  I_MaintNotificationItemTP.IsDeleted != 'X'