C_IHBLimitApprovalStartEml

@AbapCatalog.sqlViewName: 'CIHBLIMEML'
@EndUserText.label: 'IHB Limit Email Template Data Provider'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType : {
  serviceQuality: #D,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@VDM.viewType : #CONSUMPTION
@ObjectModel.supportedCapabilities:[ #OUTPUT_EMAIL_DATA_PROVIDER ]
@Metadata.ignorePropagatedAnnotations:true
define view C_IHBLimitApprovalStartEml
  as select from I_WorkflowTask           as _Workflowtask
    join         I_WorkflowTaskApplObject as _WorkflowTaskApplObject on  _WorkflowTaskApplObject.WorkflowTaskInternalID        = _Workflowtask.WorkflowTaskInternalID
                                                                     and _WorkflowTaskApplObject.WorkflowObjectRole            = '99'
                                                                     and _WorkflowTaskApplObject.TechnicalWrkflwObjectType     = '/PF1/CL_IHB_LIMIT_WORKFLOW'
                                                                     and _WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'CL'
    join         R_IHBMasterDataObjectTP  as _IHBMasterDataObjectTP  on  _WorkflowTaskApplObject.TechnicalWrkflwObject = bintohex(
      _IHBMasterDataObjectTP.IHBObjectReferenceUUID
    )
                                                                     and _IHBMasterDataObjectTP.IHBReleaseStatus       = '01'
  association [0..1] to I_WorkflowTaskURL as _WorkflowTaskURL on $projection.WorkflowTaskInternalID = _WorkflowTaskURL.WorkflowTaskInternalID
  association [0..1] to I_User            as _User            on $projection.IHBObjectChangedByUser = _User.UserID
{
  key _Workflowtask.WorkflowTaskInternalID,
      _IHBMasterDataObjectTP.IHBBankArea,
      _IHBMasterDataObjectTP.IHBObjectLevel,
      _IHBMasterDataObjectTP._IHBObjectLevel._IHBObjectLevelT[1:Language = $session.system_language ].IHBObjectLevelText,
      _IHBMasterDataObjectTP._IHBAccount.IHBAccountNumber,
      _IHBMasterDataObjectTP._IHBAccount._IHBAccountText[1:IHBAccountLanguage = $session.system_language ].IHBAccountDescription,
      _IHBMasterDataObjectTP._IHBGroupType.InhouseBankGroupID,
      _IHBMasterDataObjectTP._IHBGroupType._IHBGroupTypeText[1:IHBGroupLanguage = $session.system_language ].IHBGroupDescription,
      _IHBMasterDataObjectTP.IHBObjectApprovalActivity,

      case _IHBMasterDataObjectTP.IHBObjectLevel
      when '01' then concat_with_space('Single Limit For Account', _IHBMasterDataObjectTP._IHBAccount.IHBAccountNumber, 1 ) //Single

      when '02' then concat_with_space('Group Limit', _IHBMasterDataObjectTP._IHBGroupType.InhouseBankGroupID, 1 ) //Group

      end                                                                                          as IHBObjectEmailHeaderText,

      case _IHBMasterDataObjectTP.IHBObjectLevel
      when '01' then concat_with_space('Account:', _IHBMasterDataObjectTP._IHBAccount.IHBAccountNumber, 1 ) //Single

      when '02' then concat_with_space('Group:', _IHBMasterDataObjectTP._IHBGroupType.InhouseBankGroupID, 1 ) //Group

      end                                                                                          as IHBObjectLevelEmailText,

      _IHBMasterDataObjectTP.IHBObjectChangedDateTime                                              as IHBObjectChangedDateTime,
      cast(tstmp_to_dats( IHBObjectChangedDateTime, 'UTC', $session.client, 'NULL' ) as sww_lsd )  as IHBObjectChangedDate,
      cast(tstmp_to_tims( IHBObjectChangedDateTime, 'UTC', $session.client, 'NULL' ) as sww_lst )  as IHBObjectChangedTime,

      _IHBMasterDataObjectTP.IHBObjectDeadlineDateTime                                             as IHBObjectDeadlineDateTime,
      cast(tstmp_to_dats( IHBObjectDeadlineDateTime, 'UTC', $session.client, 'NULL' ) as sww_lsd ) as IHBObjectDeadlineDate,
      cast(tstmp_to_tims( IHBObjectDeadlineDateTime, 'UTC', $session.client, 'NULL' ) as sww_lst ) as IHBObjectDeadlineTime,

      _IHBMasterDataObjectTP.IHBObjectChangedByUser,
      _User.UserDescription                                                                        as IHBObjectChangedByUserText,

      _Workflowtask._WorkflowTaskResult._WorkflowTaskResultReason._WorkflowTaskResultReasonText[1:Language=$session.system_language].WorkflowTaskResultReasonText,
      _Workflowtask._WorkflowTaskResult.WorkflowTaskResultComment,

      _Workflowtask.WrkflwTskCreationUTCDateTime,

      _WorkflowTaskURL.WorkflowTaskURL
}