R_SrvcContrTmplDurationTP

DDL: R_SRVCCONTRTMPLDURATIONTP Type: view_entity TRANSACTIONAL Package: CRMS4_SRVC_CONTR_TEMPLATE_RAP

Service Contract Template Duration - TP

R_SrvcContrTmplDurationTP is a Transactional CDS View that provides data about "Service Contract Template Duration - TP" in SAP S/4HANA. It reads from 2 data sources (I_ServiceDocument, I_ServiceDocumentDuration) and exposes 4 fields with key fields ServiceContractTemplate, SrvcDocDurationType. Part of development package CRMS4_SRVC_CONTR_TEMPLATE_RAP.

2 data source(s) 4 fields

Data Sources (2)

SourceAliasJoin Type
I_ServiceDocument ServiceContractTemplate inner
I_ServiceDocumentDuration ServiceDuration from

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #PRIVILEGED_ONLY view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #L view
EndUserText.label Service Contract Template Duration - TP view

Fields (4)

KeyFieldSource TableSource FieldDescription
KEY ServiceContractTemplate I_ServiceDocumentDuration ServiceDocument
KEY SrvcDocDurationType I_ServiceDocumentDuration SrvcDocDurationType
SrvcDocDurationValue I_ServiceDocumentDuration SrvcDocDurationValue
SrvcDocDurationUnit I_ServiceDocumentDuration SrvcDocDurationUnit 
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  usageType: {
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #B,
    sizeCategory:   #L
  }
}

@EndUserText.label: 'Service Contract Template Duration - TP'

define view entity R_SrvcContrTmplDurationTP
  as select from I_ServiceDocumentDuration as ServiceDuration

    inner join   I_ServiceDocument         as ServiceContractTemplate on  ServiceDuration.ServiceDocument           = ServiceContractTemplate.ServiceDocument
                                                                      and ServiceDuration.ServiceObjectType         = ServiceContractTemplate.ServiceObjectType
                                                                      and ServiceDuration.ServiceDocumentItem       = '000000'
                                                                      and ServiceContractTemplate.ServiceObjectType = 'BUS2000112'

{

  key ServiceDuration.ServiceDocument      as ServiceContractTemplate,
  key ServiceDuration.SrvcDocDurationType  as SrvcDocDurationType,
      @Semantics.quantity.unitOfMeasure: 'SrvcDocDurationUnitSAPCode' 
      ServiceDuration.SrvcDocDurationValue as SrvcDocDurationValue,
      ServiceDuration.SrvcDocDurationUnit  as SrvcDocDurationUnit,
      // Duration Unit ---> UoM SAPCode

      cast( case ServiceDuration.SrvcDocDurationUnit
              when 'DAY'    then 'TAG'
              when 'HOUR'   then 'H'
              when 'MINUTE' then 'MIN'
              when 'MONTH'  then 'MON'
              when 'SECOND' then 'S'
              when 'WEEK'   then 'WCH'
              when 'YEAR'   then 'JHR'
              when 'ANNUM'  then 'JHR'
            end as meins )                 as SrvcDocDurationUnitSAPCode

}

Learn More