R_WorkAssignmentDetailsTP_2

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Work Assignment Details TP'
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #MASTER
}
//@Consumption.dbHints: ['USE_HEX_PLAN']

@Consumption.dbHints: [ '&PREFER_JOIN_WITH_FDA 0&', 'USE_HEX_PLAN' ]
define view entity R_WorkAssignmentDetailsTP_2
  as select from R_WorkAssignmentDetailsAll as _AssignmentDetails
  //Get the Employment BP (for both old and new BP Models)

    inner join   R_WorkAssignmentBP         as _BuPaIdentification on _BuPaIdentification.WorkforceAssignment = _AssignmentDetails.WorkAssignment
    inner join   R_WorkAssignmentKeyMap     as _AssignmentKeyMap   on _AssignmentKeyMap.WorkforceAssignment = _AssignmentDetails.WorkAssignment

  association [0..1] to R_ManagerWorkAssignmentVH   as _ManagerWorkAssignmentVH   on  $projection.ManagerEmployee = _ManagerWorkAssignmentVH.ManagerAssignmentExternalID
                                                                                  and $projection.CompanyCode     = _ManagerWorkAssignmentVH.CompanyCode
                                                                                  and $projection.ManagerEmployee is not initial
  association [0..1] to I_CostCenter                as _CostCenterText            on  $projection.CompanyCode           =  _CostCenterText.CompanyCode
                                                                                  and $projection.CostCenter            =  _CostCenterText.CostCenter
                                                                                  and _CostCenterText.ControllingArea   =  'A000'
                                                                                  and _CostCenterText.ValidityStartDate <= _AssignmentDetails.EndDate
                                                                                  and _CostCenterText.ValidityEndDate   >= _AssignmentDetails.EndDate
  association [0..1] to I_CompanyCode               as _CompanyCodeText           on  $projection.CompanyCode = _CompanyCodeText.CompanyCode
  association [0..1] to I_WorkforceAssgmtStatusText as _WorkforceAssignmentStatus on  $projection.WorkforceAssignmentStatus = _WorkforceAssignmentStatus.WorkforceAssignmentStatus
                                                                                  and _WorkforceAssignmentStatus.Language   = $session.system_language
  association [1..1] to R_WorkforcePersonTP_2       as _WorkforcePerson           on  $projection.BusinessPartner = _WorkforcePerson.BusinessPartner
  association        to parent R_WorkAssignmentTP_2 as _WorkAssignment            on  $projection.WorkAssignmentBusinessPartner = _WorkAssignment.WorkAssignmentBusinessPartner
{
  key   _BuPaIdentification.WorkAssignmentBusinessPartner                 as WorkAssignmentBusinessPartner,
  key   _AssignmentDetails.StartDate                                      as StartDate,
        _AssignmentDetails.EndDate                                        as EndDate,
        _AssignmentDetails.WorkAssignment                                 as WorkAssignment,
        _AssignmentDetails.CompanyCode                                    as CompanyCode,
        _AssignmentDetails.CostCenter                                     as CostCenter,
        _AssignmentKeyMap.BusinessPartner                                 as BusinessPartner,
        _AssignmentDetails.WorkforcePersonJobCode                         as WorkforcePersonJobCode,
        _AssignmentDetails.WorkforcePersonJobTitle                        as WorkforcePersonJobTitle,
        cast ( _AssignmentDetails.WorkforceAssignmentIsPrimary as xfeld ) as WorkforceAssignmentIsPrimary,
        _AssignmentDetails.ManagerAssignmentID                            as ManagerAssignmentID,
        _AssignmentDetails.WeeklyWorkingDays                              as WeeklyWorkingDays,
        _AssignmentDetails.WeeklyWorkingHours                             as WeeklyWorkingHours,
        _AssignmentDetails.EmploymentPercent                              as EmploymentPercent,
        _AssignmentDetails.WorkforceAssignmentStatus                      as WorkforceAssignmentStatus,
        @Consumption.valueHelp:'_ManagerWorkAssignmentVH'
        _AssignmentDetails.ManagerAssignmentExternalID                    as ManagerEmployee,
        cast( ' ' as boolean )                                            as IsEditable,
        cast('%' as qprozent)                                             as EmploymentPercentageUnit,
        _AssignmentDetails.IsBlocked                                      as IsBlocked,

        _WorkAssignment,
        _WorkforcePerson,
        _ManagerWorkAssignmentVH,
        _CostCenterText,
        _WorkforceAssignmentStatus,
        _CompanyCodeText
        
}
//where

//  _AssignmentDetails.CompanyCode is not initial