fac_cds_fh_node

@AbapCatalog.sqlViewName: 'FACV_FH_NODE'
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Flexible Hierarchy Node'

@ObjectModel: {usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #XL}
}

define view fac_cds_fh_node
  as select from hrrp_node_n
    inner join   flexhier_dir on  hrrp_node_n.hryid_42 = flexhier_dir.hryid
                              and hrrp_node_n.hryvalto = flexhier_dir.hryvalto
  association [0..*] to fac_cds_fh_nodet as _Text    on  hrrp_node_n.hryid_42 = _Text.FlexibleHierarchy
                                                     and hrrp_node_n.nodecls  = _Text.HierarchyNodeClass
                                                     and hrrp_node_n.hrynode  = _Text.HierarchyNode
                                                     and hrrp_node_n.parnode  = _Text.ParentNode
                                                     and hrrp_node_n.hryvalto = _Text.ValidityEndDate
  association [1..*] to fac_cds_fh       as _to_hier on  $projection.FlexibleHierarchy = _to_hier.FlexibleHierarchy
                                                     and $projection.ValidityEndDate   = _to_hier.ValidityEndDate
{
  key    hrrp_node_n.hryid_42                                           as FlexibleHierarchy,
         @VDM.lifecycle.status:    #DEPRECATED
  key    cast( '000000000000001' as hryversn preserving type )          as HierarchyVersion,
  key    hrrp_node_n.nodecls                                            as HierarchyNodeClass,
  key    hrrp_node_n.hrynode                                            as HierarchyNode,
  key    hrrp_node_n.parnode                                            as ParentNode,
  key    hrrp_node_n.hryvalto                                           as ValidityEndDate,
         hrrp_node_n.hryvalfrom                                         as ValidityStartDate,
         hrrp_node_n.nodetype                                           as HierarchyNodeType,
         hrrp_node_n.nodevalue                                          as HierarchyNodeValue,
         hrrp_node_n.hryseqnbr                                          as HierarchySequenceNumber,
         hrrp_node_n.hrylevel                                           as HierarchyLevel,
         hrrp_node_n.hrytyp                                             as HierarchyType,

         _Text[1:Language = $session.system_language].HierarchyNodeText as HierarchyNodeText,

         case
           when hrrp_node_n.nodetype = 'L' then 'leaf'
           when hrrp_node_n.hrylevel = '000000' or hrrp_node_n.hrylevel = '000001' then 'expanded'
           else 'collapsed'
         end                                                            as DrillState,
         _to_hier
}
where
  hrrp_node_n.nodetype <> 'D';