C_CntrlPurReqnItmWrkflwDdlnEml

@AbapCatalog.sqlViewName: 'CTRLPURREQWFLEML'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Central PurchaseRequsition Wrkflw deadline email notifi'
@VDM.viewType : #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType : {
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@ObjectModel.supportedCapabilities: #OUTPUT_EMAIL_DATA_PROVIDER 
@Metadata.ignorePropagatedAnnotations:true
define view C_CntrlPurReqnItmWrkflwDdlnEml as select from    I_WorkflowTask   as _Workflowtask
    join I_WorkflowTaskApplObject       as _WorkflowTaskApplObject on  _WorkflowTaskApplObject.WorkflowTaskInternalID        = _Workflowtask.WorkflowTaskInternalID
                                                                              and _WorkflowTaskApplObject.WorkflowObjectRole            = '99'
                                                                              and _WorkflowTaskApplObject.SAPObjectNodeRepresentation   = 'CentralPurchaseRequisitionItem'
                                                                              and _WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'CL'
    left outer to one join I_PurchaseRequisitionItemAPI01 as _PurchaseRequisitionItem on  _PurchaseRequisitionItem.PurchaseRequisition      = _WorkflowTaskApplObject.SAPBusinessObjectNodeKey1
                                                                              and _PurchaseRequisitionItem.PurchaseRequisitionItem  = _WorkflowTaskApplObject.SAPBusinessObjectNodeKey2                                                                       
  association [0..1] to I_WorkflowTaskURL as _WorkflowTaskURL on $projection.WorkflowTaskInternalID = _WorkflowTaskURL.WorkflowTaskInternalID

{
  key _Workflowtask.WorkflowTaskInternalID,
      _PurchaseRequisitionItem.PurchaseRequisition      as PurchaseRequisition,
   _PurchaseRequisitionItem.PurchaseRequisitionItem  as PurchaseRequisitionItem,
      _PurchaseRequisitionItem.PurchaseReqnItemUniqueID as PurchaseReqnItemUniqueID,
      _PurchaseRequisitionItem.PurchasingDocument,
      _PurchaseRequisitionItem.PurchasingDocumentItem,
      _PurchaseRequisitionItem.PurReqnReleaseStatus,
      _PurchaseRequisitionItem.PurchaseRequisitionType,
      _PurchaseRequisitionItem.PurchasingDocumentSubtype,
      _PurchaseRequisitionItem.PurchasingDocumentItemCategory,
      _PurchaseRequisitionItem.PurchaseRequisitionItemText,
      _PurchaseRequisitionItem.AccountAssignmentCategory,
      _PurchaseRequisitionItem.MaterialGroup,
      _PurchaseRequisitionItem.PurchasingDocumentCategory,
       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      _PurchaseRequisitionItem.RequestedQuantity,
       @Semantics.unitOfMeasure: true
      _PurchaseRequisitionItem.BaseUnit,
       @Semantics.amount.currencyCode: 'PurReqnItemCurrency'
      _PurchaseRequisitionItem.PurchaseRequisitionPrice,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      _PurchaseRequisitionItem.PurReqnPriceQuantity,
      _PurchaseRequisitionItem.MaterialGoodsReceiptDuration,
      _PurchaseRequisitionItem.PurchaseRequisitionReleaseDate,
      _PurchaseRequisitionItem.SourceOfSupplyIsAssigned,
      _PurchaseRequisitionItem.SupplyingPlant,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      _PurchaseRequisitionItem.OrderedQuantity,
      @Semantics.amount.currencyCode: 'PurReqnItemCurrency'
      _PurchaseRequisitionItem.PurReqnLimitConsumptionAmt,
      _PurchaseRequisitionItem.DeliveryDate,
      _PurchaseRequisitionItem.CreationDate,
      _PurchaseRequisitionItem.ProcessingStatus,
      _PurchaseRequisitionItem.PurchasingInfoRecord,
      _PurchaseRequisitionItem.Supplier,
      _PurchaseRequisitionItem.FixedSupplier,
      _PurchaseRequisitionItem.RequisitionerName,
      _PurchaseRequisitionItem.CreatedByUser,
      _PurchaseRequisitionItem.PurReqCreationDate,
      _PurchaseRequisitionItem.DeliveryAddressID,
      _PurchaseRequisitionItem.ManualDeliveryAddressID,
      @Semantics.currencyCode: true
      _PurchaseRequisitionItem.PurReqnItemCurrency,
      _PurchaseRequisitionItem.MaterialPlannedDeliveryDurn,
      _PurchaseRequisitionItem.DelivDateCategory,
      _PurchaseRequisitionItem.MultipleAcctAssgmtDistribution,
      _PurchaseRequisitionItem.StorageLocation,
      _PurchaseRequisitionItem.PurReqnSSPRequestor,
      _PurchaseRequisitionItem.PurReqnSSPAuthor,
      _PurchaseRequisitionItem.PurchaseContract,
      _PurchaseRequisitionItem.PurReqnSourceOfSupplyType,
      _PurchaseRequisitionItem.PurchaseContractItem,
      _PurchaseRequisitionItem.ConsumptionPosting,
      _PurchaseRequisitionItem.PurReqnOrigin,
      _PurchaseRequisitionItem.PurReqnSSPCatalog,
      _PurchaseRequisitionItem.PurReqnSSPCatalogItem,
      _PurchaseRequisitionItem.PurReqnSSPCrossCatalogItem,
      @Semantics.booleanIndicator:true
      _PurchaseRequisitionItem.IsPurReqnBlocked,
      _PurchaseRequisitionItem.ItemDeliveryAddressID,
      _PurchaseRequisitionItem.Language,
      _PurchaseRequisitionItem.IsClosed,
      _PurchaseRequisitionItem.ReleaseIsNotCompleted,
      _PurchaseRequisitionItem.ServicePerformer,
      _PurchaseRequisitionItem.PurchaseRequisitionStatus,
      _PurchaseRequisitionItem.PerformancePeriodStartDate,
      _PurchaseRequisitionItem.PerformancePeriodEndDate,
      _PurchaseRequisitionItem.CompanyCode,
      _PurchaseRequisitionItem.SupplierMaterialNumber,
      _PurchaseRequisitionItem.Batch,
      _PurchaseRequisitionItem.MinRemainingShelfLife,
      @Semantics.amount.currencyCode: 'PurReqnItemCurrency'
      @EndUserText:{ label: 'Net Value'}
      _PurchaseRequisitionItem.ItemNetAmount,
      _PurchaseRequisitionItem.GoodsReceiptIsExpected,
      _PurchaseRequisitionItem.InvoiceIsExpected,
      _PurchaseRequisitionItem.GoodsReceiptIsNonValuated,
      _PurchaseRequisitionItem.RequirementTracking,
      _PurchaseRequisitionItem.MRPController,
      _PurchaseRequisitionItem.PurchaseRequisitionIsFixed,
      _PurchaseRequisitionItem.AddressID,
      _PurchaseRequisitionItem.LastChangeDateTime,
      _PurchaseRequisitionItem.ProcurementHubSourceSystem,
      _PurchaseRequisitionItem.ExtPurgOrgForPurg,
      _PurchaseRequisitionItem.ExtCompanyCodeForPurg,
      _PurchaseRequisitionItem.ExtPlantForPurg,
      _PurchaseRequisitionItem.ExtInfoRecordForPurg,
      _PurchaseRequisitionItem.ExtContractItemForPurg,
      _PurchaseRequisitionItem.ExtContractForPurg,
      _PurchaseRequisitionItem.ExtDesiredSupplierForPurg,
      _PurchaseRequisitionItem.ExtFixedSupplierForPurg,
      _PurchaseRequisitionItem.ExtMaterialForPurg,
      cast(tstmp_to_dats( _Workflowtask.WrkflwTskCreationUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_lsd ) as PurReqnWrkflwTskCrtnUTCDate,
      cast(tstmp_to_tims( _Workflowtask.WrkflwTskCreationUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_lst ) as PurReqnWrkflwTskCrtnUTCTime,
    //Deadline Due Time    

      cast(tstmp_to_dats( _TaskDueDate.WorkflowTaskDueUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_led ) as PurReqnWrkflwTaskDueUTCDate,
      cast(tstmp_to_tims( _TaskDueDate.WorkflowTaskDueUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_let ) as PurReqnWrkflwTaskDueUTCTime,
    
      _WorkflowTaskURL.WorkflowTaskURL
}