R_WrkAssgmtPaymentMethodTP_2

DDL: R_WRKASSGMTPAYMENTMETHODTP_2 Type: view_entity TRANSACTIONAL Package: ODATA_CA_BUM_WF

Work assignment Payment Method TP

R_WrkAssgmtPaymentMethodTP_2 is a Transactional CDS View that provides data about "Work assignment Payment Method TP" in SAP S/4HANA. It reads from 3 data sources (I_BusinessPartnerSupplier, R_WorkAssignment_2, R_WrkAssgmtPaymentMethod) and exposes 8 fields with key fields WorkAssignmentBusinessPartner, CompanyCode, PaymentMethod. It has 2 associations to related views. Part of development package ODATA_CA_BUM_WF.

3 data source(s) 8 fields

Data Sources (3)

SourceAliasJoin Type
I_BusinessPartnerSupplier _SupplierBP inner
R_WorkAssignment_2 _WorkAssignmentBasic from
R_WrkAssgmtPaymentMethod _WrkAssgmtPaymentMethod inner

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_PaymentMethodText _FinancePaymentMethodText _FinancePaymentMethodText.Country = $projection.CompanyCodeCountry and _FinancePaymentMethodText.PaymentMethod = $projection.PaymentMethod and _FinancePaymentMethodText.Language = $session.system_language
[1..1] R_WorkforcePersonTP_2 _WorkforcePerson $projection.BusinessPartner = _WorkforcePerson.BusinessPartner

Annotations (9)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Work assignment Payment Method TP view
Metadata.ignorePropagatedAnnotations true view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MASTER view
AccessControl.personalData.blocking #NOT_REQUIRED view

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY WorkAssignmentBusinessPartner R_WorkAssignment_2 WorkAssignmentBusinessPartner
KEY CompanyCode R_WorkAssignment_2 CompanyCode
KEY PaymentMethod R_WrkAssgmtPaymentMethod PaymentMethod
CompanyCodeCountry R_WorkAssignment_2 CompanyCodeCountry
BusinessPartner R_WorkAssignment_2 BusinessPartner
_FinancePaymentMethodText _FinancePaymentMethodText
_WorkAssignment _WorkAssignment
_WorkforcePerson _WorkforcePerson 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Work assignment Payment Method TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #MASTER
}
@AccessControl.personalData.blocking: #NOT_REQUIRED
//@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

@Consumption.dbHints: [ '&PREFER_JOIN_WITH_FDA 0&', 'USE_HEX_PLAN' ]
define view entity R_WrkAssgmtPaymentMethodTP_2
  as select from R_WorkAssignment_2        as _WorkAssignmentBasic
    inner join   I_BusinessPartnerSupplier as _SupplierBP             on _WorkAssignmentBasic.WorkAssignmentBusinessPartner = _SupplierBP.BusinessPartner
    inner join   R_WrkAssgmtPaymentMethod  as _WrkAssgmtPaymentMethod on  _WrkAssgmtPaymentMethod.Supplier    = _SupplierBP.Supplier
                                                                      and _WrkAssgmtPaymentMethod.CompanyCode = _WorkAssignmentBasic.CompanyCode
  //FI Payment Method Text

  association [1..1] to I_PaymentMethodText         as _FinancePaymentMethodText on  _FinancePaymentMethodText.Country       = $projection.CompanyCodeCountry
                                                                                 and _FinancePaymentMethodText.PaymentMethod = $projection.PaymentMethod
                                                                                 and _FinancePaymentMethodText.Language      = $session.system_language

  //Below associations for handling DCL

  association [1..1] to R_WorkforcePersonTP_2       as _WorkforcePerson          on  $projection.BusinessPartner = _WorkforcePerson.BusinessPartner
  association        to parent R_WorkAssignmentTP_2 as _WorkAssignment           on  $projection.WorkAssignmentBusinessPartner = _WorkAssignment.WorkAssignmentBusinessPartner

{
  key _WorkAssignmentBasic.WorkAssignmentBusinessPartner as WorkAssignmentBusinessPartner,
  key _WorkAssignmentBasic.CompanyCode                   as CompanyCode,
  key _WrkAssgmtPaymentMethod.PaymentMethod              as PaymentMethod,
      _WorkAssignmentBasic.CompanyCodeCountry            as CompanyCodeCountry,
      _WorkAssignmentBasic.BusinessPartner               as BusinessPartner,
      _FinancePaymentMethodText,
      _WorkAssignment,
      _WorkforcePerson
}

Learn More