R_WorkAgreementPaymentMethod

@AbapCatalog.sqlViewName: 'R_WRKASSPAYMENT'
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AbapCatalog.compiler.compareFilter:true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking:#BLOCKED_DATA_EXCLUDED
@EndUserText.label: 'Work Assignment Payment Method'
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #MASTER
}
@Consumption.dbHints:[ 'USE_HEX_PLAN' ]

define view R_WorkAgreementPaymentMethod
  as select from           I_Supplier_to_BusinessPartner as _SupplierBP
    inner join             R_WorkAssignmentBasic         as _WorkAssignmentBasic    on _WorkAssignmentBasic.WorkAssignmentUUID = _SupplierBP.BusinessPartnerUUID
    inner join             R_WrkAssgmtPaymentMethod      as _WrkAssgmtPaymentMethod on  _WrkAssgmtPaymentMethod.Supplier    = _SupplierBP.Supplier
                                                                                    and _WrkAssgmtPaymentMethod.CompanyCode = _WorkAssignmentBasic.CompanyCode
  //Get Company Code Country

    left outer to one join I_CompanyCode                 as _CompanyCode            on _CompanyCode.CompanyCode = _WorkAssignmentBasic.CompanyCode

  //FI Payment Method Text

  association [1..1] to I_PaymentMethodText        as _FinancePaymentMethodText on  _FinancePaymentMethodText.Country       = $projection.CompanyCodeCountry
                                                                                and _FinancePaymentMethodText.PaymentMethod = $projection.PaymentMethod
                                                                                and _FinancePaymentMethodText.Language      = $session.system_language
  //Below associations for handling DCL

  association [1..1] to R_WorkforcePersonFactSheet as _WorkforcePerson          on  $projection.PersonUUID = _WorkforcePerson.PersonUUID
  association        to parent R_WorkAssignment    as _WorkAssignment           on  $projection.WorkAssignmentUUID = _WorkAssignment.WorkAssignmentUUID
                                                                                and $projection.WorkAssignment     = _WorkAssignment.WorkAssignment
{
  key _SupplierBP.BusinessPartnerUUID       as WorkAssignmentUUID,
  key _CompanyCode.CompanyCode              as CompanyCode,
  key _WrkAssgmtPaymentMethod.PaymentMethod as PaymentMethod,
  key _WorkAssignmentBasic.WorkAssignment  as WorkAssignment,  
//  key _WorkAssignment.WorkAssignment        as WorkAssignment,

      _CompanyCode.Country                  as CompanyCodeCountry,
      _WorkAssignmentBasic.PersonUUID       as PersonUUID,
      _FinancePaymentMethodText,
      _WorkAssignment,
      _WorkforcePerson
}