R_ServiceOrderTemplateItemTP

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata:
{
  ignorePropagatedAnnotations: true
}

@EndUserText.label: 'Service Order Template Item - TP'
@ObjectModel: {
  sapObjectNodeType.name: 'ServiceOrderTemplateItem',
  semanticKey: ['ServiceOrderTemplateItem'],
  representativeKey: 'ServiceOrderTemplateItem',
   usageType: {dataClass:      #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory:   #L}
}
define view entity R_ServiceOrderTemplateItemTP
  as select from I_ServiceDocumentItemEnhcd
  association        to parent R_ServiceOrderTemplateTP as _ServiceOrderTemplateTP on  $projection.ServiceOrderTemplate = _ServiceOrderTemplateTP.ServiceOrderTemplate
  association [0..1] to I_StatusObjectUUIDStatus        as _SrvcOrdTmplItmStatus   on  $projection.ServiceOrderTemplateItemUUID = _SrvcOrdTmplItmStatus.StatusObjectUUID
                                                                                   and (
                                                                                      _SrvcOrdTmplItmStatus.StatusCode          = 'I1002'
                                                                                      or _SrvcOrdTmplItmStatus.StatusCode       = 'I1003'
                                                                                      or _SrvcOrdTmplItmStatus.StatusCode       = 'I1004'
                                                                                      or _SrvcOrdTmplItmStatus.StatusCode       = 'I1005'
                                                                                    )
                                                                                   and _SrvcOrdTmplItmStatus.StatusIsActive     = 'X'
  //! Extensibility support

  association [0..1] to E_ServiceDocumentItem           as _Extension              on  _Extension.ServiceCategory           = 'BUS2000116'
                                                                                   and $projection.ServiceOrderTemplate     = _Extension.ServiceOrderItem
                                                                                   and $projection.ServiceOrderTemplateItem = _Extension.ServiceLineExternalID

  composition [0..*] of R_SrvcOrdTmplItmRefObjectTP     as _SrvcOrdTmplItmRefObjectTP
  composition [0..*] of R_SrvcOrdTmplItemUserStatusTP   as _SrvcOrdTmplItemUserStatusTP
  composition [0..*] of R_SrvcOrdTmplItemPartnerTP      as _SrvcOrdTmplItmPartnerTP
  composition [0..*] of R_SrvcOrdTmplItemLongTextTP     as _SrvcOrdTmplItemLongTextTP
  composition [0..*] of R_SrvcOrdTmplItemAppointmentTP  as _SrvcOrdTmplItemAppointmentTP
  composition [0..*] of R_SrvcOrdTmplItemDurationTP     as _SrvcOrdTmplItemDurationTP
{
      // Administrative Fields

      @ObjectModel.foreignKey.association: '_ServiceDocument'
  key ServiceDocument                                       as ServiceOrderTemplate,
  key ServiceDocumentItem                                   as ServiceOrderTemplateItem,

      ServiceDocumentItemUUID                               as ServiceOrderTemplateItemUUID,
      ServiceDocumentItemDescription                        as SrvcOrdTmplItmDescription,

      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,

      @ObjectModel.sapObjectNodeTypeReference: 'ServiceDocumentItemCategory'
      ServiceDocItemCategory                                as SrvcOrdTmplItmCategory,

      ServiceDocumentItemObjectType,
      Language,

      @Semantics.dateTime:true
      SrvcDocItmValdtyStartDateTime                         as SrvcOrdTmplItmValdtyStrtDteTme,

      @Semantics.dateTime:true
      SrvcDocItmValdtyEndDateTime                           as SrvcOrdTmplItmValdtyEndDteTme,

      @Semantics.dateTime:true
      ServiceDocItemChangedDateTime,

      @Semantics.dateTime:true
      ServiceDocItemCreationDateTime,

//      ResponsibleEmployee                                   as RespEmployeeBusinessPartnerId,


      ServiceDocItemCreatedByUser,
      ServiceDocItemChangedByUser,

      //      OriginallyRequestedProduct                            as Product,


      @ObjectModel.foreignKey.association: '_Product'
      Product,

      @Semantics: { quantity : {unitOfMeasure: 'QuantityUnit'} }
      ServiceDocumentItemQuantity                           as Quantity,
      ServiceDocItemQuantityUnit                            as QuantityUnit,


      _ParentServiceDocItem.ServiceDocumentItem             as ParentServiceOrderTemplateItem,
      // Status

      cast( case _SrvcOrdTmplItmStatus.StatusCode
      when 'I1002' then 'X'
      else ' '
      end                  as   xfeld preserving type     ) as SrvcOrdTmplItmIsNew,
      cast( case _SrvcOrdTmplItmStatus.StatusCode
      when 'I1003' then 'X'
      else ' '
      end                  as   xfeld preserving type     ) as SrvcOrdTmplItmIsInProcess,
      cast( case _SrvcOrdTmplItmStatus.StatusCode
      when 'I1004' then 'X'
      else ' '
      end                  as   xfeld preserving type     ) as SrvcOrdTmplItmIsReleased,
      cast( case _SrvcOrdTmplItmStatus.StatusCode
      when 'I1005' then 'X'
      else ' '
      end                  as   xfeld preserving type     ) as SrvcOrdTmplItmIsCompleted,


      //Inheritance of complex set

      SrvcDocItmPartReferenceItem,
      SrvcDocItmApptReferenceItem,
      SrvcDocItmApptRefObjectUUID,

      //Associations

      _ServiceOrderTemplateTP,
      _ServiceObjType,
      _ServiceDocument,
      _SrvcOrdTmplItmStatus,
      _SrvcOrdTmplItmRefObjectTP,
      _SrvcOrdTmplItemUserStatusTP,
      _SrvcOrdTmplItmPartnerTP,
      _SrvcOrdTmplItemLongTextTP,
      _SrvcOrdTmplItemAppointmentTP,
      _SrvcOrdTmplItemDurationTP,
      _Product

}
where
      ServiceObjectType              = 'BUS2000116' //  Service Process

  and ServiceDocumentItemIsQuotation is initial
  and ServiceDocumentTemplateType    is not initial