R_StockTransportOrderItemNote

DDL: R_STOCKTRANSPORTORDERITEMNOTE Type: view_entity BASIC Package: VDM_MM_STO

Item Note for Stock Transport Order

R_StockTransportOrderItemNote is a Basic CDS View that provides data about "Item Note for Stock Transport Order" in SAP S/4HANA. It reads from 2 data sources (R_StockTransportOrderItem, I_TextObjectPlainLongText) and exposes 12 fields with key fields StockTransportOrder, StockTransportOrderItem, TextObjectType, Language. Part of development package VDM_MM_STO.

2 data source(s) 12 fields

Data Sources (2)

SourceAliasJoin Type
R_StockTransportOrderItem StockTransportOrderItem from
I_TextObjectPlainLongText StockTransportOrderItemText inner

Annotations (8)

NameValueLevelField
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #BASIC view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #L view
AccessControl.authorizationCheck #PRIVILEGED_ONLY view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
EndUserText.label Item Note for Stock Transport Order view

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY StockTransportOrder R_StockTransportOrderItem StockTransportOrder
KEY StockTransportOrderItem R_StockTransportOrderItem StockTransportOrderItem
KEY TextObjectType I_TextObjectPlainLongText TextObjectType
KEY Language I_TextObjectPlainLongText Language
STOItemUniqueID R_StockTransportOrderItem STOItemUniqueID
PlainLongText I_TextObjectPlainLongText PlainLongText
_Language I_TextObjectPlainLongText _Language
StockTransportOrderType R_StockTransportOrderItem StockTransportOrderType
PurchasingOrganization R_StockTransportOrderItem PurchasingOrganization
PurchasingGroup R_StockTransportOrderItem PurchasingGroup
Plant R_StockTransportOrderItem Plant
_TextObjectPlainLongText _TextObjectPlainLongText 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #BASIC
}

@ObjectModel: {
  usageType: {
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #A,
    sizeCategory:   #L
  }
}

@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED,
  privilegedAssociations: ['_TextObjectPlainLongText']
}

@EndUserText.label: 'Item Note for Stock Transport Order'

define view entity R_StockTransportOrderItemNote
  as select from R_StockTransportOrderItem as StockTransportOrderItem
    inner join   I_TextObjectPlainLongText as StockTransportOrderItemText on StockTransportOrderItem.STOItemUniqueID = StockTransportOrderItemText.TextObjectKey

  association to many I_TextObjectPlainLongText as _TextObjectPlainLongText on  _TextObjectPlainLongText.TextObjectKey      = $projection.STOItemUniqueID
                                                                            and _TextObjectPlainLongText.TextObjectCategory = 'EKPO'
{
  key StockTransportOrderItem.StockTransportOrder,
  key StockTransportOrderItem.StockTransportOrderItem,
  key StockTransportOrderItemText.TextObjectType,
  key StockTransportOrderItemText.Language,
      StockTransportOrderItem.STOItemUniqueID,
      StockTransportOrderItemText.PlainLongText,
      StockTransportOrderItemText._Language,
      
      StockTransportOrderItem.StockTransportOrderType,
      StockTransportOrderItem.PurchasingOrganization,
      StockTransportOrderItem.PurchasingGroup,
      StockTransportOrderItem.Plant,

      _TextObjectPlainLongText
}
where
  StockTransportOrderItemText.TextObjectCategory = 'EKPO'

Learn More