R_ServiceContractItemTP

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata:
{
  ignorePropagatedAnnotations: true
}
@EndUserText.label: 'Service Contract Item - TP'
@ObjectModel: {
  sapObjectNodeType.name: 'ServiceContractItem',
  semanticKey: ['ServiceContractItem'],
  representativeKey: 'ServiceContractItem',
  usageType: {dataClass:      #TRANSACTIONAL,
              serviceQuality: #C,
              sizeCategory:   #L}
}
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity R_ServiceContractItemTP
  as select from I_ServiceDocumentItemEnhcd

  association        to parent R_ServiceContractTP    as _ServiceContractTP          on  $projection.ServiceContract = _ServiceContractTP.ServiceContract

  association [0..1] to I_StatusObjectUUIDStatus      as _SrvcOrdItmStatus           on  $projection.ServiceContractItemUUID = _SrvcOrdItmStatus.StatusObjectUUID
                                                                                     and (
                                                                                        _SrvcOrdItmStatus.StatusCode         = 'I1002'
                                                                                        or _SrvcOrdItmStatus.StatusCode      = 'I1003'
                                                                                        or _SrvcOrdItmStatus.StatusCode      = 'I1004'
                                                                                        or _SrvcOrdItmStatus.StatusCode      = 'I1005'
                                                                                      )
                                                                                     and _SrvcOrdItmStatus.StatusIsActive    = 'X'

  association [0..1] to I_CustMgmtExtRefID            as _ExtRefServiceContract      on  _ExtRefServiceContract.CustMgmtObjectType   = 'BUS2000112'
                                                                                     and $projection.ServiceContract                 = _ExtRefServiceContract.CustMgmtDocument
                                                                                     and _ExtRefServiceContract.CustMgmtExtRefIDType = '0003'

  association [0..1] to I_CustMgmtExtRefID            as _ExtRefServiceContractItem  on  _ExtRefServiceContractItem.CustMgmtObjectType   = 'BUS2000112'
                                                                                     and $projection.ServiceContract                     = _ExtRefServiceContractItem.CustMgmtDocument
                                                                                     and $projection.ServiceContractItem                 = _ExtRefServiceContractItem.CustMgmtDocumentItem
                                                                                     and _ExtRefServiceContractItem.CustMgmtExtRefIDType = '0004'

  association [0..1] to I_CustMgmtExtRefID            as _ExtRefServiceQtan          on  _ExtRefServiceQtan.CustMgmtObjectType   = 'BUS2000112'
                                                                                     and $projection.ServiceContract             = _ExtRefServiceQtan.CustMgmtDocument
                                                                                     and _ExtRefServiceQtan.CustMgmtExtRefIDType = '0009'

  association [0..1] to I_CustMgmtExtRefID            as _ExtRefServiceQtanItem      on  _ExtRefServiceQtanItem.CustMgmtObjectType   = 'BUS2000112'
                                                                                     and $projection.ServiceContract                 = _ExtRefServiceQtanItem.CustMgmtDocument
                                                                                     and $projection.ServiceContractItem             = _ExtRefServiceQtanItem.CustMgmtDocumentItem
                                                                                     and _ExtRefServiceQtanItem.CustMgmtExtRefIDType = '0010'
  
  association [0..1] to R_SrvcDocItemDocumentFlow     as _RefServiceTemplate         on  $projection.ServiceContract                     = _RefServiceTemplate.ServiceDocument
                                                                                     and $projection.ServiceContractItem                 = _RefServiceTemplate.ServiceDocumentItem
                                                                                     and _RefServiceTemplate.PrdcssrSuccssrDocObjectType = 'BUS2000112'
                                                                                     and _RefServiceTemplate.ServiceDocumentTemplateType is not initial
                                                                                     and _RefServiceTemplate.ServiceObjectType           = 'BUS2000112'

  association [0..1] to I_CustMgmtDateRule            as _SettlementPeriodRule       on  $projection.SettlementPeriodRuleUUID = _SettlementPeriodRule.CustMgmtDateRuleUUID

  association [0..1] to I_CustMgmtDateRule            as _BillingPlanBillingDateRule on  $projection.BillingPlanBillingDateRuleUUID = _BillingPlanBillingDateRule.CustMgmtDateRuleUUID
  
  association [0..1] to I_PaymentMethodInCountryVH    as _PaymentMethodVH            on  $projection.PaymentMethod = _PaymentMethodVH.PaymentMethod
                                                                                     and $projection.SoldToPartyCountry = _PaymentMethodVH.Country

  // association [0..1] to I_ServiceDocumentItemEnhcd     as _ChgProcSourceItem        on  $projection.SrvcTransChgProcSourceItemUUID = _ChgProcSourceItem.ServiceDocumentItemUUID


  association [1..*] to I_SrvcDocLifecycleStatusText     as _SrvcDocLifecycleStatusText  on $projection.ServiceContractItemStatus = _SrvcDocLifecycleStatusText.ServiceDocumentStatus
  
  association [1..*] to I_ServiceDocBillingStatusText    as _ServiceDocBillingStatusText on $projection.ServiceContrItemBillingStatus = _ServiceDocBillingStatusText.ServiceDocBillingStatus
    
  association [1..*] to I_SrvcDocTransferStatusText      as _SrvcDocTransferStatusText on $projection.SrvcDocItemTransferStatus  = _SrvcDocTransferStatusText.SrvcDocTransferStatus
 
  association [1..*] to I_SrvcDocRejectionStatusText as _SrvcDocRejectionStatusText on $projection.ServiceContractItemIsRejected = _SrvcDocRejectionStatusText.ServiceDocumentIsRejected
  
  association [1..*] to I_BillingBlockReasonText        as _BillingBlockReasonText on $projection.BillingBlockReason = _BillingBlockReasonText.BillingBlockReason
    
  association [1..*] to I_PaymentTermsText               as _PaymentTermsText    on $projection.PaymentTerms = _PaymentTermsText.PaymentTerms
    
  association [1..*] to I_ServiceDocItemCategoryText  as _ServiceDocItemCategoryText on $projection.ServiceContractItemCategory = _ServiceDocItemCategoryText.ServiceDocItemCategory

  association [1..*] to I_UnitOfMeasureText  as _UnitOfMeasureText on $projection.QuantityUnit = _UnitOfMeasureText.UnitOfMeasure  
  
  association [1..*] to I_CurrencyText   as _CurrencyText on $projection.TransactionCurrency = _CurrencyText.Currency
  
  association [0..*] to I_CustMgmtDateRuleText           as _SrvcMgmtDateRuleText  on  $projection.SrvcMgmtBillgPlanBillgDateRule = _SrvcMgmtDateRuleText.CustMgmtDateRuleName
                                                                                            
  association [0..*] to I_CustMgmtDateRuleText           as _SettlementPeriodRuleText  on  $projection.SettlementPeriodRule = _SettlementPeriodRuleText.CustMgmtDateRuleName
  
  association [1..*] to I_ServiceCancellationPartyText as _ServiceCancellationPartyText on $projection.ServiceContractItemCanclnParty = _ServiceCancellationPartyText.ServiceContractCanclnParty

  association [1..*] to I_ServiceCanclnReasonText as _ServiceCanclnReasonText on $projection.ServiceContractItmCanclnReason = _ServiceCanclnReasonText.ServiceContrCancellationReason
  
  composition [0..*] of R_SrvcContrItemPartnerTP      as _SrvcContrItmPartnerTP
  composition [0..*] of R_SrvcContrItemPriceElementTP as _SrvcContrItmPriceElementTP
  composition [0..*] of R_SrvcContrItemUserStatusTP   as _SrvcContrItemUserStatusTP
  composition [0..*] of R_SrvcContrItmFUPBillgDocTP   as _SrvcContrItmFUPBillgDocTP
  composition [0..*] of R_SrvcContrItmFUPSrvcOrdTP    as _SrvcContrItmFUPSrvcOrdTP
  composition [0..*] of R_SrvcContrItemRefObjectTP    as _SrvcContrItemRefObjectTP
  composition [0..*] of R_SrvcContrItemProductTP      as _SrvcContrItemProductTP
  composition [0..*] of R_SrvcContrItmBillgReqItemTP  as _SrvcContrItmBillgReqItemTP
  composition [0..*] of R_SrvcContrItemDurationTP     as _SrvcContrItemDurationTP
  composition [0..*] of R_SrvcContrItemAppointmentTP  as _SrvcContrItemAppointmentTP
  composition [0..*] of R_SrvcContrItemLongTextTP     as _SrvcContrItemLongTextTP


  //  association [1..1] to R_ServiceContractTP           as _ServiceContract             on  _ServiceContract.ServiceObjectType = 'BUS2000112'

  //                                                                                      and $projection.ServiceContract         = _ServiceContract.ServiceContract


  association [0..1] to I_WBSElementBasicData         as _WBSElement                 on  _WBSElement.WBSElementInternalID = I_ServiceDocumentItemEnhcd.WBSElementInternalID

  association [0..1] to E_ServiceDocumentItem         as _Extension                  on  $projection.ServiceObjectType   = _Extension.ServiceCategory
                                                                                     and $projection.ServiceContract     = _Extension.ServiceOrderItem
                                                                                     and $projection.ServiceContractItem = _Extension.ServiceLineExternalID
{

      // Administrative fields

      @ObjectModel.foreignKey.association: '_ServiceDocument'
  key ServiceDocument                                                                as ServiceContract,
  key cast(ServiceDocumentItem as crms4_number_int preserving type)                  as ServiceContractItem,
      ServiceDocumentDescription                                                     as ServiceContractDescription,
      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,
      _ParentServiceDocItem_2.ServiceDocumentItem                                    as ParentServiceContractItem,
      @ObjectModel.text.association: '_ServiceDocItemCategoryText'
      ServiceDocItemCategory                                                         as ServiceContractItemCategory,
      ServiceDocumentItemUUID                                                        as ServiceContractItemUUID,
      ServiceDocumentItemDescription                                                 as ServiceContractItemDescription,
      Language,
      ServiceDocItemCreationDateTime,
      cast( tstmp_to_dats( ServiceDocItemCreationDateTime, 
        abap_system_timezone( $session.client,'NULL' ), 
        $session.client, 'NULL' )   as crms4_created_on preserving type )            as ServiceDocItemCreationDate,
      ServiceDocItemChangedDateTime,
      ServiceDocItemCreatedByUser,
      ServiceDocItemChangedByUser,


      // Item Fields

      @ObjectModel.foreignKey.association: '_Product'
      Product,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      ServiceDocumentItemQuantity                                                    as Quantity,
      @ObjectModel.text.association: '_UnitOfMeasureText'
      ServiceDocItemQuantityUnit                                                     as QuantityUnit,

      // Partners

      SoldToParty,
      ShipToParty,
      BillToParty,
      PayerParty,
      @ObjectModel.foreignKey.association: '_ContactPerson'
      ContactPerson                                                                  as ContactPersonBusinessPartnerId,
      @ObjectModel.foreignKey.association: '_RespEmployee'
      ResponsibleEmployee                                                            as RespEmployeeBusinessPartnerId,
      SoldToPartyCountry,

      // Billing Relevant Fields

      @ObjectModel.foreignKey.association: '_PaymentTerms'
      @ObjectModel.text.association: '_PaymentTermsText'
      PaymentTerms,
      PaymentMethod,
      SEPAMandate,
      @ObjectModel.foreignKey.association: '_SrvcSEPAMandateRelevance'
      SrvcSEPAMandateRelevance,

      // Organizational Data

      //RespyMgmtServiceTeam,

      //_ServiceTeamHeader.RespyMgmtGlobalTeamID                                             as RespyMgmtGlobalTeamID,

      SalesOrganization,
      DistributionChannel,
      Division,
      SalesOffice,
      SalesGroup,
      
      SalesOrganizationOrgUnitID,

      // Status

      cast( case _SrvcOrdItmStatus.StatusCode
      when 'I1002' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                          as ServiceContractItemIsNew,
      cast( case _SrvcOrdItmStatus.StatusCode
      when 'I1003' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                          as ServiceContractItemIsInProcess,
      cast( case _SrvcOrdItmStatus.StatusCode
      when 'I1004' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                          as ServiceContractItemIsReleased,
      cast( case _SrvcOrdItmStatus.StatusCode
      when 'I1005' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                          as ServiceContractItemIsCompleted,
      @ObjectModel.text.association: '_SrvcDocLifecycleStatusText'
      ServiceDocumentItemStatus                                                      as ServiceContractItemStatus,
      @ObjectModel.text.association: '_ServiceDocBillingStatusText'
      ServiceDocItemBillingStatus                                                    as ServiceContrItemBillingStatus,
      @Semantics.booleanIndicator
      @ObjectModel.text.association: '_SrvcDocRejectionStatusText'
      ServiceDocumentItemIsRejected                                                  as ServiceContractItemIsRejected,
      @Semantics.booleanIndicator
      ServiceDocumentItemHasError                                                    as ServiceContractItemHasError,
      @ObjectModel.text.association: '_SrvcDocTransferStatusText'
      SrvcDocItemTransferStatus,
      SrvcDocItemCreditStatus                                                        as SrvcContrItemCreditStatus,

      // Dates and Durations

      @Semantics.dateTime:true
      ServiceContrItemStartDateTime,
      cast( tstmp_to_dats( ServiceContrItemStartDateTime, 
        abap_system_timezone( $session.client,'NULL' ), 
        $session.client, 'NULL' )   as crms4_created_on preserving type )            as ServiceContractItemStartDate,
      @Semantics.dateTime:true
      ServiceContrItemEndDateTime,
      cast( tstmp_to_dats( ServiceContrItemEndDateTime, 
        abap_system_timezone( $session.client,'NULL' ), 
        $session.client, 'NULL' )   as crms4_created_on preserving type )            as ServiceContractItemEndDate,
      @Semantics: { quantity : {unitOfMeasure: 'SrvcContrItemRnwlDurationUnit'} }
      SrvcContrItemRnwlDuration                                                      as SrvcContrItemRnwlDuration,
      SrvcContrItemRnwlDurationUnit                                                  as SrvcContrItemRnwlDurationUnit,
      @Semantics: { quantity : {unitOfMeasure: 'SrvcContrItemExtnDurationUnit'} }
      SrvcContrItemExtensionDuration                                                 as SrvcContrItemExtensionDuration,
      SrvcContrItemExtnDurationUnit                                                  as SrvcContrItemExtnDurationUnit,
      
      ResponseProfile,
      ServiceProfile,

      ProfitCenter,

      // Pricing

      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocItemGrossAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemNetAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemTaxAmount,
      @ObjectModel.text.association: '_CurrencyText'
      TransactionCurrency,

      //Cancellation

      @ObjectModel.text.association: '_ServiceCancellationPartyText'
      ServiceDocumentItemCanclnParty                                                 as ServiceContractItemCanclnParty,
      @ObjectModel.text.association: '_ServiceCanclnReasonText'
      ServiceDocumentItmCanclnReason                                                 as ServiceContractItmCanclnReason,
      cast( case ServiceDocumentItemCanclnParty
      when '' then 0
      else ServiceContrItemEndDateTime
      end as timestamp preserving type     )                                         as SrvcContrItemCanclnDateTime,

      // Item - Billing Plan

      SettlementPeriodRuleUUID,
      _SettlementPeriodRule.CustMgmtDateRuleName                                     as SettlementPeriodRule,
      @ObjectModel.text.association: '_SettlementPeriodRuleText'
      BillingPlanBillingDateRuleUUID,
      @ObjectModel.text.association: '_SrvcMgmtDateRuleText'
      _BillingPlanBillingDateRule.CustMgmtDateRuleName                               as SrvcMgmtBillgPlanBillgDateRule,
      @ObjectModel.text.association: '_BillingBlockReasonText'
      BillingBlockReason,
      BillingPlanPriceDateRule,
      BillingPlanIsFinalized,
      ContractAccount,

      // Reference Documents

      _ExtRefServiceContract.CustMgmtExtRefID                                        as SrvcContrExternalReference,
      _ExtRefServiceContractItem.CustMgmtExtRefID                                    as SrvcContrItmExternalReference,

      _ExtRefServiceQtan.CustMgmtExtRefID                                            as ServiceQtanExtReference,
      _ExtRefServiceQtanItem.CustMgmtExtRefID                                        as ServiceQtanItemExtReference,
      
      cast( _RefServiceTemplate.CustMgmtPrdcssrTransactionKey as crmt_object_id_db ) as RefServiceContractTemplate,
      cast( _RefServiceTemplate.BusinessTransactionDocItem as crms4_number_int )     as RefServiceContractTemplateItem,

      //Inheritance of Complex set in RAP

      SrvcDocItmPartReferenceItem, //For Item Partner

      SrvcDocItmApptRefObjectUUID, //For Item Appointment UUID

      //SrvcDocItmApptReferenceItem,//For Appointment and Duration


      _WBSElement.WBSElementExternalID,
      
      // Sales

      PurchaseOrderByCustomer,

      //Associations

      _ServiceDocument,
      //      _ServiceContract,

      _ServiceContractTP,
      _SrvcContrItmPartnerTP,
      _SrvcContrItmPriceElementTP,
      _SrvcContrItemUserStatusTP,

      _ServiceObjType,


      _ExtRefServiceContract,
      _ExtRefServiceContractItem,


      _Product,
      _ContactPerson,
      _RespEmployee,
      _PaymentTerms,
      _PaymentMethod,
      _PaymentMethodVH,
      _SrvcSEPAMandateRelevance,
      _SrvcContrItmFUPBillgDocTP,
      _SrvcContrItmFUPSrvcOrdTP,
      _SrvcContrItemRefObjectTP,
      _SrvcContrItemProductTP,
      _SrvcContrItmBillgReqItemTP,
      _SrvcContrItemDurationTP,
      _SrvcContrItemAppointmentTP,
      _SrvcContrItemLongTextTP,
      _BaseUnit,
      _SrvcContrItemExtnDurationUnit,
      _SrvcContrItemRnwlDurationUnit,
      
      // Mass Process Enhancement

      _ServiceDocItemCategory,
      _SrvcDocItmLifecycleStatus,
      _ServiceDocItemHasError,
      _SrvcDocItemCreditStatus,
      _ServiceDocItemBillingStatus,
      _SoldToParty,
      _ShipToParty,
      _BillToParty,
      _PayerParty,
      _SalesOrganization,
      _DistributionChannel,
      _Division,
      _SalesOffice,
      _SalesGroup,
      _BillingBlockReason,
      
      // UX improvement

      _SrvcDocLifecycleStatusText,
      _ServiceDocBillingStatusText,
      _SrvcDocTransferStatusText,
      _SrvcDocRejectionStatusText,
      _BillingBlockReasonText,
      _PaymentTermsText,
      _ServiceDocItemCategoryText,
      _UnitOfMeasureText,
      _CurrencyText,
      _SrvcMgmtDateRuleText,
      _SettlementPeriodRuleText,
      _ServiceCancellationPartyText,
      _ServiceCanclnReasonText
}
where
  ServiceObjectType = 'BUS2000112' //Service Contract

  and ServiceDocumentTemplateType is initial