R_WorkforceTagTP

DDL: R_WORKFORCETAGTP Type: view_entity TRANSACTIONAL Package: ODATA_CA_BUM_WF

Workforce Tag data TP

R_WorkforceTagTP is a Transactional CDS View that provides data about "Workforce Tag data TP" in SAP S/4HANA. It reads from 2 data sources (I_WorkerCentralPerson, I_EmployeeskillTags) and exposes 11 fields with key field WorkforcePersonTagUUID. It has 1 association to related views. Part of development package ODATA_CA_BUM_WF.

2 data source(s) 11 fields

Data Sources (2)

SourceAliasJoin Type
I_WorkerCentralPerson _WorkerCentralPerson inner
I_EmployeeskillTags SkillTag from

Associations (1)

CardinalityTargetAliasCondition
[1..1] I_BusinessPartner _WorkforcePersonBP _WorkforcePersonBP.BusinessPartner is not initial and _WorkforcePersonBP.BusinessPartner = _WorkerCentralPerson.BusinessPartner

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
EndUserText.label Workforce Tag data TP view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MASTER view

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY WorkforcePersonTagUUID I_EmployeeskillTags EmployeeSkillTagID
PersonUUID _WorkforcePersonBP BusinessPartnerUUID
PersonnelNumber I_EmployeeskillTags PersonnelNumber
WorkforcePersonTagTypeValue I_EmployeeskillTags EmployeeSkillTagType
WorkforcePersonTagText I_EmployeeskillTags EmployeeSkillTagName
SystemOfRecordID I_EmployeeskillTags SystemOfRecordID
LastChangeDateTime I_EmployeeskillTags LastChangeDate
LastChangedByUser I_EmployeeskillTags LastChangedByUser
_CreatedByUser I_EmployeeskillTags _CreatedByUser
LastChangedByUserFullName
_WorkforcePerson _WorkforcePerson 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl: { authorizationCheck: #CHECK,
                  privilegedAssociations: [ '_CREATEDBYUSER' ]
                  }
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@EndUserText.label: 'Workforce Tag data TP'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #MASTER
}
@Consumption.dbHints: [ '&PREFER_JOIN_WITH_FDA 0&', 'USE_HEX_PLAN' ]
define view entity R_WorkforceTagTP
  as select from I_EmployeeskillTags   as SkillTag
  //    left outer to one join I_WorkerCentralPerson as _WorkerCentralPerson on _WorkerCentralPerson.CentralPerson = SkillTag.PersonnelNumber

    inner join   I_WorkerCentralPerson as _WorkerCentralPerson on  _WorkerCentralPerson.CentralPerson = SkillTag.PersonnelNumber
                                                               and SkillTag.PersonnelNumber           is not initial
  association [1..1] to I_BusinessPartner          as _WorkforcePersonBP on  _WorkforcePersonBP.BusinessPartner is not initial
                                                                         and _WorkforcePersonBP.BusinessPartner = _WorkerCentralPerson.BusinessPartner

  //then get the uuid by inner join - double check i buspartnr

  association        to parent R_WorkforcePersonTP as _WorkforcePerson   on  $projection.PersonUUID = _WorkforcePerson.PersonUUID
{
  key   SkillTag.EmployeeSkillTagID                                     as WorkforcePersonTagUUID,
        _WorkforcePersonBP.BusinessPartnerUUID                          as PersonUUID,
        SkillTag.PersonnelNumber                                        as PersonnelNumber,
        SkillTag.EmployeeSkillTagType                                   as WorkforcePersonTagTypeValue,
        SkillTag.EmployeeSkillTagName                                   as WorkforcePersonTagText,
        SkillTag.SystemOfRecordID                                       as SystemOfRecordID,
        SkillTag.LastChangeDate                                         as LastChangeDateTime,
        SkillTag.LastChangedByUser,
        /* Associations */
        SkillTag._CreatedByUser,
        cast( SkillTag._CreatedByUser.UserDescription as suidtechdesc ) as LastChangedByUserFullName,
        _WorkforcePerson
}
where
  SkillTag.EmployeeSkillTagType = 'U'

Learn More