R_SpecCompositionDateIndep

@AbapCatalog.sqlViewName: 'RSPCCMPDATEINDEP'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE

@EndUserText.label: 'Spec Value Assignment Instance with Comp Date Independent'
define view R_SpecCompositionDateIndep
  as select from I_SpecValAssgmtHeader as header
    inner join   I_SpecValAssgmt       as va    on  header.SpecificationInternalID = va.SpecificationInternalID
                                                and header.SpecValAssgmtHdr        = va.SpecValAssgmtHdr
    inner join   I_SpecValAssgmtUsage  as usage on  va.SpecValAssgmt                  = usage.MasterTableElementInternalID
                                                and header.SpecificationInternalID    = usage.SpecificationInternalID
                                                and va.SpecValAssgmtValidityStartDate = usage.SpecValAssgmtUsgeValdtyStrtDte
                                                and va.SpecValAssgmtValidityEndDate   = usage.SpecValAssgmtUsgeValdtyEndDte
    inner join   I_SpecValAssgmtItem   as comp  on  header.SpecificationInternalID    = comp.SpecificationInternalID
                                                and va.SpecValAssgmt                  = comp.SpecValAssgmt
                                                and va.SpecValAssgmtValidityStartDate = comp.SpecValAssgmtItemValdtyStrtDte
                                                and va.SpecValAssgmtValidityEndDate   = comp.SpecValAssgmtItemValdtyEndDte

  association [0..1] to I_SpecificationForKeyDate as _SpecificationForKeyDate on $projection.SpecificationInternalID = _SpecificationForKeyDate.SpecificationInternalID
{

  key header.SpecValAssgmtHdr,
  key va.SpecValAssgmt,
  key comp.ComponentSpecificationIntID,
  key header.SpecificationInternalID,
  key va.SpecValAssgmtChangeState,
  key usage.SpecificationRating,
  key usage.SpecificationValidityArea,

      header.SpecValAssgmtType,

      header.SpecValAssgmtHdrIsDeleted,

      va.SpecValAssgmtValidityStartDate,
      va.SpecValAssgmtValidityEndDate,
      va.SpecValAssgmtChangeNumber,
      va.SpecValAssgmtCreationDate,
      va.SpecValAssgmtCreatedByUser,
      va.SpecValAssgmtLastChangeDate,
      va.SpecValAssgmtLastChangedByUser,

      va.SpecValAssgmtSortSequence,
      va.SpecValAssgmtUnitRefDimension,
      va.SpecValAssgmtIsInhtncSource,
      va.InhtdSpecValAssgmtIsTmpChgd,
      va.InhtdSpecValAssgmtIsPermChgd,
      va.SpecInheritanceTemplate,
      va.SpecValAssgmtInheritanceParent,
      va.SpecValAssgmtInheritanceRoot,
      va.SpecValAssgmtRootSpecIntID,

      va.SpecValAssgmtIsDeleted,

      usage.SpecValAssgmtUsageIsExcluded,
      usage.SpecValAssgmtUsageIsRelevant,

      comp.CompSpecComponentType,
      comp.SpecValAssgmtItem,
      comp.SpecValAssgmtItemChangeState,

      comp.CompSpecQuantity,
      comp.CompSpecUnit,
      comp.CompSpecExceptionCode,
      comp.CompSpecLowerLimitOperator,
      comp.CompSpecLowerLimit,
      comp.CompSpecUpperLimitOperator,
      comp.CompSpecUpperLimit,

      _SpecificationForKeyDate

}
where
      va.SpecValAssgmtInheritanceRoot =  '00000000000000000000'
  and comp.SpecValAssgmtItemIsDeleted <> 'X'