C_CustRetWrkflwEmailTemplate

DDL: C_CUSTRETWRKFLWEMAILTEMPLATE SQL: CSDCRWFEMLTMPL Type: view CONSUMPTION

Email Template for Cust Ret Wrkflw

C_CustRetWrkflwEmailTemplate is a Consumption CDS View that provides data about "Email Template for Cust Ret Wrkflw" in SAP S/4HANA. It reads from 1 data source (I_WorkflowTask) and exposes 20 fields with key field WorkflowTaskInternalID.

1 data source(s) 20 fields

Data Sources (1)

SourceAliasJoin Type
I_WorkflowTask Workflowtask from

Annotations (10)

NameValueLevelField
AbapCatalog.sqlViewName CSDCRWFEMLTMPL view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Email Template for Cust Ret Wrkflw view
VDM.viewType #CONSUMPTION view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view

Fields (20)

KeyFieldSource TableSource FieldDescription
KEY WorkflowTaskInternalID I_WorkflowTask WorkflowTaskInternalID
CustomerReturn CustomerReturn CustomerReturn
SalesOrganizationName
SalesOrganization CustomerReturn SalesOrganization
DistributionChannelName
DistributionChannel CustomerReturn DistributionChannel
DivisionName
OrganizationDivision CustomerReturn OrganizationDivision
CustomerReturnTypeName
CustomerReturnType CustomerReturn CustomerReturnType
CustomerReturnDate CustomerReturn CustomerReturnDate
SDDocumentReasonText
SDDocumentReason CustomerReturn SDDocumentReason
CustomerName _SoldToParty CustomerName
SoldToParty CustomerReturn SoldToParty
TransactionCurrency CustomerReturn TransactionCurrency
TotalNetAmount CustomerReturn TotalNetAmount
WorkflowTaskPriority I_WorkflowTask WorkflowTaskPriority
WorkflowTaskStatus I_WorkflowTask WorkflowTaskStatus
WorkflowTaskURL _WorkflowTaskURL WorkflowTaskURL 
@AbapCatalog.sqlViewName: 'CSDCRWFEMLTMPL'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@EndUserText.label: 'Email Template for Cust Ret Wrkflw'
@VDM.viewType : #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType : {
  serviceQuality: #D,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
define view C_CustRetWrkflwEmailTemplate as select from I_WorkflowTask as Workflowtask
  left outer to one join  I_WorkflowTaskApplObject as WorkflowTaskApplObject on  WorkflowTaskApplObject.WorkflowTaskInternalID        = Workflowtask.WorkflowTaskInternalID
                                                                             and WorkflowTaskApplObject.SAPObjectNodeRepresentation   = 'CustomerReturn'
                                                                             and WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'CL'
  left outer to one join I_CustomerReturn          as CustomerReturn         on  CustomerReturn.CustomerReturn                        = WorkflowTaskApplObject.TechnicalWrkflwObject
  association[0..1] to   I_CustomerReturnType      as _CustomerReturnType    on  _CustomerReturnType.CustomerReturnType               = CustomerReturn.CustomerReturnType
  association[0..1] to   I_WorkflowTaskURL         as _WorkflowTaskURL       on  _WorkflowTaskURL.WorkflowTaskInternalID              = Workflowtask.WorkflowTaskInternalID
{
  key Workflowtask.WorkflowTaskInternalID,
      CustomerReturn.CustomerReturn,

      _SalesOrganization._Text[1: Language=$session.system_language ].SalesOrganizationName,
      CustomerReturn.SalesOrganization,

      _DistributionChannel._Text[1: Language=$session.system_language ].DistributionChannelName,
      CustomerReturn.DistributionChannel,

      _OrganizationDivision._Text[1: Language=$session.system_language ].DivisionName,
      CustomerReturn.OrganizationDivision,

      cast(_CustomerReturnType._Text[1:Language=$session.system_language].SalesDocumentTypeName as sd_customer_return_type_name preserving type) as CustomerReturnTypeName,
      CustomerReturn.CustomerReturnType,

      CustomerReturn.CustomerReturnDate,

      _SDDocumentReason._Text[1:Language=$session.system_language].SDDocumentReasonText,
      CustomerReturn.SDDocumentReason,

      _SoldToParty.CustomerName as CustomerName,
      CustomerReturn.SoldToParty,

      @Semantics.currencyCode:true
      CustomerReturn.TransactionCurrency,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturn.TotalNetAmount,

      Workflowtask.WorkflowTaskPriority,
      Workflowtask.WorkflowTaskStatus,
      _WorkflowTaskURL.WorkflowTaskURL
}

Learn More