C_InvoiceListObjPg

@AbapCatalog: { 
  sqlViewName: 'CINVLISTOP',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl: {
  authorizationCheck: #CHECK,
  privilegedAssociations: [ '_SDDocumentPartnerCard' ],
  personalData: {
    blocking: #REQUIRED
  }
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION

@Metadata.allowExtensions: true

@ObjectModel: {
  compositionRoot: true,
  semanticKey:     ['InvoiceList'],
  usageType: {
    serviceQuality: #C,
    sizeCategory: #L,
    dataClass: #MIXED
   }
}

@Search.searchable: false

define view C_InvoiceListObjPg
  as select from I_InvoiceList as InvoiceList

  association [0..*] to C_InvoiceListItemObjPg    as _Item                    on  $projection.InvoiceList = _Item.InvoiceList
  association [0..*] to C_SDDocumentPartnerCard   as _SDDocumentPartnerCard   on  $projection.InvoiceList               = _SDDocumentPartnerCard.SDDocument
                                                                              and _SDDocumentPartnerCard.SDDocumentItem = '000000'
  association [0..1] to I_InvoiceListRemuneration as _InvoiceListRemuneration on  $projection.InvoiceList = _InvoiceListRemuneration.InvoiceList

{

  key InvoiceList.InvoiceList,

      
      InvoiceList.PayerParty,
      
      

      @Semantics.businessDate.at: true
      InvoiceList.BillingDocumentDate,
      InvoiceList.TotalNetAmount,
      InvoiceList.TotalTaxAmount,

      InvoiceList.TransactionCurrency,

      InvoiceList.CompanyCode,

      InvoiceList.SalesOrganization,

      InvoiceList.DocumentReferenceID,

      InvoiceList.CustomerPaymentTerms,

      InvoiceList.AccountingTransferStatus,

      InvoiceList.BillingDocumentType,
      InvoiceList._BillingDocumentType._Text[1: Language = $session.system_language ].BillingDocumentTypeName                                                       as BillingDocumentTypeName,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      _InvoiceListRemuneration.TotalRemunerationNetAmount                                                                                                           as TotalRemunerationNetAmount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      _InvoiceListRemuneration.TotalRemunerationTaxAmount                                                                                                           as TotalRemunerationTaxAmount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast( TotalTaxAmount + TotalNetAmount + _InvoiceListRemuneration.TotalRemunerationNetAmount + _InvoiceListRemuneration.TotalRemunerationTaxAmount  as sum_rl) as TotalGrossAmount,
      //InvoiceList.TotalGrossAmount,


      InvoiceList._PayerParty,
      InvoiceList._BillingDocumentType,
      InvoiceList._SalesOrganization,
      InvoiceList._CompanyCode,
      InvoiceList._CustomerPaymentTerms,
      InvoiceList._AccountingTransferStatus,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _Item,

      _SDDocumentPartnerCard

}