C_ChmlCmplncMktReqTP

@EndUserText.label: 'Chemical Compliance Market Request'

@AbapCatalog:
{
  sqlViewName: 'CCCUMKTREQTP',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION

@ObjectModel:
{
  transactionalProcessingDelegated: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,
  semanticKey:  [ 'Country' ],
  usageType:
  {
    /*Service Quality - reflects the quality of service with respect to the expected performance of the CDS view:
      #A: may be consumed within business logic for high volume transactions or background processing
      #B: may be consumed within business logic for transactions or background processing
    */
    dataClass: #MIXED,
    sizeCategory: #M,
    serviceQuality: #C
  }
}

@UI : {
  headerInfo :
  {
      typeName: 'Assigned Markets and Production Countries/Regions',
      typeNamePlural: 'Assigned Markets and Production Countries/Regions'
  },
  presentationVariant.sortOrder: [{by: 'CountryName', direction: 'ASC' }]
  }
  
@Search.searchable: true

define view C_ChmlCmplncMktReqTP
  as select from I_ChmlCmplncMktReqTP
  association [1..1] to C_ChmlCmplncInfoTP as _ChmlCmplncInfo on _ChmlCmplncInfo.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID

{

      @ObjectModel.readOnly: true
      @UI.hidden: true
  key ChmlCmplncMktReqUUID,

      @UI.hidden: true
      @ObjectModel.readOnly: true
      ChmlCmplncInfoUUID,

      @UI.hidden: true
      Country,

      @ObjectModel.readOnly: true
      @UI: {
        lineItem:
        {
          position: 10
        }
      }
      @Search: {
        defaultSearchElement : true,
        fuzzinessThreshold: 0.7,
        ranking: #MEDIUM
      }
      cast (_Country._Text[1: Language = $session.system_language].CountryName as ehfnd_country_desc_long) as CountryName,

      @UI: {
        lineItem:
        {
          position: 40
        },
        identification : {
          position: 40
        }
      }
      ChmlCmplncProdnIsReqd,

      @UI: {
        lineItem:
        {
          position: 70
        },
        identification : {
          position: 70
        }
      }
      ChmlCmplncSalesIsReqd,

      /* Associations */
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _ChmlCmplncInfo,
      _Country
}