R_ServiceOrderItemTP

@EndUserText.label: 'Service Order Item - TP'

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata: {
  ignorePropagatedAnnotations: true
}

@ObjectModel: {
   representativeKey: 'ServiceOrderItem',
   semanticKey: ['ServiceOrderItem'],
   usageType: {dataClass:      #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory:   #L}
}

@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
 
define view entity R_ServiceOrderItemTP
  as select from I_ServiceDocumentItemEnhcd

  association        to parent R_ServiceOrderTP        as _ServiceOrderTP               on  //$projection.ServiceObjectType = _ServiceOrderTP.ServiceObjectType and

                                                                                            $projection.ServiceOrder = _ServiceOrderTP.ServiceOrder

  association [0..*] to I_ServiceDocumentRefObject     as _ServiceOrderItemRefObj       on  $projection.ServiceObjectType = _ServiceOrderItemRefObj.ServiceObjectType
                                                                                        and $projection.ServiceOrder      = _ServiceOrderItemRefObj.ServiceDocument
                                                                                        and $projection.ServiceOrderItem  = _ServiceOrderItemRefObj.ServiceDocumentItem

  association [0..1] to I_CustMgmtExtRefID             as _CustMgmtExtRef               on  $projection.ServiceOrder             = _CustMgmtExtRef.CustMgmtDocument
                                                                                        and $projection.ServiceObjectType        = _CustMgmtExtRef.CustMgmtObjectType
                                                                                        and $projection.ServiceOrderItem         = _CustMgmtExtRef.CustMgmtDocumentItem
                                                                                        and _CustMgmtExtRef.CustMgmtExtRefIDType = '0002'

  association [0..1] to I_CustMgmtExtRefID             as _CustMgmtHeaderExtRef         on  $projection.ServiceOrder                   = _CustMgmtHeaderExtRef.CustMgmtDocument
                                                                                        and $projection.ServiceObjectType              = _CustMgmtHeaderExtRef.CustMgmtObjectType
                                                                                        and _CustMgmtHeaderExtRef.CustMgmtExtRefIDType = '0001'

  association [0..1] to R_SrvcDocItemDocumentFlow      as _RefServiceContract           on  $projection.ServiceOrder                        = _RefServiceContract.ServiceDocument
                                                                                        and $projection.ServiceOrderItem                    = _RefServiceContract.ServiceDocumentItem
                                                                                        and _RefServiceContract.PrdcssrSuccssrDocObjectType = 'BUS2000112'
                                                                                        and _RefServiceContract.ServiceObjectType           = 'BUS2000116'

  association [0..1] to R_SrvcDocItemDocumentFlow      as _RefServiceTemplate           on  $projection.ServiceOrder                        = _RefServiceTemplate.ServiceDocument
                                                                                        and $projection.ServiceOrderItem                    = _RefServiceTemplate.ServiceDocumentItem
                                                                                        and _RefServiceTemplate.PrdcssrSuccssrDocObjectType = 'BUS2000116'
                                                                                        and _RefServiceTemplate.ServiceDocumentTemplateType is not initial
                                                                                        and _RefServiceTemplate.ServiceObjectType           = 'BUS2000116'

  association [0..1] to R_SrvcDocItemDocumentFlow      as _RefServiceQuotation          on  $projection.ServiceOrder                            = _RefServiceQuotation.ServiceDocument
                                                                                        and $projection.ServiceOrderItem                        = _RefServiceQuotation.ServiceDocumentItem
                                                                                        and _RefServiceQuotation.PrdcssrSuccssrDocObjectType    = 'BUS2000116'
                                                                                        and _RefServiceQuotation.ServiceDocumentItemIsQuotation is not initial
                                                                                        and _RefServiceQuotation.ServiceObjectType              = 'BUS2000116'


  association [0..1] to I_SrvcMgmtObjectStatus         as _SrvcOrdItmStatus             on  $projection.ServiceOrderItemUUID = _SrvcOrdItmStatus.SrvcMgmtObjectUUID
                                                                                        and (
                                                                                           _SrvcOrdItmStatus.SrvcMgmtObjectStatus    = 'I1002'
                                                                                           or _SrvcOrdItmStatus.SrvcMgmtObjectStatus = 'I1003'
                                                                                           or _SrvcOrdItmStatus.SrvcMgmtObjectStatus = 'I1004'
                                                                                           or _SrvcOrdItmStatus.SrvcMgmtObjectStatus = 'I1005'
                                                                                         )
                                                                                        and _SrvcOrdItmStatus.SrvcMgmtObjectStatusIsInactive != 'X'
  association [0..1] to I_CustMgmtPartner              as _ServicePerformer             on  _ServicePerformer.CustMgmtPartnerFunction      = '00000028'
                                                                                        and _ServicePerformer.CustMgmtPartFunctionCategory = '0091'
                                                                                        and $projection.ServiceOrder                       = _ServicePerformer.CustMgmtDocument
                                                                                        and $projection.ServiceOrderItem                   = _ServicePerformer.CustMgmtDocumentItem
  association [0..1] to I_SrvcMgmtObjectStatus         as _StatusSCDetn                 on  $projection.ServiceOrderItemUUID   = _StatusSCDetn.SrvcMgmtObjectUUID
                                                                                        and _StatusSCDetn.SrvcMgmtObjectStatus = 'I0994'
  association [0..1] to I_SrvcOrdItmRefFSMSrvcActivity as _SrvcOrdItmRefFSMSrvcActivity on  $projection.ServiceOrder                       = _SrvcOrdItmRefFSMSrvcActivity.ServiceDocument
                                                                                        and $projection.ServiceOrderItem = _SrvcOrdItmRefFSMSrvcActivity.ServiceDocumentItem
  association [0..1] to I_RespyMgmtTeamHeaderDetail    as _ServiceTeamHeader            on  $projection.RespyMgmtServiceTeam = _ServiceTeamHeader.RespyMgmtTeamID

  composition [0..*] of R_SrvcOrdItemReferenceObjectTP as _SrvcOrdItemReferenceObjectTP
  composition [0..*] of R_SrvcOrdItemPriceElementTP    as _SrvcOrdItemPriceElementTP
  composition [0..*] of R_SrvcOrdItmPartnerTP          as _SrvcOrdItmPartnerTP
  composition [0..*] of R_SrvcOrdItemUserStatusTP      as _SrvcOrdItmUserStatusTP
  composition [0..*] of R_SrvcOrdItmFUPSrvcConfTP      as _SrvcOrdItmFUPSrvcConfTP
  composition [0..*] of R_SrvcOrdItmFUPBillgDocTP      as _SrvcOrdItmFUPBillgDocTP
  composition [0..*] of R_SrvcOrdItmFUPPurchaseOrderTP as _SrvcOrdItmFUPPurchaseOrderTP
  composition [0..1] of R_SrvcOrdItmFUPPurReqnTP       as _SrvcOrdItmFUPPurReqnTP
  composition [0..*] of R_SrvcOrdItmFUPSrvcEntrSheetTP as _SrvcOrdItmFUPEntrySheetTP
  composition [0..*] of R_SrvcOrdItmFUPSuplrInvcTP     as _SrvcOrdItmFUPSuplrInvcTP
  composition [0..*] of R_SrvcOrdItemAppointmentTP     as _SrvcOrdItemAppointmentTP
  composition [0..*] of R_SrvcOrdItemDurationTP        as _SrvcOrdItemDurationTP
  composition [0..*] of R_SrvcOrdItmFUPMaintOrdTP      as _SrvcOrdItmFUPMaintOrdTP
  composition [0..*] of R_SrvcOrdItemLongTextTP        as _SrvcOrdItemLongTextTP

  //! Extensibility support

  association [0..1] to E_ServiceDocumentItem          as _Extension                    on  _Extension.ServiceCategory   = 'BUS2000116'
                                                                                        and $projection.ServiceOrder     = _Extension.ServiceOrderItem
                                                                                        and $projection.ServiceOrderItem = _Extension.ServiceLineExternalID
  association [0..1] to I_WBSElementBasicData          as _WBSElement                   on  _WBSElement.WBSElementInternalID = I_ServiceDocumentItemEnhcd.WBSElementInternalID

{

      // Administrative Fields

      @ObjectModel.foreignKey.association: '_ServiceDocument'
  key ServiceDocument                                                                               as ServiceOrder,
  key ServiceDocumentItem                                                                           as ServiceOrderItem,
      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,
      ServiceDocumentItemObjectType,
      ServiceDocItemCategory                                                                        as ServiceOrderItemCategory,
      ServiceDocumentItemUUID                                                                       as ServiceOrderItemUUID,
      @Semantics.uuid:true
      //ServiceDocumentItemCharUUID                                                                   as ServiceOrderItemCharUUID,

      _ParentServiceDocItem_2.ServiceDocumentItem                                                   as ParentServiceOrderItem,
      ServiceDocumentItemDescription                                                                as ServiceOrderItemDescription,
      Language,
      ServiceDocItemCreationDateTime,
      ServiceDocItemChangedDateTime,
      ServiceDocItemCreatedByUser,
      ServiceDocItemChangedByUser,

      // Item Fields

      @ObjectModel.foreignKey.association: '_Product'
      Product,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      ServiceDocumentItemQuantity                                                                   as Quantity,
      ServiceDocItemQuantityUnit                                                                    as QuantityUnit,

      // Partners

      SoldToParty,
      ShipToParty,
      BillToParty,
      PayerParty,

      @ObjectModel.foreignKey.association: '_PaymentTerms'
      PaymentTerms,

      //@ObjectModel.foreignKey.association: '_PaymentMethod'

      PaymentMethod,

      SEPAMandate,

      @ObjectModel.foreignKey.association: '_SrvcSEPAMandateRelevance'
      SrvcSEPAMandateRelevance,

      @ObjectModel.foreignKey.association: '_ContactPerson'
      ContactPerson                                                                                 as ContactPersonBusinessPartnerId,
      @ObjectModel.foreignKey.association: '_RespEmployee'
      ResponsibleEmployee                                                                           as RespEmployeeBusinessPartnerId,
      ServiceEmployee                                                                               as ExecutingServiceEmployee,
      _ServicePerformer.CustMgmtBusinessPartner                                                     as ServicePerformer,

      // Organizational Data

      RespyMgmtServiceTeam,
      //_ServiceTeamHeader.TeamName                                                                   as RespyMgmtServiceTeamName,

      _ServiceTeamHeader.RespyMgmtGlobalTeamID                                                      as RespyMgmtGlobalTeamID,

      // Status

      cast( case _SrvcOrdItmStatus.SrvcMgmtObjectStatus
      when 'I1002' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                                         as ServiceOrderItemIsNew,
      cast( case _SrvcOrdItmStatus.SrvcMgmtObjectStatus
      when 'I1003' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                                         as ServiceOrderItemIsInProcess,
      cast( case _SrvcOrdItmStatus.SrvcMgmtObjectStatus
      when 'I1004' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                                         as ServiceOrderItemIsReleased,
      cast( case _SrvcOrdItmStatus.SrvcMgmtObjectStatus
      when 'I1005' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                                         as ServiceOrderItemIsCompleted,
      ServiceDocumentItemStatus                                                                     as ServiceOrderItemStatus,
      SrvcDocItmIsReleasedForBilling                                                                as SrvcOrdItmReldForBillgStatus,
      ServiceDocItemBillingStatus                                                                   as ServiceOrderItemBillingStatus,
      @Semantics.booleanIndicator
      ServiceDocumentItemIsRejected                                                                 as ServiceOrderItemIsRejected,
      @Semantics.booleanIndicator
      ServiceDocumentItemHasError                                                                   as ServiceOrderItemHasError,
      SrvcDocItemTransferStatus,
      SrvcDocItemExecutionStatus                                                                    as SrvcOrdItemExecutionStatus,
      SrvcDocItemCreditStatus                                                                       as SrvcOrdItemCreditStatus,

      // Dates and Durations

      RequestedServiceStartDateTime,
      RequestedServiceEndDateTime,
      ServiceFirstResponseByDateTime,
      SrvcDocItemSLADueByDateTime,
      PlannedServiceStartDateTime,
      PlannedServiceEndDateTime,
      //RequestedDeliveryUTCDateTime                                                                  as ErlstRequestedDeliveryDateTime,


      @Semantics: { quantity : {unitOfMeasure: 'ServiceDurationUnit'} }
      ServiceDuration,
      ServiceDurationUnit,

      //SC Determination flag

      //_StatusSCDetn.StatusIsActive                                                                  as SrvcContrDetnIsSpprsd,                                                             as SrvcContrDetnIsSpprsd,

      cast( case coalesce( _StatusSCDetn.SrvcMgmtObjectStatusIsInactive, 'X' )
        when 'X' then ' '
        else 'X'
      end as vdm_j_statusisactive preserving type )                                                 as SrvcContrDetnIsSpprsd,

       // Pricing Fields

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      TransactionCurrency,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocItemGrossAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemNetAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemTaxAmount,
      @ObjectModel.foreignKey.association: '_BillableControl'
      BillableControl,

      //RAP : Inheritance of complex set

      SrvcDocItmPartReferenceItem,
      SrvcDocItmApptRefObjectUUID,
      SrvcDocItmApptReferenceItem,

      // Sales Fields

      @ObjectModel.foreignKey.association: '_ServiceDocItemRejectionReason'
      ServiceDocItemRejectionReason                                                                 as ServiceOrdItemRejectionReason,

      // Reference Documents

      _CustMgmtHeaderExtRef.CustMgmtExtRefID                                                        as SrvcOrdExtReference,
      _CustMgmtExtRef.CustMgmtExtRefID                                                              as SrvcOrdItemExtReference,
      cast( _RefServiceContract.CustMgmtPrdcssrTransactionKey as crmt_object_id_db )                as ReferenceServiceContract,
      cast( _RefServiceContract.BusinessTransactionDocItem as crms4_number_int )                    as ReferenceServiceContractItem,
      cast( _RefServiceTemplate.CustMgmtPrdcssrTransactionKey as crmt_object_id_db )                as RefServiceOrderTemplate,
      cast( _RefServiceTemplate.BusinessTransactionDocItem as crms4_number_int )                    as RefServiceOrderTemplateItem,
      cast( _RefServiceQuotation.CustMgmtPrdcssrTransactionKey  as crms4_reference_document_id_co ) as ReferenceServiceQtan,
      cast( _RefServiceQuotation.BusinessTransactionDocItem as crms4_number_int )                   as ReferenceServiceQtanItem,

      //Shipping

      ShippingCondition,

      _WBSElement.WBSElementExternalID,

      @Feature: 'BF:API_ESSENTIALSCOPE'
      SrvcDocItemIsUnplanned                                                                        as SrvcOrdItemIsUnplanned,

      // FSM Field

      _SrvcOrdItmRefFSMSrvcActivity.FSMServiceActivity,
      TimeSheetOvertimeCategory,
      ProfitCenter,


      /* Associations */
      _ServiceOrderTP,
      _ServiceObjType,
      _ServiceDocument,
      _ServiceOrderItemRefObj,
      _PaymentTerms,
      _SrvcSEPAMandateRelevance,
      _Product,
      _ContactPerson,
      _RespEmployee,
      _ServiceDocItemRejectionReason,
      _SrvcOrdItemReferenceObjectTP,
      _SrvcOrdItemPriceElementTP,
      _SrvcOrdItmPartnerTP,
      _TransactionCurrency,
      _BillableControl,
      _SrvcOrdItmStatus,
      _SrvcOrdItmUserStatusTP,
      _SrvcOrdItmFUPSrvcConfTP,
      _SrvcOrdItmFUPBillgDocTP,
      _SrvcOrdItmFUPPurchaseOrderTP,
      _SrvcOrdItmFUPPurReqnTP,
      _SrvcOrdItmFUPEntrySheetTP,
      _SrvcOrdItmFUPSuplrInvcTP,
      _SrvcOrdItemAppointmentTP,
      _SrvcOrdItemDurationTP,
      _SrvcOrdItmFUPMaintOrdTP,
      _SrvcOrdItemLongTextTP

}
where
      ServiceObjectType              = 'BUS2000116' // Service Process

  and ServiceDocumentItemIsQuotation is initial
  and ServiceDocumentTemplateType    is initial