VAL_Partial_clear_base

@AccessControl.authorizationCheck: #NOT_ALLOWED
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@ObjectModel.usageType: { serviceQuality: #D, sizeCategory: #XXL, dataClass: #MIXED }

define view entity VAL_Partial_clear_base
  with parameters
    p_run_id             : cls_run_id,
    p_fiscal_year_period : fiscalyearperiod,
    p_key_date           : fis_budat

  as select from           VALUATIONACDOCA           as acdoca

    left outer to one join VALLEADINGITEMWITHGROUPID as wl        on  acdoca.CompanyCode                = wl.companycode
                                                                  and acdoca.InvoiceItemReference       = wl.accountingdocumentitem
                                                                  and acdoca.InvoiceReferenceFiscalYear = wl.Fiscalyear
                                                                  and acdoca.InvoiceReference           = wl.accountingdocument
                                                                  and acdoca.Ledger                     = wl.ledger
                                                                  and wl.Jrnlperiodendclosingrunloguuid = $parameters.p_run_id

    left outer to one join VALUATIONWORKLIST         as remainval on  acdoca.CompanyCode        = remainval.companycode
                                                                  and acdoca.LedgerGLLineItem   = remainval.ledgergllineitem
                                                                  and acdoca.FiscalYear         = remainval.Fiscalyear
                                                                  and acdoca.AccountingDocument = remainval.accountingdocument
                                                                  and acdoca.Ledger             = remainval.ledger

{
      // items which can potentially linked to an invoice

      // items whose linkage can be found in worklist have same group id as their linkage

      // items whose linkage can not be found in worklist have '' as group id and rebz* will be reset to initial

      // Debit items are invoices, credit items are payments

  key acdoca.CompanyCode,
  key acdoca.FiscalYear,
  key acdoca.AccountingDocument,
  key acdoca.LedgerGLLineItem,
  key acdoca.Ledger,
  key acdoca.SourceLedger,
      @Environment.sql.passValue: true
      acdoca.p_is_mdc_on,
      acdoca.AccountingDocumentItem,
      acdoca.OriginalGlAccount,
      wl.group_id,
      wl.grouping_rule,
      wl.grouping_rule_step,
      wl.valuation_rule_step,
      wl.marked_for_deletion,
      wl.accountingdocument               as InvoiceAccountingDocument,
      wl.accountingdocumentitem           as InvoiceAccountingDocumentItem,
      wl.ledgergllineitem                 as InvoiceLedgergllineitem,
      wl.Fiscalyear                       as InvoiceFiscalYear,
      wl.clearingaccountingdocument       as InvoiceClearingDocument,
      wl.clearingdocfiscalyear            as InvoiceClearingDocFiscalYear,
      wl.clearingdate                     as InvoiceClearingDate,
      acdoca.OrganizationalChange,
      acdoca.TaxCode,
      acdoca.TaxCountry,
      acdoca.ClearingAccountingDocument,
      acdoca.ClearingDocFiscalYear,
      acdoca.ClearingDate,
      acdoca.NetDueDate,
      acdoca.ChartOfAccounts,
      acdoca.BusinessTransactionCategory,
      remainval.finclosinglineitemprocessstep,
      remainval.Jrnlperiodendclosingrunloguuid,

      // Debitor: Debit items are invoices, credit items are payments

      // Creditor: Credit items are invoices, debit items are payments

      // others: Debit items are invoices, credit items are payments

      case acdoca.FinancialAccountType
      when 'K'
      then

       case  acdoca._PostingKey.DebitCreditCode
         when 'S'
         then
           case  when acdoca.FiscalYearPeriod = $parameters.p_fiscal_year_period
           then 'PAYMENT_CURRENT'
           when acdoca.FiscalYearPeriod < $parameters.p_fiscal_year_period
           then 'PAYMENT_PREVIOUS'
         end
         else 'INVOICE' end

      else

      case  acdoca._PostingKey.DebitCreditCode
      when 'H'
      then
       case  when acdoca.FiscalYearPeriod = $parameters.p_fiscal_year_period
       then 'PAYMENT_CURRENT'
       when acdoca.FiscalYearPeriod < $parameters.p_fiscal_year_period
       then 'PAYMENT_PREVIOUS'
      end
      else 'INVOICE' end

      end                                 as line_type,

      cast(case
      when acdoca.IsReversed = 'X' and acdoca.ClearingDate is not initial and acdoca.ClearingDate <= $parameters.p_key_date then 'R'
      else '' end as  cls_line_item_type) as financialclosinglineitemtype,

      case
        when acdoca.ClearingDate is not initial and acdoca.ClearingDate <= $parameters.p_key_date
        then 'X'
        else ' '
      end                                 as IsClearedAtKeydate,

      // filtering

      acdoca.IsReversal,
      acdoca.GLAccount,

      acdoca.CreationDateTime,
      acdoca.SubLedgerAcctLineItemType,
      acdoca.PostingDate                  as OriginalPostingDate,
      acdoca.PostingDate,
      acdoca.DocumentDate,
      acdoca.AccountingDocumentCategory,
      acdoca.LedgerFiscalYear,
      acdoca.FiscalYearPeriod,
      acdoca.ReferenceDocumentType,
      acdoca._PostingKey.DebitCreditCode,
      acdoca.PostingKey,
      acdoca.InvoiceReferenceFiscalYear,
      acdoca.InvoiceReference,
      acdoca.InvoiceItemReference,

      acdoca.Supplier,
      acdoca.Customer,

      // grouping

      acdoca.GLAccountType,
      acdoca.FinancialAccountType, // corresponding wl field name ACCOUNT_TYPE

      acdoca.AssignmentReference,

      acdoca.CUSTOMER_SUPPLIER_GROUP_KEY,

      acdoca.FiscalPeriod,
      acdoca.OffsettingAccount,
      acdoca.WBSElement,
      acdoca.GLRecordType,

      acdoca.BalanceTransactionCurrency,
      acdoca.CompanyCodeCurrency,
      acdoca.GlobalCurrency,
      acdoca.FreeDefinedCurrency1,
      acdoca.FreeDefinedCurrency2,
      acdoca.FreeDefinedCurrency3,
      acdoca.FreeDefinedCurrency4,
      acdoca.FreeDefinedCurrency5,
      acdoca.FreeDefinedCurrency6,
      acdoca.FreeDefinedCurrency7,
      acdoca.FreeDefinedCurrency8,

      @Semantics.amount.currencyCode: 'BalanceTransactionCurrency'
      acdoca.AmountInBalanceTransacCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      acdoca.AmountInCompanyCodeCurrency,

      @Semantics.amount.currencyCode: 'GlobalCurrency'
      acdoca.AmountInGlobalCurrency,

      @Semantics.amount.currencyCode: 'FreeDefinedCurrency1'
      acdoca.AmountInFreeDefinedCurrency1,

      @Semantics.amount.currencyCode: 'FreeDefinedCurrency2'
      acdoca.AmountInFreeDefinedCurrency2,

      @Semantics.amount.currencyCode: 'FreeDefinedCurrency3'
      acdoca.AmountInFreeDefinedCurrency3,

      @Semantics.amount.currencyCode: 'FreeDefinedCurrency4'
      acdoca.AmountInFreeDefinedCurrency4,

      @Semantics.amount.currencyCode: 'FreeDefinedCurrency5'
      acdoca.AmountInFreeDefinedCurrency5,

      @Semantics.amount.currencyCode: 'FreeDefinedCurrency6'
      acdoca.AmountInFreeDefinedCurrency6,

      @Semantics.amount.currencyCode: 'FreeDefinedCurrency7'
      acdoca.AmountInFreeDefinedCurrency7,

      @Semantics.amount.currencyCode: 'FreeDefinedCurrency8'
      acdoca.AmountInFreeDefinedCurrency8,

      acdoca.HouseBank,
      acdoca.HouseBankAccount,
      acdoca.CostCtrActivityType,
      acdoca.WBSElementInternalID,
      acdoca.FinancialTransactionType,
      acdoca.JointVenture,
      acdoca.JointVentureEquityType,
      acdoca.JointVentureEquityGroup,
      acdoca.PartnerVenture,
      acdoca.JointVenturePartner,
      acdoca.JointVentureCostRecoveryCode,
      acdoca.ProjectNetwork,
      acdoca.RelatedNetworkActivity,
      acdoca.OrderID,
      acdoca.BusinessProcess,
      acdoca.SalesOrder,
      acdoca.SalesOrderItem,
      acdoca.CostObject,
      acdoca.CostCenter,
      acdoca.ProfitCenter,
      acdoca.FunctionalArea,
      acdoca.BusinessArea,
      acdoca.ControllingArea,
      acdoca.Segment,
      acdoca.PartnerCostCenter,
      acdoca.PartnerProfitCenter,
      acdoca.PartnerFunctionalArea,
      acdoca.PartnerBusinessArea,

      acdoca.PartnerCompany,


      acdoca.PartnerSegment,
      acdoca.FinancialValuationObjectType,
      acdoca.FinancialValuationObject,
      acdoca.FinancialValuationSubobject,
      acdoca.REBusinessEntity,
      acdoca.RealEstateBuilding,
      acdoca.RealEstateProperty,
      acdoca.Fund,
      acdoca.BudgetPeriod,
      acdoca.GrantID,
      acdoca.PubSecBudgetAccount,
      acdoca.CashLedgerAccount,
      acdoca.SponsoredProgram,
      acdoca.SponsoredClass,
      acdoca.Plant,
      acdoca.Product,
      acdoca.ShipToParty,
      acdoca.PartnerFund,
      acdoca.PartnerGrant,
      acdoca.CashLedgerCompanyCode,
      acdoca.FundsCenter,
      acdoca.PartnerEquityGroup,
      acdoca.FundedProgram,
      acdoca.PartnerBudgetPeriod,
      acdoca.PubSecBudgetAccountCoCode,
      acdoca.ServiceDocument,
      acdoca.ServiceDocumentItem,
      acdoca.ServiceDocumentType,
      acdoca.AccrualObjectType,
      acdoca.AccrualObject,
      acdoca.AccrualSubobject,
      acdoca.AccrualItemType,
      acdoca.AccrualReferenceObject,
      acdoca.AccrualObjectLogicalSystem,
      acdoca.Material,

      acdoca.relatednetworkactivityinternal,

      acdoca.CompanyCode                  as PrdcssrJournalEntryCompanyCode,
      acdoca.FiscalYear                   as PrdcssrJournalEntryFiscalYear,
      acdoca.AccountingDocument           as PredecessorJournalEntry,
      acdoca.LedgerGLLineItem             as PredecessorJournalEntryItem,


      acdoca.BusinessPartner,

      acdoca.CreditRiskClass,

      acdoca.MASTERDATARECNCLNACCT,
      acdoca.MASTERDATAPARTNERCOMPANY,
      acdoca.SpecialGLCode
}

where
  (
       acdoca.InvoiceReference                            is not initial
    or acdoca.InvoiceItemReference                        is not initial
    or acdoca.InvoiceReferenceFiscalYear                  is not initial
  )
  and // residual items

       acdoca.FollowOnDocumentType                        <> 'V'
  and(
       acdoca.Supplier                                    is initial
    or acdoca._SupplierCompany.IsBusinessPurposeCompleted =  ''
  )
  and(
       acdoca.Customer                                    is initial
    or acdoca._CustomerCompany.IsBusinessPurposeCompleted =  ''
  )