C_ARGlobalFilterOvw

@AbapCatalog.sqlViewName: 'CARFILTEROVW'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'General'
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #MIXED
@Metadata.allowExtensions: true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #CONSUMPTION
define view C_ARGlobalFilterOvw
  with parameters
    @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_Currency', element: 'Currency' } }]
    @Consumption.defaultValue: 'EUR'
    P_DisplayCurrency       : vdm_v_display_currency,
    @Consumption.defaultValue: '30'
    P_NetDueInterval1InDays : farp_due_interval1_c,
    @Consumption.defaultValue: '60'
    P_NetDueInterval2InDays : farp_due_interval2_c,
    @Consumption.defaultValue: '90'
    P_NetDueInterval3InDays : farp_due_interval3_c

  as select from I_CompanyCode
  association [0..1] to I_AccountingClerk         as _AccountingClerk on _AccountingClerk.CompanyCode = $projection.CompanyCode
  association [0..1] to I_Customer                as _Customer        on _Customer.Customer is null or _Customer.Customer is not null
  association [0..1] to I_Country                 as _Country         on _Country.Country is null or _Country.Country is not null
  association [0..1] to I_PostingKey              as _PostingKey      on _PostingKey.PostingKey is null or _PostingKey.PostingKey is not null
  association [0..1] to I_CrdtMSegmentVH          as _CreditSegment   on _CreditSegment.CreditSegment is null or _CreditSegment.CreditSegment is not null
{
  @UI.selectionField: {position: 10, exclude: false }
  @ObjectModel.text.element: 'CompanyCodeName'
  @UI.textArrangement: #TEXT_LAST
  @Consumption.filter: { selectionType: #SINGLE, multipleSelections: true, mandatory: true }
  @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } }]
  CompanyCode,
  @Consumption.filter.hidden: true
  CompanyCodeName,
  @UI.selectionField: {position: 20, exclude: false }
  @ObjectModel.text.element: 'AccountingClerkName'
  @UI.textArrangement: #TEXT_LAST
  @Consumption.filter: { selectionType: #SINGLE, multipleSelections: true, mandatory: false }
  @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_AccountingClerkStdVH', element: 'AccountingClerk' } }]
  _AccountingClerk.AccountingClerk,
  @Consumption.filter.hidden: true
  _AccountingClerk.AccountingClerkName as AccountingClerkName,
  @UI.selectionField: {position: 30, exclude: false }
  @Consumption.filter: { selectionType: #SINGLE, multipleSelections: true, mandatory: false }
  @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_Customer_VH', element: 'Customer' } }]
  _Customer.Customer,
  @UI.selectionField: {position: 40, exclude: false }
  @ObjectModel.text.element: 'CountryName'
  @UI.textArrangement: #TEXT_LAST
  @Consumption.filter: { selectionType: #SINGLE, multipleSelections: true, mandatory: false }
  @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_Country', element: 'Country' } }]
  _Country.Country,

  @UI.selectionField: {position: 50, exclude: false }
  @Consumption.filter: { selectionType: #SINGLE, multipleSelections: true, mandatory: false }
  @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_GLAccountStdVH', element: 'GLAccount' } }]
  cast (_Customer._CustomerCompany.ReconciliationAccount as far_ar_ovp_akont) as ReconciliationAccount,
  @UI.selectionField: {position: 60, exclude: false }
  @ObjectModel.text.element: 'PostingKeyName'
  @UI.textArrangement: #TEXT_LAST
  @Consumption.filter: { selectionType: #SINGLE, multipleSelections: true, mandatory: false }
  @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_PostingKey', element: 'PostingKey' } }]
  _PostingKey.PostingKey,
  @UI.selectionField: {position: 70, exclude: false }
  @ObjectModel.text.element: 'CreditSegmentName'
  @UI.textArrangement: #TEXT_LAST
  @Consumption.filter: { selectionType: #SINGLE, multipleSelections: true, mandatory: false }
  @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_CrdtMSegmentVH', element: 'CreditSegment' } }]
  _CreditSegment.CreditSegment,
  @Consumption.filter.hidden: true
  _CreditSegment._Text[1:Language = $session.system_language].CreditSegmentName,
  @Consumption.filter.hidden: true
  _PostingKey._PostingKeyText[1:Language = $session.system_language].PostingKeyName,
  @Consumption.filter.hidden: true
  _Country._Text.CountryName,
  @Consumption.filter.hidden: true
  @DefaultAggregation: #SUM
  ''                                   as DummyMeasure
}