m_v_m2s_pd_itm

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'CDS_M_M2S_PD_ITM'
@EndUserText.label: 'View for Purchasing Document Item'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.authorizationCheck:#CHECK
@AccessControl.personalData.blocking: #REQUIRED
/***********************************************************************************************************/
/*   ME2STAR: Purchasing Document Item                                                                     */
/***********************************************************************************************************/
define view m_v_m2s_pd_itm
  as select from    ekpo           as ekpo
    inner join      ekko           as _PurchasingDocument on ekpo.ebeln = _PurchasingDocument.ebeln
    left outer join lfa1           as lfa1                on _PurchasingDocument.lifnr = lfa1.lifnr
    left outer join t024e          as t024e               on _PurchasingDocument.ekorg = t024e.ekorg
    left outer join t024           as t024                on _PurchasingDocument.ekgrp = t024.ekgrp
    left outer join t001           as t001                on ekpo.bukrs = t001.bukrs
    left outer join t001w          as t001w               on ekpo.werks = t001w.werks
    left outer join t001w          as t001w_sp            on _PurchasingDocument.reswk = t001w_sp.werks
    left outer join usr21          as usr21               on _PurchasingDocument.ernam = usr21.bname
    left outer join adrp           as adrp                on adrp.persnumber = usr21.persnumber
    left outer join m_v_m2s_pd_i_c as pdi_calc            on  ekpo.ebeln = pdi_calc.ebeln
                                                          and ekpo.ebelp = pdi_calc.ebelp

{
      -- Key fields
  key ekpo.ebeln,
  key ekpo.ebelp,

      -- Fields from table EKPO
      ekpo.txz01,
      ekpo.matnr,
      ekpo.matkl,
      ekpo.werks,
      ekpo.lmein,
      ekpo.lgort,
      ekpo.bukrs,
      ekpo.meins,
      ekpo.bprme,
      ekpo.knttp,
      ekpo.loekz                                       as loekz_i,
      ekpo.banfn,
      ekpo.bnfpo,
      ekpo.ematn,
      ekpo.menge,
      ekpo.peinh,
      ekpo.netpr,
      ekpo.netwr,
      ekpo.ktmng,
      ekpo.zwert,
      ekpo.statu,
      ekpo.pstyp,
      ekpo.stapo,
      ekpo.retpo,
      ekpo.umren,
      ekpo.umrez,
      ekpo.elikz,
      ekpo.erekz,
      ekpo.wepos,
      ekpo.webre,
      ekpo.repos,

      -- Fields from table EKKO
      cast(_PurchasingDocument.wkurs as abap.dec(9,5)) as wkurs,
      _PurchasingDocument.bstyp,
      _PurchasingDocument.bsart,
      _PurchasingDocument.aedat,
      _PurchasingDocument.ernam,
      _PurchasingDocument.lifnr,
      _PurchasingDocument.zterm,
      _PurchasingDocument.ekorg,
      _PurchasingDocument.ekgrp,
      _PurchasingDocument.waers,
      _PurchasingDocument.bedat,
      _PurchasingDocument.kdatb,
      _PurchasingDocument.kdate,
      _PurchasingDocument.kufix,
      _PurchasingDocument.konnr,
      _PurchasingDocument.reswk,
      _PurchasingDocument.loekz                        as loekz_h,
      _PurchasingDocument.angdt,
      _PurchasingDocument.submi,
      _PurchasingDocument.ktwrt,
      _PurchasingDocument.description,
      _PurchasingDocument.iseopblocked,

      -- Fields from other tables
      lfa1.name1,
      lfa1.sortl,
      t024.eknam,
      t024e.ekotx,
      t001.butxt,
      t001w.name1                                      as name1_p,
      t001w_sp.name1                                   as name1_sp,
      adrp.name_text,

      -- Calculated fields from DDL m_v_m2s_pd_i_c
      pdi_calc.status                                  as status,
      pdi_calc.wemng                                   as wemng,
      pdi_calc.wewrt                                   as wewrt,
      pdi_calc.remng                                   as remng,
      pdi_calc.rewrt                                   as rewrt,

      pdi_calc.valuemismatch,
      pdi_calc.qtymismatch,
      pdi_calc.confmiss,
      pdi_calc.wesbs                                   as wesbs,

      case pdi_calc.status
      when '23' then cast('X' as abap.char(1))
      when '24' then cast('X' as abap.char(1))
      when '05' then cast('X' as abap.char(1))
      else
       cast('' as abap.char(1))

       end                                             as postgr,

      -- Placeholder fields (to be calculated in ABAP)
      cast('' as abap.char(40))                        as maktx,
      cast('' as abap.char(20))                        as wgbez,
      cast('' as abap.char(20))                        as batxt,
      cast('' as abap.char(40))                        as statustext,
      cast(0 as abap.int4)                             as cntf,
      cast(0 as abap.int4)                             as cntk,
      cast(0 as abap.int4)                             as cntl,
      cast(0 as abap.quan(15,3))                       as releasequantity,
      ''                                               as contractitemusage,
      cast(0 as abap.curr(19,2))                       as releasevalue,
      -- Source of Supply
      case _PurchasingDocument.lifnr when '' then cast(_PurchasingDocument.reswk as abap.char(10))
                      else         cast(_PurchasingDocument.lifnr as abap.char(10))
      end                                              as sosid,
      case _PurchasingDocument.lifnr when '' then cast(t001w_sp.name1 as abap.char(100))
                      else         cast(lfa1.name1  as abap.char(100))
      end                                              as sosname

}