C_CndnContrWorkItem

@AbapCatalog: {
  sqlViewName: 'CCONDCNTRWI',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
    authorizationCheck: #MANDATORY,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}
@ObjectModel:{
   usageType: {
      dataClass: #MIXED,
      serviceQuality: #D,
      sizeCategory:  #XL
   },
   semanticKey: [ 'WorkflowTaskInternalID' ],
   representativeKey: 'WorkflowTaskInternalID'
}
@ClientHandling: {
    algorithm: #SESSION_VARIABLE,
    type: #INHERITED
}
@VDM.viewType: #CONSUMPTION
@Consumption.semanticObject: 'WorkflowTaskInternalID'
@EndUserText.label: 'Condition Contract Work Item'

define view C_CndnContrWorkItem
  as select from I_WorkflowTask           as _WorkflowTask
    inner join   I_WorkflowTaskApplObject as _WorkflowTaskApplObject on  _WorkflowTaskApplObject.WorkflowTaskInternalID        = _WorkflowTask.WorkflowTaskInternalID
                                                                     and _WorkflowTaskApplObject.WorkflowObjectRole            = '01'
                                                                     and _WorkflowTaskApplObject.TechnicalWrkflwObjectCategory = 'BO'
                                                                     and _WorkflowTaskApplObject.SAPObjectNodeRepresentation   = 'ConditionContract'
    inner join   C_CndnContrWrkflwRel     as _CndnContrWrkflwRel     on _CndnContrWrkflwRel.ConditionContract = _WorkflowTaskApplObject.TechnicalWrkflwObject
{
  key _WorkflowTask.WorkflowTaskInternalID,

      _CndnContrWrkflwRel.ConditionContract,
      _CndnContrWrkflwRel.CndnContrType,
      _CndnContrWrkflwRel.DataPoint03 as CndnContrTypeDesc,
      @ObjectModel.foreignKey.association: '_Customer'
      _CndnContrWrkflwRel.Customer,
      _CndnContrWrkflwRel.CustomerName,
      @ObjectModel.foreignKey.association: '_Supplier'
      _CndnContrWrkflwRel.Supplier,
      _CndnContrWrkflwRel.SupplierName,
      _CndnContrWrkflwRel.CndnContrValidFrom,
      _CndnContrWrkflwRel.CndnContrValidTo,
      _CndnContrWrkflwRel.ExternalDocumentReferenceID,
      _CndnContrWrkflwRel.CndnContrIsInactive,
      _CndnContrWrkflwRel.CndnContrIsInactiveName,
      _CndnContrWrkflwRel.CreatedByUser,
      @Semantics.text: true
      _CndnContrWrkflwRel.UserFullName,
      _CndnContrWrkflwRel.CreationDate,
      _CndnContrWrkflwRel.LastChangedByUser,
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      _CndnContrWrkflwRel.SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      _CndnContrWrkflwRel.DistributionChannel,
      _CndnContrWrkflwRel.DistributionChannelName,
      @ObjectModel.foreignKey.association: '_Division'
      _CndnContrWrkflwRel.Division,
      _CndnContrWrkflwRel.DivisionName,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      _CndnContrWrkflwRel.PurchasingGroup,
      _CndnContrWrkflwRel.PurchasingGroupName,
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      _CndnContrWrkflwRel.PurchasingOrganization,
      _CndnContrWrkflwRel.PurchasingOrganizationName,
      _CndnContrWrkflwRel.CompanyCode,
      _CndnContrWrkflwRel.CompanyCodeName,
      @ObjectModel.foreignKey.association: '_PriorSupplier'
      _CndnContrWrkflwRel.PriorSupplier,

      /* Worker related fields */
      @Consumption.hidden: true
      _CndnContrWrkflwRel.PersonWorkAgreement,
      @Consumption.hidden: true
      _CndnContrWrkflwRel.CndnContrWorkerCostCenter,

      //Associations

      _CndnContrWrkflwRel._Customer,
      _CndnContrWrkflwRel._Supplier,
      _CndnContrWrkflwRel._SalesOrganization,
      _CndnContrWrkflwRel._DistributionChannel,
      _CndnContrWrkflwRel._Division,
      _CndnContrWrkflwRel._PurchasingOrganization,
      _CndnContrWrkflwRel._PurchasingGroup,
      _CndnContrWrkflwRel._PriorSupplier,
      @Consumption.hidden: true
      _CndnContrWrkflwRel._PersonWorkAgreement

}