R_WorkAssignmentPrivateAddress

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Address Associated with Work Assignment'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
    serviceQuality: #C,
    sizeCategory: #L,
    dataClass: #MIXED
}
@Consumption.dbHints:[ 'USE_HEX_PLAN' ]
define view entity R_WorkAssignmentPrivateAddress
  as select distinct from I_Businesspartneraddressusage as _BPAddressUsage
    inner join            R_WorkAssignmentBP            as _BuPaIdentification on _BuPaIdentification.WorkAssignmentBusinessPartner = _BPAddressUsage.BusinessPartner

    inner join            I_BusPartAddress              as _BPAddress          on  _BPAddressUsage.BusinessPartner = _BPAddress.BusinessPartner
                                                                               and _BPAddressUsage.AddressNumber   = _BPAddress.AddressID
  association [1..1] to I_WorkAssignmentDetail_1 as _AssgmtDetails      on  _AssgmtDetails.WorkforceAssignment       = _BuPaIdentification.WorkforceAssignment
                                                                        and _AssgmtDetails.WorkforceAssgmtStartDate  <= $session.system_date
                                                                        and _AssgmtDetails.WorkforceAssgmtEndDate    >= $session.system_date
                                                                        and _AssgmtDetails.WorkforceAssignmentStatus = '1'
  association [0..1] to I_BPProtectedAddress     as _BPProtectedAddress on  $projection.BusinessPartner = _BPProtectedAddress.BusinessPartner
                                                                        and $projection.AddressNumber   = _BPProtectedAddress.AddressID
  association [0..1] to I_CountryText            as _CountryText        on  $projection.CountryOrRegion = _CountryText.Country
                                                                        and _CountryText.Language       = $session.system_language
  association [0..1] to I_RegionText             as _RegionText         on  $projection.AddressRegion   = _RegionText.Region
                                                                        and $projection.CountryOrRegion = _RegionText.Country
                                                                        and _RegionText.Language        = $session.system_language
  association [1..1] to I_BusinessPartner        as _BP                 on  _BP.BusinessPartner = _BPAddressUsage.BusinessPartner
  association        to parent R_WorkAssignment  as _WorkAssignment     on  $projection.WorkAssignmentUUID = _WorkAssignment.WorkAssignmentUUID
                                                                        and $projection.WorkAssignment     = _WorkAssignment.WorkAssignment

{
  key _BP.BusinessPartnerUUID                                                                        as WorkAssignmentUUID,
  key _BPAddressUsage.AddressNumber                                                                  as AddressNumber,
      _BPAddressUsage.BusinessPartner                                                                as BusinessPartner,
      cast (tstmp_to_dats( _BPAddressUsage.ValidityStartDate,
      abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' ) as vdm_v_start_date) as StartDate,
      cast (tstmp_to_dats( _BPAddressUsage.ValidityEndDate,
        abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' ) as vdm_v_end_date) as EndDate,
      _BPAddress._AddressDefaultRepresentation.HouseNumber                                           as HouseNumber,
      _BPAddress._AddressDefaultRepresentation.HouseNumberSupplementText                             as HouseNumberSupplementText, //HouseSupplement,

      _BPAddress._AddressDefaultRepresentation.Region                                                as AddressRegion, //Region,

      _BPAddress._AddressDefaultRepresentation.PostalCode                                            as AddressPostalCode, //PostalCode,

      _BPAddress._AddressDefaultRepresentation.POBoxPostalCode                                       as PostOfficeBoxPostalCode, //POpostalcode,

      _BPAddress._AddressDefaultRepresentation.DistrictName                                          as DistrictName,
      _BPAddress._AddressDefaultRepresentation.POBox                                                 as POBox,
      _BPAddress._AddressDefaultRepresentation.Street                                                as Street,
      _BPAddress._AddressDefaultRepresentation.StreetName                                            as StreetName,
      _BPAddress._AddressDefaultRepresentation.CityName                                              as CityName, //City,

      _BPAddress._AddressDefaultRepresentation.Floor                                                 as Floor,
      _BPAddress._AddressDefaultRepresentation.Country                                               as CountryOrRegion,
      //      _BPAddress._Address._Country.Country                                                           as CountryOrRegion,

      //      _BPAddress._Address._Country._Text[1:Language = $session.system_language].CountryName,

      _BPAddress._AddressDefaultRepresentation.RoomNumber                                            as RoomNumber,
      case _BuPaIdentification.BPRoleCategoryUsageCode
             when  'C'
            then _BuPaIdentification.WorkforceAssignment
             when 'B'
         then _AssgmtDetails.WorkforceAssignment
      else null
              end                                                                                    as WorkAssignment,
      @Semantics.booleanIndicator: true
      _BP.IsBusinessPurposeCompleted,
      _BP.DataControllerSet,
      _BP.DataController1,
      _BP.DataController2,
      _BP.DataController3,
      _BP.DataController4,
      _BP.DataController5,
      _BP.DataController6,
      _BP.DataController7,
      _BP.DataController8,
      _BP.DataController9,
      _BP.DataController10,
      _BP.AuthorizationGroup,
      _BuPaIdentification.BPRoleCategoryUsageCode,
      _CountryText,
      _RegionText,
      _WorkAssignment,
      _BPProtectedAddress
}
where
  _BPAddressUsage.AddressUsage = 'HCM001'