C_MaintNotificationCauseTP

@EndUserText.label: 'Maintenance Notification Cause'

@AbapCatalog.sqlViewName: 'CNTFCAUSETETP'
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL

@ObjectModel: {
  representativeKey : 'MaintenanceNotificationCause',
  semanticKey: ['MaintenanceNotificationCause', 'MaintenanceNotificationItem', 'MaintenanceNotification'],
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,
  transactionalProcessingDelegated: true
}

define view C_MaintNotificationCauseTP
  as select from I_MaintNotificationCauseTP
  association [1..1] to C_MaintNotificationTP     as _MaintNotificationTP          on  _MaintNotificationTP.MaintenanceNotification = $projection.MaintenanceNotification
  association [1..1] to C_MaintNotificationItemTP as _MaintNotificationItemTP      on  $projection.MaintenanceNotification     = _MaintNotificationItemTP.MaintenanceNotification
                                                                                   and $projection.MaintenanceNotificationItem = _MaintNotificationItemTP.MaintenanceNotificationItem
  association [0..*] to I_InspectionCodeText      as _MaintNotifCauseCodeText      on  $projection.MaintNotificationCauseCode = _MaintNotifCauseCodeText.InspectionCode
                                                                                   and $projection.MaintNotifCauseCodeCatalog = _MaintNotifCauseCodeText.InspectionCatalog
                                                                                   and $projection.MaintNotifCauseCodeGroup   = _MaintNotifCauseCodeText.InspectionCodeGroup
  association [0..*] to I_Inspectioncodegrouptext as _MaintNotifCauseCodeGroupText on  $projection.MaintNotifCauseCodeCatalog = _MaintNotifCauseCodeGroupText.InspectionCatalog
                                                                                   and $projection.MaintNotifCauseCodeGroup   = _MaintNotifCauseCodeGroupText.InspectionCodeGroup

{

  key I_MaintNotificationCauseTP.MaintenanceNotificationCause,
      @ObjectModel.foreignKey.association: '_MaintNotificationItemTP'
  key I_MaintNotificationCauseTP.MaintenanceNotificationItem,
      @ObjectModel.foreignKey.association: '_MaintNotificationTP'
  key I_MaintNotificationCauseTP.MaintenanceNotification,
      I_MaintNotificationCauseTP.MaintNotificationCauseForEdit,
      I_MaintNotificationCauseTP.MaintNotifCauseText,

      @Consumption.valueHelp: '_MaintNotifCauseCodeVH'
      @ObjectModel.text.association: '_MaintNotifCauseCodeText'
      I_MaintNotificationCauseTP.MaintNotificationCauseCode,
      @ObjectModel.text.association: '_MaintNotifCauseCodeGroupText'
      I_MaintNotificationCauseTP.MaintNotifCauseCodeGroup,
      I_MaintNotificationCauseTP.MaintNotifCauseCodeCatalog,
      I_MaintNotificationCauseTP.IsDeleted,
      I_MaintNotificationCauseTP.MaintNotifCauseSortNumber,

      I_MaintNotificationCauseTP.IsMaintNotificationRootCause,



      /* Associations */
      I_MaintNotificationCauseTP._IsDeleted,
      I_MaintNotificationCauseTP._MaintenanceNotification,
      I_MaintNotificationCauseTP._MaintNotifCauseCodeCatalog,
      I_MaintNotificationCauseTP._MaintNotifCauseCodeGroup,
      I_MaintNotificationCauseTP._MaintNotificationCauseCode,
      _MaintNotifCauseCodeGroupText,
      _MaintNotifCauseCodeText,
      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
      _MaintNotificationItemTP,
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
      _MaintNotificationTP
}
where
  I_MaintNotificationCauseTP.IsDeleted != 'X'