V_DOC_CURR

@AbapCatalog.sqlViewName: 'V_DOC_CURR_CDS'
@EndUserText.label: 'Document Currency'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
define view V_DOC_CURR 
as select distinct from vbak{           //SALES ORDER HEAD

  vbeln, 
  'VBAK' as dbtable,
  knumv,
  waerk,
  erdat
}
union all 
select distinct from likp{              //DELIVERY HEAD

  vbeln,
  'LIKP' as dbtable,
  knumv, 
  waerk,
  '20111111' as erdat
}
union all
select distinct from vbrk{              //CUSTOMER INVOICE HEAD

  vbeln, 
  'VBRK' as dbtable, 
  knumv, 
  waerk,
  erdat
}
union all
select distinct from ekko{              //PURCHASE ORDER HEAD

  ebeln as vbeln, 
  'EKKO' as dbtable,
  knumv, 
  waers as waerk,
  aedat as erdat
}
union all
select distinct from ekbe{              //PURCHASING DOCUMENT HISTORY

  ebeln as vbeln, 
  'EKBE' as dbtable, 
  knumv, 
  waers as waerk,
  budat as erdat
}
union all
select distinct from eslh{              //SERVICE PACKAGE HEAD

  ebeln as vbeln,
  'ESLH' as dbtable, 
  knumv, 
  waers as waerk,
  '20111111' as erdat
}
union all
select distinct from rbkp{              //INVOICE RECEIPT HEAD

  belnr as vbeln, 
  'RVKP' as dbtable, 
  knumve as knumv,
  waers as waerk,
  '20111111' as erdat
 }
union all
select distinct from vfkp{              //SHIPMENT COSTS ITEM

  ebeln as vbeln, 
  'VFKP' as dbtable,
  knumv,
  waers as waerk,
  '20111111' as erdat
} 
union all
select distinct from vpkhead            //RESOURCE RELATED BILLING HEAD

  inner join vbak 
  on vbak.vbeln = vpkhead.vbeln{
  vpkhead.vbeln as vbeln,
  'VPKHEAD' as dbtable, 
  vpkhead.knumv as knumv, 
  vbak.waerk as waerk,
  '20111111' as erdat
}