A_ServiceQuotation

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Service Quotation'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASRVQTAN',
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'ServiceQuotation',
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: false,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
@AbapCatalog.preserveKey:true

define view A_ServiceQuotation
  as select from I_ServiceDocumentEnhcd as ServiceQuotation

  association [0..*] to A_ServiceQuotationItem       as _Item                 on  $projection.ServiceQuotation = _Item.ServiceQuotation

  association [0..*] to A_ServiceQtanPersonResp      as _PersonResponsible    on  $projection.ServiceQuotation = _PersonResponsible.ServiceQuotation
  association [0..*] to A_ServiceQtanRefObject       as _ReferenceObject      on  $projection.ServiceQuotation = _ReferenceObject.ServiceQuotation
  association [0..*] to A_ServiceQuotationText       as _Text                 on  $projection.ServiceQuotation = _Text.ServiceQuotation
  association [0..*] to A_ServiceQtanPriceElement    as _PricingElement       on  $projection.ServiceQuotation = _PricingElement.ServiceQuotation
  association [0..*] to A_ServiceQtanFUPSrvcOrd      as _FollowUpServiceOrder on  $projection.ServiceQuotation = _FollowUpServiceOrder.ServiceQuotation

  association [0..1] to I_CustMgmtExtRefID           as _CustMgmtExtRef       on  $projection.ServiceQuotation         = _CustMgmtExtRef.CustMgmtDocument
                                                                              and _CustMgmtExtRef.CustMgmtObjectType   = ServiceObjectType
                                                                              and _CustMgmtExtRef.CustMgmtExtRefIDType = '0009'

  association [0..1] to P_SrvcQtanWithSglFUPSrvcOrd  as _RefServiceOrder      on  $projection.ServiceQuotationUUID = _RefServiceOrder.ServiceQuotationUUID
                                                                              and $projection.ServiceQuotation     = _RefServiceOrder.ServiceQuotation

  association [0..1] to I_ServiceDocumentPredecessor as _RefServiceContract   on  $projection.ServiceQuotationUUID                = _RefServiceContract.ServiceDocumentUUID
                                                                              and _RefServiceContract.ServiceDocPrdcssrBusObjType = 'BUS2000112'

  //  //Extensibility

  association [0..1] to E_ServiceDocument            as _Extension            on  _Extension.ServiceCategory   = 'BUS2000116'
                                                                              and $projection.ServiceQuotation = _Extension.ServiceOrder

  association [0..*] to A_SrvcQtanInHouseRepairItem as _InHouseRepairItem     on $projection.ServiceQuotation = _InHouseRepairItem.ServiceQuotation

{

  key  ServiceDocument                                                                  as ServiceQuotation,
       ServiceDocumentType                                                              as ServiceQuotationType,
       ServiceDocumentUUID                                                              as ServiceQuotationUUID,
       ServiceDocumentDescription                                                       as ServiceQuotationDescription,
       Language,
       RequestedServiceStartDateTime,
       RequestedServiceEndDateTime,
       cast ( SrvcQtanValidityStartDateTime as crms4_cont_start_dec15 preserving type ) as SrvcQtanValidityStartDateTime,
       cast ( SrvcQtanValidityEndDateTime   as crms4_cont_end_dec15   preserving type ) as SrvcQtanValidityEndDateTime,

       _CustMgmtExtRef.CustMgmtExtRefID                                                 as ServiceQtanExtReference,
       /* STATUS */
       ServiceDocumentIsReleased                                                        as ServiceQuotationIsReleased,

       case when ServiceDocumentIsOpen = '' and ServiceDocumentIsRejected = ''
         then 'X'
         else ''
       end                                                                              as ServiceQuotationIsAccepted,
       ServiceDocumentIsRejected                                                        as ServiceQuotationIsRejected,

       ServiceDocumentRejectionReason                                                   as SrvcQuotationRejectionReason,
       //ServiceDocumentIsQuotation, - system already recongnize its a service quotation based on the configuration.so no need of this field.


       /* ORG */
       SalesOrganization,
       DistributionChannel,
       Division,
       SalesOffice,
       SalesGroup,

       /* PARTNER */
       SoldToParty,
       ShipToParty,
       ContactPerson,

       _RefServiceOrder.ServiceOrder                                                    as ServiceQtanSuccessorOrder,
       //_RefServiceContract._ServiceDoc.ServiceDocument              as ReferenceServiceContract,


       /********************************************************/
       /*********  Cloud Specific Fields **************************/
       /* Dont delete this comment:
          This field always should be commented while publishing and add it later as the ATC will not allow to delete the field which is already released.
          In end of 2008 we have removed it at the time of API publishing since this field is not required to be exposed to the customer, with help of API
          hub team. Later in 2011 it was decided to remove it from odata, which was not possible. Since depreaction was not possible, we added this field
          back to the odata. This is a work around until a permanent solution is found*/
       @Feature: 'BF:API_ESSENTIALSCOPE'
       RespyMgmtServiceTeam,

       @Feature: 'BF:API_ESSENTIALSCOPE'
       @ObjectModel.readOnly: true
       _ServiceTeamHeader.TeamName                                                      as RespyMgmtServiceTeamName,

       @Feature: 'BF:API_ESSENTIALSCOPE'
       _ServiceTeamHeader.RespyMgmtGlobalTeamID                                         as RespyMgmtGlobalTeamID,
       /********************************************************/

       @ObjectModel.sapObjectNodeTypeReference: 'PaymentTerms'
       PaymentTerms,

       /* CUMULAT_H */
       TransactionCurrency,
       @Semantics.amount.currencyCode: 'TransactionCurrency'
       ServiceDocGrossAmount,
       @Semantics.amount.currencyCode: 'TransactionCurrency'
       ServiceDocNetAmount,
       @Semantics.amount.currencyCode: 'TransactionCurrency'
       ServiceDocTaxAmount,

       /********************************************************/
       /*********  In-House Repair Specific Fields *************/
       ReferenceInHouseRepair                                                           as ReferenceInHouseRepair,

       //Associations

       _Item,
       _PersonResponsible,
       _ReferenceObject,
       _Text,
       _PricingElement,
       _FollowUpServiceOrder,
       _InHouseRepairItem
}
where
      ServiceObjectType          = 'BUS2000116'
  and ServiceDocumentIsQuotation = 'X' // Service Process