A_ServiceQuotationItem

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Service Quotation Item'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASRVQTANITEM',
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
@AbapCatalog.preserveKey:true

define view A_ServiceQuotationItem
  as select from I_ServiceDocumentItemEnhcd as ServiceQuotationItem

  association [0..*] to A_ServiceQtanItemRefObject     as _ReferenceObject               on  $projection.ServiceQuotation     = _ReferenceObject.ServiceQuotation
                                                                                         and $projection.ServiceQuotationItem = _ReferenceObject.ServiceQuotationItem

  association [0..*] to A_ServiceQuotationItemText     as _Text                          on  $projection.ServiceQuotation     = _Text.ServiceQuotation
                                                                                         and $projection.ServiceQuotationItem = _Text.ServiceQuotationItem

  association [0..*] to A_ServiceQtanItemPriceElement  as _PricingElement                on  $projection.ServiceQuotation     = _PricingElement.ServiceQuotation
                                                                                         and $projection.ServiceQuotationItem = _PricingElement.ServiceQuotationItem

  association [1]    to A_ServiceQuotation             as _ServiceQuotation              on  $projection.ServiceQuotation = _ServiceQuotation.ServiceQuotation

  association [0..1] to I_ServiceDocumentItemSuccssr_2 as _RefServiceOrderItem           on  ServiceQuotationItem.ServiceDocumentItemCharUUID    = _RefServiceOrderItem.ServiceDocumentItemCharUUID
                                                                                         and _RefServiceOrderItem.ServiceDocItmSuccssrBusObjType = ServiceQuotationItem.ServiceDocumentItemObjectType

  association [0..1] to A_ServiceOrdItmRefSrvcContr    as _RefServiceContractItem        on  $projection.ServiceQuotationItemUUID = _RefServiceContractItem.ServiceOrderItemUUID

  association [0..1] to I_CustMgmtExtRefID             as _CustMgmtExtRef                on  $projection.ServiceQuotation         = _CustMgmtExtRef.CustMgmtDocument
                                                                                         and _CustMgmtExtRef.CustMgmtObjectType   = ServiceObjectType
                                                                                         and $projection.ServiceQuotationItem     = _CustMgmtExtRef.CustMgmtDocumentItem
                                                                                         and _CustMgmtExtRef.CustMgmtExtRefIDType = '0010'

  association [0..1] to I_SrvcMgmtObjectStatus         as _SrvcMgmtLifeCycleSystemStatus on  $projection.ServiceQuotationItemUUID                          = _SrvcMgmtLifeCycleSystemStatus.SrvcMgmtObjectUUID
                                                                                         and (
                                                                                            _SrvcMgmtLifeCycleSystemStatus.SrvcMgmtObjectStatus            = 'I1002' // IsNew

                                                                                            or _SrvcMgmtLifeCycleSystemStatus.SrvcMgmtObjectStatus         = 'I1003' // InProcess

                                                                                            or _SrvcMgmtLifeCycleSystemStatus.SrvcMgmtObjectStatus         = 'I1004' // Released

                                                                                            or _SrvcMgmtLifeCycleSystemStatus.SrvcMgmtObjectStatus         = 'I1005' // Rejected or accepted

                                                                                          )
                                                                                         and _SrvcMgmtLifeCycleSystemStatus.SrvcMgmtObjectStatusIsInactive = ' '
  //  Extensibility

  association [0..1] to E_ServiceDocumentItem          as _Extension                     on  _Extension.ServiceCategory       = 'BUS2000116'
                                                                                         and $projection.ServiceQuotation     = _Extension.ServiceOrderItem
                                                                                         and $projection.ServiceQuotationItem = _Extension.ServiceLineExternalID

  association [0..1] to I_CustMgmtPartner              as _ServicePerformer              on  CustMgmtPartnerFunction          = '00000028'
                                                                                         and CustMgmtPartFunctionCategory     = '0091'
                                                                                         and $projection.ServiceQuotation     = _ServicePerformer.CustMgmtDocument
                                                                                         and $projection.ServiceQuotationItem = _ServicePerformer.CustMgmtDocumentItem

  association [0..*] to A_SrvcQtanItmInHouseRepairItem as _InHouseRepairItem             on  $projection.ServiceQuotation     = _InHouseRepairItem.ServiceQuotation
                                                                                         and $projection.ServiceQuotationItem = _InHouseRepairItem.ServiceQuotationItem

  association [0..1] to I_SrvcMgmtObjectStatus         as _SrvcMgmtSendToPlanningStatus  on  $projection.ServiceQuotationItemUUID                         = _SrvcMgmtSendToPlanningStatus.SrvcMgmtObjectUUID
                                                                                         and (
                                                                                            _SrvcMgmtSendToPlanningStatus.SrvcMgmtObjectStatus            = 'I1927' // Send to Planning

                                                                                          )
                                                                                         and _SrvcMgmtSendToPlanningStatus.SrvcMgmtObjectStatusIsInactive = ' '

{

      /* QuotationADM_I */
  key ServiceDocument                                                      as ServiceQuotation,
  key ServiceDocumentItem                                                  as ServiceQuotationItem,
      ServiceDocItemCategory,
      ServiceDocumentItemUUID                                              as ServiceQuotationItemUUID,
      ServiceDocumentItemDescription                                       as ServiceQtanItemDescription,
      Language,
      OriginallyRequestedProduct                                           as Product,
      ServiceDocItemQuantityUnit                                           as QuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      ServiceDocumentItemQuantity                                          as Quantity,


      ServiceDuration,
      ServiceDurationUnit,
      @ObjectModel.readOnly: true
      ServiceDocumentItemIsQuotation,
      MaintenancePlanningPlant,
      _WorkCenter.Plant                                                    as MaintenanceWorkCenterPlant,
      _WorkCenter.WorkCenter                                               as MaintenanceWorkCenter,
      SrvcDocItemCategoryUsage,


      //BillableControl,


      _CustMgmtExtRef.CustMgmtExtRefID                                     as ServiceQtanItemExtReference,
      SrvcDocItmBillingRelevance,
      DynItemProcessorPrfl,

      /* PARTNER */
      SoldToParty,
      ShipToParty,
      ResponsibleEmployee                                                  as PersonResponsible,
      _ServicePerformer.CustMgmtBusinessPartner                            as ServicePerformer,

      /* STATUS */
      case _SrvcMgmtLifeCycleSystemStatus.SrvcMgmtObjectStatus
        when 'I1002' then 'X'
        else ''
      end                                                                  as ServiceQuotationItemIsNew,
      case _SrvcMgmtLifeCycleSystemStatus.SrvcMgmtObjectStatus
        when 'I1003' then 'X'
        else ''
      end                                                                  as SrvcQtanItemIsInProcess,
      case _SrvcMgmtLifeCycleSystemStatus.SrvcMgmtObjectStatus
        when 'I1004' then 'X'
        else ''
      end                                                                  as ServiceQuotationItemIsReleased,
      case _SrvcMgmtLifeCycleSystemStatus.SrvcMgmtObjectStatus
        when 'I1005' then case ServiceDocumentItemIsRejected
                     when 'X' then ''
                     else 'X'
                     end
        else ''
      end                                                                  as ServiceQuotationItemIsAccepted,
      ServiceDocumentItemIsRejected                                        as ServiceQuotationItemIsRejected,
      ServiceDocItemRejectionReason                                        as SrvcQtanItmRejectionReason,
      @Semantics.booleanIndicator
      case _SrvcMgmtSendToPlanningStatus.SrvcMgmtObjectStatus
        when'I1927'then'X'
        else''
      end                                                                  as SrvcQtanItmIsToBeSentToPlng,

      TimeSheetOvertimeCategory,

      _RefServiceContractItem.ReferenceServiceContract                     as ReferenceServiceContract,
      _RefServiceContractItem.ReferenceServiceContractItem                 as ReferenceServiceContractItem,
      _RefServiceOrderItem._ServiceDocItm._ServiceDocument.ServiceDocument as ServiceQtanSuccessorOrder,
      _RefServiceOrderItem._ServiceDocItm.ServiceDocumentItem              as ServiceQtanSuccessorOrderItem,


      _ParentServiceDocItem.ServiceDocumentItem                            as ParentServiceQuotationItem,

      @ObjectModel.sapObjectNodeTypeReference: 'PaymentTerms'
      PaymentTerms,

      //FPS03 Development

      @ObjectModel.readOnly: true
      MaterialSubstitutionReason,

      @ObjectModel.readOnly: true
      case
      when MaterialSubstitutionReason <> ''
        then Product
        else ''
      end                                                                  as SubstituteProduct,

      /********************************************************/
      /*********  Cloud Specific Fields **************************/
      /* Dont delete this comment:
            This field always should be commented while publishing and add it later as the ATC will not allow to delete the field which is already released.
            In end of 2008 we have removed it at the time of API publishing since this field is not required to be exposed to the customer, with help of API
            hub team. Later in 2011 it was decided to remove it from odata, which was not possible. Since depreaction was not possible, we added this field
            back to the odata. This is a work around until a permanent solution is found*/
      @Feature: 'BF:API_ESSENTIALSCOPE'
      RespyMgmtServiceTeam,

      @Feature: 'BF:API_ESSENTIALSCOPE'
      @ObjectModel.readOnly: true
      _ServiceTeamHeader.TeamName                                          as RespyMgmtServiceTeamName,

      @Feature: 'BF:API_ESSENTIALSCOPE'
      _ServiceTeamHeader.RespyMgmtGlobalTeamID                             as RespyMgmtGlobalTeamID,
      /********************************************************/

      //      Associations

      _ReferenceObject,
      _Text,
      _ServiceQuotation,
      _PricingElement,
      _InHouseRepairItem

}

where
      ServiceObjectType              = 'BUS2000116'
  and ServiceDocumentItemIsQuotation = 'X' //  Service Process