R_TranspOrderChargeItemTP

DDL: R_TRANSPORDERCHARGEITEMTP Type: view_entity TRANSACTIONAL Package: RAP_TM_TOR

Transportation Charge Item

R_TranspOrderChargeItemTP is a Transactional CDS View that provides data about "Transportation Charge Item" in SAP S/4HANA. It reads from 1 data source (I_TranspChargeItem) and exposes 25 fields with key field TranspChargeItemUUID. It has 3 associations to related views. Part of development package RAP_TM_TOR.

1 data source(s) 25 fields

Data Sources (1)

SourceAliasJoin Type
I_TranspChargeItem I_TranspChargeItem from

Associations (3)

CardinalityTargetAliasCondition
[1..1] R_TransportationOrderTP _TransportationOrder $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID
[0..*] R_TranspOrdChrgElmntTP _TranspOrdChrgElmnt
[0..*] R_TranspOrdChrgItmExchRateTP _TranspOrdChrgItmExchRate

Annotations (9)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Transportation Charge Item view
Metadata.ignorePropagatedAnnotations true view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #XXL view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.representativeKey TranspChargeItemUUID view

Fields (25)

KeyFieldSource TableSource FieldDescription
KEY TranspChargeItemUUID TranspChargeItemUUID
TransportationChargesObjUUID TransportationChargeUUID
TransportationOrderUUID TranspChargeHostDocumentUUID
HostObjectSAPObjectType HostObjectSAPObjectType
HostObjNodeSAPObjectNodeType HostObjNodeSAPObjectNodeType
TranspChargeCalcLevelRefUUID TranspChargeCalcLevelRefUUID
TransportationAgreementUUID TransportationAgreementUUID
BusinessPartnerUUID BusinessPartnerUUID
TranspChargeCalcLevel TranspChargeCalcLevel
TranspChargePostingStatus TranspChargePostingStatus
TranspChrgItemDocCurrency TranspChrgItemDocCurrency
TranspChrgItmTotAmtInDocCrcy
TranspChrgItemLoclCurrency TranspChrgItemLoclCurrency
TranspChrgItmTotAmtInLoclCrcy
TranspChargeItemCalcDateTme TranspChargeCalculationDateTme
ExchangeRateDate TranspChrgItemExchangeRateDate
TranspChargePostingDate TranspChargePostingDate
TranspChrgCalcDteTmeIsChanged TranspChrgCalcDteTmeIsChanged
PaymentTerms TranspChargePaymentTerms
TransportationOrderCategory _TransportationOrder TransportationOrderCategory
_TransportationOrder _TransportationOrder
_BusinessPartner _BusinessPartner
_TranspOrdChrgElmnt _TranspOrdChrgElmnt
_TransportationOrderCharge _TransportationOrderCharge
_TranspOrdChrgItmExchRate _TranspOrdChrgItmExchRate 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl: {
authorizationCheck: #MANDATORY,
privilegedAssociations: [
    '_TranspOrdChrgElmnt',
    '_TranspOrdChrgItmExchRate'
  ]
}
@EndUserText.label: 'Transportation Charge Item'
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
usageType:{
  serviceQuality: #B,
  sizeCategory: #XXL,
  dataClass: #TRANSACTIONAL
  },
  representativeKey: 'TranspChargeItemUUID'
}
define view entity R_TranspOrderChargeItemTP
  as select from I_TranspChargeItem
  composition [0..*] of R_TranspOrdChrgElmntTP        as _TranspOrdChrgElmnt
  composition [0..*] of R_TranspOrdChrgItmExchRateTP  as _TranspOrdChrgItmExchRate
  association        to parent R_TransportationOrderChargeTP as _TransportationOrderCharge on $projection.TransportationChargesObjUUID = _TransportationOrderCharge.TransportationChargesObjUUID
  association [1..1] to R_TransportationOrderTP       as _TransportationOrder              on $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID
{
  key TranspChargeItemUUID,
      TransportationChargeUUID                                                              as TransportationChargesObjUUID,
      TranspChargeHostDocumentUUID                                                          as TransportationOrderUUID,
      HostObjectSAPObjectType,
      HostObjNodeSAPObjectNodeType,
      TranspChargeCalcLevelRefUUID,
      TransportationAgreementUUID,
      BusinessPartnerUUID,
      TranspChargeCalcLevel,
      TranspChargePostingStatus,
      TranspChrgItemDocCurrency,
      @Semantics.amount.currencyCode: 'TranspChrgItemDocCurrency'
      cast( TranspChrgItmTotAmtInDocCrcy as transpchrgtotalamtindoccrcy preserving type )   as TranspChrgItmTotAmtInDocCrcy,
      TranspChrgItemLoclCurrency,
      @Semantics.amount.currencyCode: 'TranspChrgItemLoclCurrency'
      cast( TranspChrgItmTotAmtInLoclCrcy as transpchrgtotalamtinloclcrcy preserving type ) as TranspChrgItmTotAmtInLoclCrcy,
      TranspChargeCalculationDateTme                                                        as TranspChargeItemCalcDateTme,
      TranspChrgItemExchangeRateDate                                                        as ExchangeRateDate,
      TranspChargePostingDate,
      TranspChrgCalcDteTmeIsChanged,
      TranspChargePaymentTerms                                                              as PaymentTerms,
      // TransportationOrderCategory needed for filtering in projection view

      _TransportationOrder.TransportationOrderCategory,

      /* Associations */
      _TransportationOrder,
      _BusinessPartner,

      /* Composition Associations */
      _TranspOrdChrgElmnt,
      _TransportationOrderCharge,
      _TranspOrdChrgItmExchRate
}
where
    HostObjectSAPObjectType = 'TransportationOrder' and 
    HostObjNodeSAPObjectNodeType = 'TransportationOrder';

Learn More