R_SrvcDocItemPartnerAddress

@AccessControl: {
  authorizationCheck:#PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
}
@EndUserText.label: 'Partner Address For Srvc Trans Item'
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
define view entity R_SrvcDocItemPartnerAddress 
as select from I_ServiceDocumentItemPartner //P_SrvcDocItemPartner

            as ServicePartner
  association [0..1] to I_Address_2              as _Address                on  $projection.AddressID = _Address.AddressID
  association [0..1] to I_PersonWorkplaceAddress as _PersonWorkplaceAddress on  $projection.AddressID         = _PersonWorkplaceAddress.AddressID
                                                                            and $projection.AddressPersonID   = _PersonWorkplaceAddress.AddressPersonID
                                                                            and $projection.AddressObjectType = '3'


{
  key  ServicePartner.ServiceDocument                                       as ServiceDocument,
  key  ServiceDocumentItem                                                     as ServiceDocumentItem,
  key  ServicePartner.CustMgmtPartnerFunction,
  key  ServicePartner.CustMgmtBusinessPartner,

       ServicePartner.ServiceObjectType                                     as CustMgmtObjectType,
       //Added for PersonWorkPlaceAddress association

       @Consumption.hidden: true
       @ObjectModel.readOnly: true
       ServicePartner.AddressID,
       @Consumption.hidden: true
       @ObjectModel.readOnly: true
       ServicePartner.AddressPersonID,

       @Consumption.hidden: true
       @ObjectModel.readOnly: true
       //Added to fetch address details based on address type

       ServicePartner.AddressObjectType,

       @ObjectModel.readOnly: true
       case
           when ServicePartner.AddressObjectType = '3'
            then _PersonWorkplaceAddress.PersonFullName
           else _Address.AddresseeFullName
       end                                                                  as AddresseeFullName,
       _Address.CityName,
       _Address.CorrespondenceLanguage                                      as CorrespondenceLanguage,
       //       case

       //           when ServicePartner.AddressObjectType = '1'

       //            then _Address.CorrespondenceLanguage

       //       //            _PersonWorkplaceAddress.CorrespondenceLanguage

       //           else _Address.CorrespondenceLanguage

       //       end                                                                  as CorrespondenceLanguage,

       _Address.Country,
       _Address.DistrictName,
       case
        when ServicePartner.AddressObjectType = '3'
        then _PersonWorkplaceAddress._CurrentDfltEmailAddress.EmailAddress
        else
       _Address._CurrentDfltEmailAddress.EmailAddress
       end                                                                  as EmailAddress,
       _Address._CurrentDfltFaxNumber.FaxAreaCodeSubscriberNumber,
       _Address._CurrentDfltFaxNumber.FaxExtensionNumber,
       _Address._CurrentDfltFaxNumber.FaxNumberCountry,
       _Address.FormOfAddress                                               as FormOfAddress,
       //       case

       //           when ServicePartner.AddressObjectType = '3'

       //            then _PersonWorkplaceAddress.FormOfAddress

       //           else _Address.FormOfAddress

       //       end                                                                  as FormOfAddress,

       _Address.HouseNumber,
       _Address._CurrentDfltMobilePhoneNumber.PhoneAreaCodeSubscriberNumber as MobileNumber,
       _Address._CurrentDfltMobilePhoneNumber.PhoneNumberCountry            as MobilePhoneCountry,
       _Address.OrganizationName1,
       _Address.OrganizationName2,
       _Address.OrganizationName3,
       _Address.OrganizationName4,
       case
           when ServicePartner.AddressObjectType = '3'
            then _PersonWorkplaceAddress.FamilyName
           else _Address.PersonFamilyName
       end                                                                  as PersonFamilyName,
       case
           when ServicePartner.AddressObjectType = '3'
            then _PersonWorkplaceAddress.GivenName
           else _Address.PersonGivenName
       end                                                                  as PersonGivenName,

       case
          when ServicePartner.AddressObjectType = '3'
           then _PersonWorkplaceAddress._CurrentDfltLandlinePhoneNmbr.PhoneExtensionNumber
          else _Address._CurrentDfltLandlinePhoneNmbr.PhoneExtensionNumber
       end                                                                  as PhoneExtensionNumber,
       //_Address._CurrentDfltLandlinePhoneNmbr.PhoneExtensionNumber,


       case
          when ServicePartner.AddressObjectType = '3'
           then _PersonWorkplaceAddress._CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber
           else _Address._CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber
          end                                                               as PhoneNumber,
       _Address._CurrentDfltLandlinePhoneNmbr.PhoneNumberCountry,
       _Address.POBox,
       _Address.POBoxPostalCode,
       _Address.PostalCode,
       _Address.Region,
       _Address.StreetName,
       _Address.StreetPrefixName1,
       _Address.StreetPrefixName2,
       _Address.StreetSuffixName1,
       _Address.StreetSuffixName2,
       _Address.TaxJurisdiction,
       _Address.TransportZone
}