C_SDDocumentPartnerCard

@AbapCatalog.sqlViewName: 'CSDDOCPARTCARD'
@ClientHandling.algorithm:#SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@EndUserText.label: 'Business Partner for Fact Sheets'

@ObjectModel: {
   semanticKey: ['SDDocument','SDDocumentItem'],
   usageType.dataClass: #TRANSACTIONAL,
   usageType.serviceQuality: #C,
   usageType.sizeCategory: #L
}

define view C_SDDocumentPartnerCard

  as select from I_SDDocumentCompletePartners as SDPartner
  
  association [1]    to I_WorkAssignment               as _WorkAssignment               on $projection.Personnel        = _WorkAssignment.WorkAssignment
  
  association [0..1] to I_AddrCurDfltLandlinePhoneNmbr as _CurrentDfltLandlinePhoneNmbr on  $projection.AddressID       = _CurrentDfltLandlinePhoneNmbr.AddressID
                                                                                        and $projection.AddressPersonID = _CurrentDfltLandlinePhoneNmbr.AddressPersonID 

  association [0..1] to I_AddrCurDefaultEmailAddress   as _CurrentDfltEmailAddress      on  $projection.AddressID       = _CurrentDfltEmailAddress.AddressID
                                                                                        and $projection.AddressPersonID = _CurrentDfltEmailAddress.AddressPersonID

  association [0..1] to I_AddrCurDfltMobilePhoneNumber as _CurrentDfltMobilePhoneNumber on  $projection.AddressID       = _CurrentDfltMobilePhoneNumber.AddressID
                                                                                        and $projection.AddressPersonID = _CurrentDfltMobilePhoneNumber.AddressPersonID
  

{

      @UI.hidden: true
      @ObjectModel: { readOnly: true }
  key SDPartner.SDDocument,

      @UI.hidden: true
      @ObjectModel: { readOnly: true }
  key SDPartner.SDDocumentItem,
        
  key cast(SDPartner.PartnerFunction as parvw_unv preserving type )           as PartnerFunction,

      @Semantics:   { organization.role: true }
      SDPartner._PartnerFunction._Text[1: Language = $session.system_language].PartnerFunctionName,

      @Semantics.contact.type: #ORGANIZATION
      case
        when SDPartner.Customer != ''
            then SDPartner.Customer
        when SDPartner.Supplier != ''
            then SDPartner.Supplier
        when SDPartner.Personnel != '00000000'
            then cast(SDPartner.Personnel as kunnr)
        when SDPartner.ContactPerson != '0000000000'
            then cast(SDPartner.ContactPerson as kunnr)
        else
            ''
        end as BusinessPartner,

      @UI.hidden: true
      SDPartner.Customer,
      @UI.hidden: true
      SDPartner.Personnel,
      @UI.hidden: true
      SDPartner.ContactPerson,
      @UI.hidden: true
      SDPartner.AddressID,
      @UI.hidden: true
      SDPartner.AddressPersonID,
      @UI.hidden: true
      SDPartner.AddressObjectType,
      @UI.hidden: true
      SDPartner.SDDocPartnerAddressRefType,
      
      @Semantics.name.fullName: true
      @Semantics.text: true
      case
        when SDPartner.ContactPerson != '0000000000'
          then 
          coalesce(SDPartner._DfltAddrRprstn.AddresseeFullName, cast(substring(replace(concat(_ContactPerson.FirstName, concat(' &@', _ContactPerson.LastName)), '&@', ''),1,80) as ad_namtext ) )
        when SDPartner.Personnel != '00000000'
         then 
          coalesce(SDPartner._DfltAddrRprstn.AddresseeFullName, coalesce(_WorkAssignment.PersonFullName, _WorkAssignment._BusinessPartner.LastName))
        else 
          SDPartner._DfltAddrRprstn.AddresseeFullName
        end
      as FullName,

      @Semantics.telephone.type: [#WORK]
      @ObjectModel.text.element: ['FormattedPostalAddressDesc']
      case AddressID
         when ''
            then _WorkAssignment._WorkplaceAddress.NormalizedPhoneNumber
         else _CurrentDfltLandlinePhoneNmbr.InternationalPhoneNumber
      end   as InternationalPhoneNumber,

      @Semantics.telephone.type: [#CELL]
      case AddressID
         when ''
            then _WorkAssignment._WorkplaceAddress.MblNormalizedPhoneNumber
         else _CurrentDfltMobilePhoneNumber.InternationalPhoneNumber
      end   as InternationalMobilePhoneNumber,

      @Semantics.eMail.address: true
      @Semantics.eMail.type:  [#WORK]
      case AddressID
         when ''
            then _WorkAssignment._WorkplaceAddress.DefaultEmailAddress
         else _CurrentDfltEmailAddress.EmailAddress
      end   as EmailAddress,

      SDPartner._PartnerFunction,
      
      @Semantics.address.label: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_S4H_SDOC_ODATA_UTIL'
      cast ( '' as ad_line_s ) as  FormattedPostalAddressDesc
}