R_WorkforcePersonTP_3

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Workforce Person Transactional Processing'

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@ObjectModel: {
    usageType.serviceQuality: #C,
    usageType.sizeCategory : #XXL,
    usageType.dataClass: #MASTER,
    supportedCapabilities: [#TRANSACTIONAL_PROVIDER]
    //modelingPattern: #TRANSACTIONAL_INTERFACE

}
@ObjectModel.alternativeKey: [{id: 'BusinessPartner'}, {id: 'BusinessPartnerUUID'}, {id: 'WorkforcePersonExternalUUID'}]
@ObjectModel.representativeKey: 'WorkforcePersonExternalID'
@ObjectModel.sapObjectNodeType.name: 'WorkforcePerson'
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.personalData.blocking: #REQUIRED
@Consumption.dbHints:[ 'USE_HEX_PLAN' ]


define root view entity R_WorkforcePersonTP_3
  as select from            I_BusinessPartner      as _BP
  //   inner join      P_BPUSRPERSONEXTERNALID as _BPIdentification  on _BPIdentification.BusinessPartner = _BP.BusinessPartner

    inner join              R_BPUserIdentification as _BPIdentification  on _BPIdentification.BusinessPartner = _BP.BusinessPartner
    inner join              I_AddressPersonName    as _AddressPersonName on  _AddressPersonName.AddressPersonID           = _BP.PersonNumber
                                                                         and _AddressPersonName.AddressRepresentationCode = ''
  //    inner join      P_BPUsrBURoleUnique     as _BPRole            on _BPRole.BusinessPartner = _BP.BusinessPartner

    inner join              R_BPUsrBusRoleUnique   as _BPRole            on _BPRole.BusinessPartner = _BP.BusinessPartner
    left outer to many join I_WorkplaceAddress     as _WorkplaceAddress  on _WorkplaceAddress.BusinessPartnerUUID = _BP.BusinessPartnerUUID
  // left outer join I_WrkFrcPersnMainEmployment as _mainemployment on _mainemployment.BusinessPartner = _BP.BusinessPartner

  // association [0..*] to P_WorkplaceAddress      as _WorkplaceAddress  on _WorkplaceAddress.BusinessPartnerUUID = _BP.BusinessPartnerUUID


  composition [0..*] of R_WorkAssignmentTP_3          as _WorkAssignment

  composition [1..*] of R_WorkforcePersonRoleTP_3     as _WorkforcePersonRole

  composition [0..*] of R_WorkforcePersonSkillTagTP_3 as _WorkforcePersonSkillTag

  association [0..1] to I_WrkFrcPersnMainEmployment   
   as _mainemployment on _mainemployment.BusinessPartner = _BP.BusinessPartner

  //  association [0..*] to I_BuPaIdentification      as _BPIdentificationHCM034 on  _BP.BusinessPartner                          = _BPIdentificationHCM034.BusinessPartner

  //                                                                             and _BPIdentificationHCM034.BPIdentificationType = 'HCM034'

  //  association [0..1] to E_BP_D                  as _BusinessPartnerExt     on  $projection.BusinessPartner = _BusinessPartnerExt.BusinessPartner

{
  key  _BPIdentification.BPIdentificationNumber as WorkforcePersonExternalID, //PersonExternalID

       _BP.BusinessPartner,
       _BP.BusinessPartnerUUID,
       //       _BPIdentificationHCM034.BPIdentificationNumber                         as WorkforcePersonExternalUUID,

       @Semantics.text:true
       @EndUserText.label: 'Full Name'
       _AddressPersonName.PersonFullName        as FullName,
       _BP.FormOfAddress,
       /* Person Data */
       _BP.FirstName,
       _BP.LastName,
       _BP.AdditionalLastName,
       _BP.BusinessPartnerBirthName             as BirthName,
       _BP.MiddleName,
       _BP.AcademicTitle,
       _BP.AcademicTitle2,
       _BP.BusinessPartnerSupplementName,
       _BP.LastNamePrefix,
       @Semantics.text:true
       _BP.LastNameSecondPrefix,
       _BP.BusinessPartnerNicknameLabel,
       _BP.Initials,
       _BP.CorrespondenceLanguage               as NativePreferredLanguage,
       _WorkplaceAddress.DestinationLocationCountry,
       _WorkplaceAddress.PhoneNumber,
       _WorkplaceAddress.PhoneNumberExtension,
       _WorkplaceAddress.MblPhoneDestinationLocCountry,
       _WorkplaceAddress.MobilePhoneNumber,
       _WorkplaceAddress.DefaultEmailAddress,
        @Feature: 'WFD_FT_ODATA_DELTAFIELDS'
       _BP.CreationDate,
        @Feature: 'WFD_FT_ODATA_DELTAFIELDS'
       _BP.CreationTime,
       _BP.LastChangeDate,
        @Feature: 'WFD_FT_ODATA_DELTAFIELDS'
       _BP.LastChangeTime,
       _BP.ETag,
       _BP.AuthorizationGroup,
       _BP.IsBusinessPurposeCompleted,
       _mainemployment.MainEmployment,
       _BP.DataControllerSet,
       _BP.DataController1,
       _BP.DataController2,
       _BP.DataController3,
       _BP.DataController4,
       _BP.DataController5,
       _BP.DataController6,
       _BP.DataController7,
       _BP.DataController8,
       _BP.DataController9,
       _BP.DataController10,
       //       cast ( hextobin( '00000000000000000000000000000000' ) as sysuuid_x16 ) as PID_Assoc, //To Store Preliminary ID


       _WorkAssignment,
       _WorkforcePersonRole,
       _WorkforcePersonSkillTag
}
where
  _BP.BusinessPartnerCategory = '1' //Person