SEPMRA_I_UnitOfMeasureText

DDL: SEPMRA_I_UNITOFMEASURETEXT Type: view Package: S_EPMRA_COMMON

Unit of Measure Text

SEPMRA_I_UnitOfMeasureText is a CDS View that provides data about "Unit of Measure Text" in SAP S/4HANA. It reads from 1 data source (t006a) and exposes 7 fields with key fields UnitOfMeasure, Language. It has 1 association to related views. Part of development package S_EPMRA_COMMON.

1 data source(s) 7 fields

Data Sources (1)

SourceAliasJoin Type
t006a Text from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (12)

NameValueLevelField
AbapCatalog.sqlViewName SEPMRAIUOMTEXT view
AbapCatalog.compiler.compareFilter true view
ClientHandling.type #CLIENT_DEPENDENT view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.dataCategory #TEXT view
ObjectModel.representativeKey UnitOfMeasure view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #CUSTOMIZING view
Search.searchable true view
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Unit of Measure Text view

Fields (7)

KeyFieldSource TableSource FieldDescription
KEY UnitOfMeasure
KEY Language
msehtasUnitOfMeasureName
msehlasUnitOfMeasureLongName
mseh3asUnitOfMeasureCommercialName
UnitOfMeasureTechnicalName t006a mseh6
Associations_Language 
@AbapCatalog: {
  sqlViewName: 'SEPMRAIUOMTEXT',
  compiler.compareFilter: true
}

@ClientHandling: {
  type:      #CLIENT_DEPENDENT,
  algorithm: #SESSION_VARIABLE
}

@ObjectModel: {
  dataCategory:      #TEXT,
  representativeKey: 'UnitOfMeasure',
  usageType: {
    serviceQuality: #B,
    sizeCategory:   #M,
    dataClass:      #CUSTOMIZING
  }
}

@Search.searchable: true
@AccessControl.authorizationCheck: #NOT_REQUIRED  -- this view is a text view used in code lists

@EndUserText.label: 'Unit of Measure Text'
define view SEPMRA_I_UnitOfMeasureText
  as select from t006a as Text

  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
      @Semantics: { unitOfMeasure: true }
  key cast( Text.msehi as sepmra_unitofmeasure preserving type ) as UnitOfMeasure,

      @Semantics:   { language: true }
      @ObjectModel: { foreignKey.association: '_Language' }
  key cast( Text.spras as sepmra_language preserving type )      as Language,


      @Search:    { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
      -- TODO: This is actually a text field; but annotating it accordingly would break SADL text denormalization because SADL can handle single text fields only!
      //      @Semantics: { text: true }

      Text.mseht                                                 as UnitOfMeasureName,

      @Search:    { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
      -- TODO: This is actually a text field; but annotating it accordingly would break SADL text denormalization because SADL can handle single text fields only!
      //      @Semantics: { text: true }

      Text.msehl                                                 as UnitOfMeasureLongName,

      @Search:    { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      -- TODO: This is actually a text field; but annotating it accordingly would break SADL text denormalization because SADL can handle single text fields only!
      -- @Semantics: { text: true }
      Text.mseh3                                                 as UnitOfMeasureCommercialName,

      @Search:    { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      @Semantics: { text: true }
      Text.mseh6                                                 as UnitOfMeasureTechnicalName,

      ----------------------------------------------------------------------------------------------------------------
      -- Associations                                                                                               --
      ----------------------------------------------------------------------------------------------------------------
      _Language
}

Learn More