C_IHBAccountApprovalStartEml

@AbapCatalog.sqlViewName: 'CIHBARRPEML2'
@EndUserText.label: 'IHB Account Email Template Provider'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@VDM.viewType : #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType : {
  serviceQuality: #D,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@ObjectModel.supportedCapabilities:[ #OUTPUT_EMAIL_DATA_PROVIDER ] 
@Metadata.ignorePropagatedAnnotations:true
define view C_IHBAccountApprovalStartEml
  as select from I_WorkflowTask           as _Workflowtask
    join         I_WorkflowTaskApplObject as _WorkflowTaskApplObject on  _WorkflowTaskApplObject.WorkflowTaskInternalID        = _Workflowtask.WorkflowTaskInternalID
                                                                     and _WorkflowTaskApplObject.WorkflowObjectRole            = '99'
                                                                     and _WorkflowTaskApplObject.TechnicalWrkflwObjectType     = '/PF1/CL_IHBACC_REL_WORKFLOW'
                                                                     and _WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'CL'
    join         R_IHBAccountTP           as _IHBAccountTP           on  _WorkflowTaskApplObject.TechnicalWrkflwObject = bintohex(
      _IHBAccountTP.IHBAccountReferenceUUID
    )
                                                                     and _IHBAccountTP.IHBAccountStatus                <> '02'
  association [0..1] to I_WorkflowTaskURL      as _WorkflowTaskURL    on $projection.WorkflowTaskInternalID = _WorkflowTaskURL.WorkflowTaskInternalID
  association [0..1] to I_IHBBankArea          as _IHBBankArea        on $projection.IHBBankArea = _IHBBankArea.IHBBankArea
  association [0..1] to C_IHBAccountActivityVH as _IHBAccountActivity on $projection.IHBAccountApprovalActivity = _IHBAccountActivity.IHBAccountActivity
{
  key _Workflowtask.WorkflowTaskInternalID,
      _IHBAccountTP.IHBAccountUUID,
      _IHBAccountTP.IHBAccountApprovalActivity,
      _IHBAccountActivity.IHBAccountActivityText,
      _IHBAccountTP.IHBBankArea,
      _IHBBankArea.IHBBankKey,
      _IHBBankArea.IHBBankAreaCountry,
      _IHBAccountTP.IHBAccountNumber,
      _IHBAccountTP.IHBAccountCurrency,
      _IHBAccountTP.IHBAccountHolder,
      _IHBAccountTP.IHBAccountAliasName,
      _IHBAccountTP.IHBAccountGroupName,

      _IHBAccountTP.IHBAccountChangedByUser,
      _IHBAccountTP._ChangedBy.UserDescription                                                                   as IHBAccountChangedByUserText,

      cast(tstmp_to_dats( _IHBAccountTP.IHBAccountChangedDateTime, 'UTC', $session.client, 'NULL' ) as sww_lsd ) as IHBAccountChangedDate,
      cast(tstmp_to_tims( _IHBAccountTP.IHBAccountChangedDateTime, 'UTC', $session.client, 'NULL' ) as sww_lst ) as IHBAccountChangedTime,

      _WorkflowTaskURL.WorkflowTaskURL
}