R_SrvcQtanPartnerAddressTP

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata:
{
  ignorePropagatedAnnotations: true
}
@EndUserText.label: 'Partner Address For Service Quotation-TP'
@ObjectModel: {
   usageType: {dataClass:      #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory:   #L}
}
define view entity R_SrvcQtanPartnerAddressTP
  as select from I_SrvcDocPartnerAddress

    inner join   I_ServiceDocument as ServiceQuotation on  ServiceQuotation.ServiceDocument            = I_SrvcDocPartnerAddress.ServiceDocument
                                                       and ServiceQuotation.ServiceObjectType          = 'BUS2000116'
                                                       and ServiceQuotation.ServiceDocumentIsQuotation is not initial


  association        to parent R_SrvcQtanPartnerTP as _SrvcQtanPartnerTP  on  $projection.ServiceQuotation        = _SrvcQtanPartnerTP.ServiceQuotation
                                                                          and $projection.CustMgmtPartnerFunction = _SrvcQtanPartnerTP.CustMgmtPartnerFunction
                                                                          and $projection.CustMgmtBusinessPartner = _SrvcQtanPartnerTP.CustMgmtBusinessPartner
  association [0..1] to R_ServiceQuotationTP       as _ServiceQuotationTP on  $projection.ServiceQuotation = _ServiceQuotationTP.ServiceQuotation

{
      @ObjectModel.foreignKey.association: '_ServiceQuotationTP'
  key I_SrvcDocPartnerAddress.ServiceDocument as ServiceQuotation,
  key I_SrvcDocPartnerAddress.CustMgmtPartnerFunction,
  key I_SrvcDocPartnerAddress.CustMgmtBusinessPartner,
      I_SrvcDocPartnerAddress.CityName,
      I_SrvcDocPartnerAddress.CorrespondenceLanguage,
      I_SrvcDocPartnerAddress.Country,
      I_SrvcDocPartnerAddress.DistrictName,
      I_SrvcDocPartnerAddress.EmailAddress,
      I_SrvcDocPartnerAddress.FaxAreaCodeSubscriberNumber,
      I_SrvcDocPartnerAddress.FaxExtensionNumber,
      I_SrvcDocPartnerAddress.FaxNumberCountry,
      I_SrvcDocPartnerAddress.FormOfAddress,
      I_SrvcDocPartnerAddress.HouseNumber,
      I_SrvcDocPartnerAddress.MobileNumber,
      I_SrvcDocPartnerAddress.MobilePhoneCountry,
      I_SrvcDocPartnerAddress.OrganizationName1,
      I_SrvcDocPartnerAddress.OrganizationName2,
      I_SrvcDocPartnerAddress.OrganizationName3,
      I_SrvcDocPartnerAddress.OrganizationName4,
      I_SrvcDocPartnerAddress.PersonFamilyName,
      I_SrvcDocPartnerAddress.PersonGivenName,
      I_SrvcDocPartnerAddress.PhoneExtensionNumber,
      I_SrvcDocPartnerAddress.PhoneNumber,
      //      PhoneNumberCountry,

      I_SrvcDocPartnerAddress.POBox,
      I_SrvcDocPartnerAddress.POBoxPostalCode,
      I_SrvcDocPartnerAddress.PostalCode,
      I_SrvcDocPartnerAddress.Region,
      I_SrvcDocPartnerAddress.StreetName,
      I_SrvcDocPartnerAddress.StreetPrefixName1,
      I_SrvcDocPartnerAddress.StreetPrefixName2,
      I_SrvcDocPartnerAddress.StreetSuffixName1,
      I_SrvcDocPartnerAddress.StreetSuffixName2,
      I_SrvcDocPartnerAddress.TaxJurisdiction,
      I_SrvcDocPartnerAddress.TransportZone,

      //Associations

      _SrvcQtanPartnerTP,
      _ServiceQuotationTP
}
where
      I_SrvcDocPartnerAddress.CustMgmtObjectType  = 'BUS2000116'
  and I_SrvcDocPartnerAddress.ServiceDocumentItem is initial