I_CHMLCMPLNCMKTREQTP

CDS View

Chemical Compliance Market Request

I_CHMLCMPLNCMKTREQTP is a CDS View in S/4HANA. Chemical Compliance Market Request. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_ChmlCmplncMktReqTP view from CONSUMPTION Chemical Compliance Market Request 
@EndUserText.label: 'Chemical Compliance Market Request'

@AbapCatalog:
{
  sqlViewName: 'ICCMKTREQTP',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #CHECK,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@ObjectModel:
{
  modelCategory: #BUSINESS_OBJECT,
  transactionalProcessingEnabled: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,
  writeDraftPersistence: 'ehfndw_cci_mreq',
  writeActivePersistence: 'ehfndv_cci_mreq',
  semanticKey:  [ 'ChmlCmplncMktReqUUID' ],

  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #B
  }
}

define view I_ChmlCmplncMktReqTP
 as select from I_ChmlCmplncMktReq
  association [1..1] to I_ChmlCmplncInfoTP as _ChmlCmplncInfo on _ChmlCmplncInfo.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID

{
  key ChmlCmplncMktReqUUID,
  @ObjectModel.readOnly: true
  ChmlCmplncMktReqUUID as ActiveChmlCmplncMktReqUUID, --Active UUID of Coverage
  @ObjectModel.mandatory: true
  ChmlCmplncInfoUUID,
  @ObjectModel.readOnly: true
  ChmlCmplncInfoUUID as ActiveChmlCmplncInfoUUID, --Active UUID of Chemical Compliance Information
  CreationUTCDateTime,
  CreatedByUser,
  LastChangeUTCDateTime,
  LastChangedByUser,
  @ObjectModel.mandatory: true
  Country,
  ChmlCmplncProdnIsReqd,
  ChmlCmplncExprtIsReqd,
  ChmlCmplncImprtIsReqd,
  ChmlCmplncSalesIsReqd,

  /* Associations */
  @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
  _ChmlCmplncInfo,

  _Country,
  _ReqStsProdn,
  _ReqStsExprt,
  _ReqStsImprt,
  _ReqStsSales,
  _CreatedByUser,
  _LastChangedByUser

}

Learn More