fac_cds_ve_group_node

@AbapCatalog.sqlViewName: 'FACV_VE_GPND'
//@ClientHandling.algorithm: #SESSION_VARIABLE

@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Validation Group Node'
@AbapCatalog.preserveKey: true
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #C,
  sizeCategory: #S
}
define view fac_cds_ve_group_node
  as select from    uhdt_node as node
    left outer join uhdt_ntxt as ntxt on  node.node_id = ntxt.node_id
                                      and ntxt.lang    = $session.system_language
    left outer join uhdt_ntxt as ntxt_e on node.node_id = ntxt_e.node_id
                                      and ntxt_e.lang    = 'E'
    left outer join uhdt_vrsn as r    on node.origin_verid = r.ver_id
  association [1..1] to fac_cds_uh_version as to_version on $projection.VersionId = to_version.VersionId
  association [1..1] to FAC_CDS_UH_NODE_ACTION       as to_node_action on $projection.JoinId = to_node_action.NodeId

{
  key node.node_id                 as NodeId,
      node.ver_id                  as VersionId,
      node_pid                     as NodeParentId,
      node.node_id                 as JoinId,
      node_type                    as NodeType,
      to_version.HierarchyId,
      to_version.HierarchyCategory as HierarchyCategory,
      node_entity                  as NodeEntity,
      node_level                   as NodeLevel,
      node_ind                     as NodeIndicator,
      node_seq                     as NodeSequence,
      node_order                   as NodeDisplayOrder,
      node_sgn                     as NodeSign,
      node_vldfm                   as NodeValidFrom,
      node_vldto                   as NodeValidTo,
      node_lval                    as NodeLowValue,
      node_hval                    as NodeHighValue,
      node.created_at              as CreatedAt,
      node.created_by              as CreatedBy,
      node.updated_at              as UpdatedAt,
      node.updated_by              as UpdatedBy,
      case when ntxt.lval_txt is not null 
        then ntxt.lval_txt 
        else ntxt_e.lval_txt    end as NodeLowText,
      case when ntxt.hval_txt is not null 
        then ntxt.hval_txt 
        else ntxt_e.hval_txt    end as NodeHighText,
//Enable the referrence node features

      node.node_rid                           as  NodeRefId,
      node.ref_verid                          as ReferenceVersionID,
      node.ref_t_group_id                     as ReferenceGroupID,
      node.origin_verid                       as OriginVersionID,
      r.hier_hid                              as  OriginHierarchyID,
      case when node_type = 'Z'
        then r.hier_hid   end                      as  RefHierarchyID,
      case when node.ref_t_group_id <> ''
      then 'R'
      else ''          end          as VirtualFlag,
      case when node.ref_t_group_id <> ''
           then 'X'
           else to_node_action.Forbid_Add_Leaf          end          as ForbidAddLeaf,

      case when node.ref_t_group_id <> ''
           then 'X'
           else to_node_action.Forbid_Add_Node          end          as ForbidAddNode,

      case when ( node.ref_t_group_id <> '' and node_type <> 'Z' )
           then 'X'
           else to_node_action.Forbid_Delete         end          as ForbidDelete,
      case when node.ref_t_group_id <> ''
           then 'X'
           else to_node_action.Forbid_Update          end          as ForbidUpdate,
      case when ( node.ref_t_group_id <> '' and node_type <> 'Z' )
           then 'X'
           else to_node_action.Forbid_Move          end          as ForbidMove,
      case when  node.ref_t_group_id <> ''
           then 'X'
           else to_node_action.Forbid_Sort_Subnode          end          as ForbidSortSubnode,
      case
        when node.node_type = 'L' then 'leaf'
        when node.node_level = '000000' then 'expanded'
        else 'collapsed'
      end                                as  DrillState,
      to_version
}
where
  to_version.HierarchyCategory = 'GL05'