C_CntrlPurReqnHdrWrkflwDdlnEml

@AbapCatalog.sqlViewName: 'CTRLPURREQHWFEML'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Central PurchaseRequisition HDR Wrkflw Deadline Email Notif'
@VDM.viewType : #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType : {
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@ObjectModel.supportedCapabilities: #OUTPUT_EMAIL_DATA_PROVIDER 
@Metadata.ignorePropagatedAnnotations:true
@AccessControl.personalData.blocking:#REQUIRED
define view C_CntrlPurReqnHdrWrkflwDdlnEml as select from    I_WorkflowTask   as _Workflowtask
    join I_WorkflowTaskApplObject       as _WorkflowTaskApplObject on  _WorkflowTaskApplObject.WorkflowTaskInternalID        = _Workflowtask.WorkflowTaskInternalID
                                                                              and _WorkflowTaskApplObject.WorkflowObjectRole            = '99'
                                                                              and _WorkflowTaskApplObject.SAPObjectNodeRepresentation   = 'CentralPurchaseRequisition'
                                                                              and _WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'CL'
  left outer to one join  I_PurchaseRequisitionItemAPI01 as _PurchaseRequisitionItem on  _PurchaseRequisitionItem.PurchaseRequisition         = _WorkflowTaskApplObject.SAPBusinessObjectNodeKey1 
  association [0..1] to I_WorkflowTaskURL as _WorkflowTaskURL on $projection.WorkflowTaskInternalID = _WorkflowTaskURL.WorkflowTaskInternalID
  association [0..1] to P_PurReqnFacts2   as _PurReqnFacts2 on _PurReqnFacts2.PurchaseRequisition      = _WorkflowTaskApplObject.SAPBusinessObjectNodeKey1
                                                          

{
  key _Workflowtask.WorkflowTaskInternalID,
      _PurchaseRequisitionItem.PurchaseRequisition     as PurchaseRequisition,
      _PurchaseRequisitionItem.PurReqnReleaseStatus,
      _PurchaseRequisitionItem.PurchaseRequisitionType,
      _PurchaseRequisitionItem.PurchaseRequisitionItemText,
      _PurchaseRequisitionItem.PurchasingDocumentCategory,
      _PurchaseRequisitionItem.CreationDate,
      _PurchaseRequisitionItem.RequisitionerName,
      _PurchaseRequisitionItem.CreatedByUser,
      _PurchaseRequisitionItem.PurReqCreationDate,
      _PurchaseRequisitionItem.ProcurementHubSourceSystem,
      _PurchaseRequisitionItem.ExtPurgOrgForPurg,
      _PurchaseRequisitionItem.ExtCompanyCodeForPurg,
      _PurchaseRequisitionItem.ExtPlantForPurg,
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      @EndUserText: {label: 'Total Net Value'}
      _PurReqnFacts2.PurReqnTotalAmountInDspCrcy,
      @Semantics.currencyCode: true
      _PurReqnFacts2.DisplayCurrency,
      @EndUserText: {label: 'Number of Items'}
      _PurReqnFacts2.NumberOfItems,
      cast(tstmp_to_dats( _Workflowtask.WrkflwTskCreationUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_lsd ) as PurReqnWrkflwTskCrtnUTCDate ,
      cast(tstmp_to_tims( _Workflowtask.WrkflwTskCreationUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_lst ) as PurReqnWrkflwTskCrtnUTCTime,
    //Deadline Due Time    

      cast(tstmp_to_dats( _TaskDueDate.WorkflowTaskDueUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_led ) as PurReqnWrkflwTaskDueUTCDate,
      cast(tstmp_to_tims( _TaskDueDate.WorkflowTaskDueUTCDateTime, 'UTC', $session.client, 'NULL' ) as sww_let ) as PurReqnWrkflwTaskDueUTCTime,
    
      _WorkflowTaskURL.WorkflowTaskURL
}