atov_ppl_merge_changes

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_ALLOWED
@EndUserText.label: 'ATO - PLL Merge Changes'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity atov_ppl_merge_changes
  as select from    atov_ppl_merge_changes_base as Item
    left outer join ato_ppl_staging             as StagedItem on  Item.ItemType     = StagedItem.item_type
                                                              and Item.ItemId       = StagedItem.item_id
                                                              and StagedItem.action = 'M'                         // include only items for merge 

    left outer join ato_cols                    as Collection on  Collection.category = 'M'
                                                              and Collection.status   = ''                        // and item is changeable


  association [0..1] to ATOV_TEXT_ADAPTATION_TYPE as Adaptation_Type_Texts     on  Adaptation_Type_Texts.code     = Item.ItemType
                                                                             and Adaptation_Type_Texts.language = $session.system_language

  association [1]    to ATOV_TEXT_COL_ITEM_STATUS as Col_Item_Status_Texts      on  Col_Item_Status_Texts.code     = Item.Status
                                                                             and Col_Item_Status_Texts.language = $session.system_language

  association [1]    to ATOV_USER                 as Changed_By_Description    on  Changed_By_Description.name = Item.LastNotificationBy

  association [1]    to ATOV_ADAPTATION_TYPE      as Adaptation_Type          on  Adaptation_Type.code = Item.ItemType

{
  key Item.ItemType                              as ItemType,
  key Item.ItemId                                as ItemId,
      Item.ItemDescription                       as ItemDescription,
      Item.LastNotificationAt                    as ChangedAt,
      Item.LastNotificationBy                    as ChangedBy,
      Item.Status                                as DifferenceToMainline,
      case
        when StagedItem.item_id is null
        then cast('' as abap_boolean preserving type )                  
        else cast('X' as abap_boolean preserving type )                 
      end                                        as IncludedInStaging,

      Collection.collection_id                   as CollectionId,
      Collection.description_text                as CollectionDescription,

      /* Associations */
      Adaptation_Type_Texts,
      Adaptation_Type,
      Col_Item_Status_Texts,
      Changed_By_Description
}